Excel-VBA Schleifen und vergleich

Hallo Liebe Forum Nutzer und Excel/VBA Experte,
ich persönlich arbeite seit einige Wochen mit VBA. Die Einarbeitung hat mit der zeit geklappt. Ich habe eine Aufgabe, welches ich durch VBA lösen muss. Habe leider aktuell dafür nicht genügend Wissen. Ich würde mich sehr freuen, wenn mir jemand hierbei helfen würde.. Muss die Aufgabe nächste Woche abgeben und hab richtig schiss :/
Meine Aufgabe ist:
Im Excel habe ich 3 Registerkarten. im 1. Registerkarten stehen Daten in einer Tabelle die von irgendeiner Quelle geholt wurden. In dieser Tabelle sind IDs, Namen, Aufgaben usw. aufgelistet. Jedoch sind nicht alle ID und Namen vorhanden, die volständige Liste der IDs und Namen sind in der 2.Registerkarte aufgelistet. Mein Problem ist jetzt: Durch ein Button soll es möglich sein mit schleifen die einzelnen id und namen in 1.Registerkarte mit der 2.Registerkarte zu vergleichen und wenn eine Übereinstimmung gibt, sollen dann die id und namen und aufgaben in die 3.Registerkarte aufgeschrieben bzw, eingefügt werden. ABER: Wenn mit der ID die im 2.Registerkarte keine Übereinstimmungen im 1.Registerkarte ist, dann soll die ID trotzdem in die 3.Registerkarte eingefügt werden und die spalten für Aufgabe einfach leer gelassen werden.
Das ist meine Aufgabe mit dem ich seit Wochen herumkämpfe, er wäre wirklich sehr nett und lieb, wenn einer mir den richtigen weg zeigen würde.
Liebe Grüße
Euer Forum-Neuling

Hey hey,
just my two cents, hier ein ganz anderer Ansatz:
1) In ein normales Modul:

Sub machen()
' Tabelle1
Dim r1 As Range
Set r1 = Tabelle1.Cells(1, 1).CurrentRegion
Set r1 = r1.Resize(r1.Rows.Count - 1).Offset(1)
' Dictionary
Dim e   As Variant
Dim dict As Object
Set dict = CreateObject("Scripting.Dictionary")
Dim Mitarbeiter As clsStaff
' Tabelle1 zeilenweise dem Object Mitarbeiter zuweisen und dann ins Dictionary schreiben
For Each e In r1.Rows
' Neue Instanz von Mitarbeiter erzeugen
Set Mitarbeiter = New clsStaff
' Felder des Objectes Mitarbeiter mit Werten der akt. Zeile füllen
With Mitarbeiter
.ID = e.Cells(1, 1)
.Name = e.Cells(1, 2)
.Aufgabe = e.Cells(1, 3)
.Schwierigkeitsgrad = e.Cells(1, 4)
.Kentnisse = e.Cells(1, 5)
End With
' Object Mitarbeiter ins Dictionary schreiben
dict.Add Mitarbeiter.ID, Mitarbeiter
' Nächste Zeile
Next e
' Tabelle2
Dim r2 As Range
Set r2 = Tabelle2.Cells(1, 1).CurrentRegion
Set r2 = r2.Resize(r2.Rows.Count - 1).Offset(1)
' Werte aus Tabelle 2 ins Dictionary schreiben.
' Im Dictionary ist die ID Primärschlüssel (unique).
' Gibt es die ID aus Tabelle2 im Dictionary wird kein weiterer Eintrag
' angelgt
For Each e In r2.Rows
Set Mitarbeiter = New clsStaff
With Mitarbeiter
.ID = e.Cells(1, 1)
.Name = e.Cells(1, 2)
End With
' ID-Check
If Not dict.exists(Mitarbeiter.ID) Then
dict.Add Mitarbeiter.ID, Mitarbeiter
End If
Next e
' Dictionary in Tabelle3 schreiben
Dim t3 As Range
Set t3 = Tabelle3.Cells(1, 1)
Dim i As Long
i = 1
' Alte Werte in Tabelle3 löschen
With t3
If .Cells(1, 1).CurrentRegion.Rows.Count > 1 Then
'.Cells(1, 1).CurrentRegion.Offset(1, 0).Resize(.CurrentRegion.Rows.Count - 1). _
Interior.Color = rgbAliceBlue
.Cells(1, 1).CurrentRegion.Offset(1, 0).Resize(.CurrentRegion.Rows.Count - 1).Clear
End If
' Dictionary durchlaufen und Werte schreiben
For Each e In dict.items
' Spaltenoffset
With .Offset(i, 0)
.Offset(0, 0) = e.ID
.Offset(0, 1) = e.Name
.Offset(0, 2) = e.Aufgabe
.Offset(0, 3) = e.Schwierigkeitsgrad
.Offset(0, 4) = e.Kentnisse
End With
' Zeilenzähler
i = i + 1
Next e
End With
End Sub

2) Klassenmodul einfügen und in clsStaff umbenennen
3) In Klassenmodul einfügen:

Public ID As String
Public Name As String
Public Aufgabe As String
Public Schwierigkeitsgrad As String
Public Kentnisse As String

Viel Spass beim Ausprobieren und Lernen!!
Christian

Excel-VBA Schleifen und vergleich

Forumthread: Excel-VBA Schleifen und vergleich

14
Beiträge zum Forumthread

Beiträge zu diesem Forumthread

Infobox / Tutorial