Userform Dashboard-sehr komplex

Abbas · 2016-07-08T01:15:49+00:00

Hallo, ich wende mich an Euch, nachdem ich alles durchsucht und nichts gefunden habe..meine Dashboard droht als totes Projekt vor der Geburt zu scheitern, und dies an der Anzeige...Bitte ummaehr dringende Hilfe, VBA Freunde: Infos: win7 / 64 bit, Office 2016 1) In einem Blatt kommen die berechneten Daten und werden arrangiert, daraus ergeben sich 20 Diagramme (jeweils Aktueller Monat, akt. Quartal, YtD und Year to End) dann für 4 Vertriebsregionen, und als gesamt Untnehmen...also 5x4... 2) diese Diagramme haben die gleiche Grösse und ich habe die arrangiert, sodass es aussieht wie eine Tabelle(4x5) 3) auf einem anderen Blatt habe ich mit dem Camera Tool ein Bild dieses Konstruktes stehen... Frage1: kann mann die Qualität dieses letzen Bildes beeiflussen (gepixelt, blass, Schatten..sieht schlecht aus)? Mit einer Sub habe ich dieses Bild exportiert...leider nur über den Umweg, CopyPicture, dann ein neues Diagramm erzeugt und das Bild rein, dann als Datei exportiert... Frage2: kann man hier die Qualität beeinflussen? Frage3: wie sind Eure Erfahrungen bzgl. Export Format (JPG, BMP, GIF)? und wie soll ich die Abmessungen einstellen (Pt. cm, etc....) Das exportierte Bild soll in einer UserForm benutzt werden...hier auch die selben Fragen, denn das istbdas eigentliche Ziel. Ich bin Euch im Voraus sehr dankbar für jeglichen Gedankenansatz, Hilfe, Links, Tutos und Snippets oder gar Workarrounds. Freundliche Grüsse Abbas

Hi zusammen,
ich habe eine frühere Antwort von Beverly gefunden...
https://www.herber.de/forum/archiv/1128to1132/1130567_Grafik_oder_Bereich_mit_VBA_als_Bild_speichern.html
... mit der das ganz ohne API geht.
Ich habe es mal an die vorliegenden Bedürfnisse angepaßt, und es scheint zu tun, allerdings mit dem kleinen Schönheitsfehler, daß ein zusätzlicher Rahmen außenrum angezeigt wird (den Karin vielleicht weg bekommt, *falls* er stören sollte).
Der Code sieht dann so aus:

Option Explicit
Sub BilderExportierenShape()
Dim shBild As Shape
Dim quer#, hoch#
Set shBild = ActiveSheet.Shapes("Gruppieren 5")
quer = shBild.Width: hoch = shBild.Height
BildExportShape shBild
Set shBild = Nothing
'    Debug.Print "Höhe: " & hoch & " Breite: " & quer
frmChart.Height = 60 + Int(hoch + 1)
frmChart.Width = 40 + Int(quer + 1)
With frmChart.imgChart
.Left = 20
.Top = 20
.Picture = LoadPicture("C:\Temp\Bild1.bmp")
.AutoSize = True
End With
'    Kill "C:\Temp\Bild1.bmp"
frmChart.Show
End Sub
Sub BildExportShape(shExport As Shape)
Dim chDiagramm As ChartObject
Application.ScreenUpdating = False
shExport.CopyPicture Appearance:=xlScreen, Format:=xlBitmap
Set chDiagramm = ActiveSheet.ChartObjects.Add(0, 0, shExport.Width, shExport.Height)
With chDiagramm.Chart
.Paste
.Export Filename:="C:\Temp\Bild1.bmp", FilterName:="BMP"
' andere Grafikformate sind möglich
End With
chDiagramm.Delete
Set chDiagramm = Nothing
Set shExport = Nothing
Application.ScreenUpdating = True
End Sub

Schöne Grüße,
Michael

Hi Karin,
na gut...
Aber er hatte ja Probleme mit der Größe; die kann er entweder vorher oder nachher ermitteln:

Sub BildDatenVorExport()
Dim quer#, hoch#
quer = ActiveSheet.Shapes("Gruppieren 5").Width
hoch = ActiveSheet.Shapes("Gruppieren 5").Height
MsgBox "hoch: " & hoch & " quer: " & quer
' das sind 478,25*299
End Sub
Sub BildDatenNachExport()
'Quelle:
'https://msdn.microsoft.com/de-de/library/bb979154.aspx?f=255&MSPPError=-2147217396
Dim quer&, hoch&
Dim ff As Integer
' Binäres Öffnen und exakt passendes Auslesen einer BMP-Datei
ff = FreeFile()
Open "C:\Temp\Bild1.bmp" For Binary Access Read As #ff
Get #ff, 19, quer
Get #ff, 23, hoch
Close #ff
' Anzeige der ermittelten Information:
MsgBox "Die Grafik in C:\Temp\Bild1.bmp ist " & vbNewLine & _
quer & " Pixel breit und " & vbNewLine & _
hoch & " Pixel hoch.", _
vbInformation, "BMP-Analyse"
' das sind bei mir 641/402, das muß also noch mit einem Korrektur-
' faktor verrechnet werden:
' 402/299=1,344481605
frmChart.Height = 60 + Int(hoch / 1.344481605 + 1)
frmChart.Width = 40 + Int(quer / 1.344481605 + 1)
With frmChart.imgChart
.Left = 20
.Top = 20
.Picture = LoadPicture("C:\Temp\Bild1.bmp")
.AutoSize = True
End With
'    Kill "C:\Temp\Bild1.bmp"
frmChart.Show
End Sub

Schöne Grüße,
Michael

Forumthread: Userform Dashboard-sehr komplex

13
Beiträge zum Forumthread

Beiträge zu diesem Forumthread

Infobox / Tutorial

Userform Dashboard in Excel erstellen

Schritt-für-Schritt-Anleitung

Häufige Fehler und Lösungen

Alternative Methoden

Praktische Beispiele

Tipps für Profis

FAQ: Häufige Fragen

Beliebteste Forumthreads (12 Monate)