Daten von Excel nach Word

Guten Morgen,
ich würde gerne in einem Word Dokument bestimmte Textmarken in Abhängigkeit eines Rich-Text-Inhaltselementes im selben Word Dokument mit Werten aus einer Excel Tabelle ausfüllen lassen.
Ich habe also 1 Word Dokument und 1 Excel Dokument.
Das Excel Dokument kann als "Datenbank" angesehen werden, dort sind die Daten auf 2 Mappen ("Mappe 1" und "Mappe 2") wie folgt aufgelistet:
Spalte A Spalte B Spalte C
Typ A 1000 50
Typ B 900 30
Typ C 700 20
Wenn in dem Word Dokument nun das erste Rich-Text-Inhaltselement den Wert "Typ A" erhält, soll bei "Textmarke1" der Wert "1000" stehen und bei "Textmarke 2" der Wert 50. Beinhaltet das Rich-Text-Inhalteselement den Wert "Typ" soll bei "Textmarke 1" die Zahl "900" erscheinen und bei "Textmarke 2" der Wert "30".
Wie genau kann man das anstellen?
Ich habe bisher rausgefunden, wie ich in Abhängigkeit des Wertes des Rich-Text-Elementes die Textmarken ausfüllen kann.
If ActiveDocument.ContentControls(1).Range.Text = "Typ A" Then
ActiveDocument.Bookmarks("Textmarke1").Range.Text = "Test"
Anstelle von "Test" müsste ich dort auf die Excel Tabelle referenzieren, dann auf die korrekte Mappe, den korrekten Wert (also beispielsweise "Typ A") bzw. die Zeile suchen in der es steht und dann die entsprechenden dazugehörigen Werte aus den anderen Spalten in die Word Textmarken übertragen.
Könnte mir hierbei jemand weiterhelfen? Habe leider nur Basikenntnisse in VBA und verstehe nicht, wie ich meine Gedanken realisieren kann.
Vielen Dank für eure Hilfe :)
Gruß,
Stephan

Beiträge zum Forumthread

Beiträge zu diesem Forumthread

Betreff

Datum

Anwender

Hallo Stephan,
so schnell hat man das dann auch nicht zusammengestellt, denn es müssen verschiedene Fehler berücksichtigt werden.
Das folgende Word-Makro greift sich standardmäßig als Quelle die aktive Arbeitsmappe im geöffneten Excel. Wenn Excel geschlossen oder keine Mappe geöffnet, dnn wird ein Dateiauswahldialog angezeigt.
LG
Franz

'Makro in Word - erstellt unter Office 365
Sub Test_Daten_von_Excel_holen()
Dim varTyp
Dim wdDoc As Document
Dim xlZeile As Long
Dim xlWorksheet As Object
Dim xlApp As Object
Dim xlWorkbook As Object
Dim xlRange As Object
On Error GoTo Fehler
Set wdDoc = ActiveDocument
varTyp = wdDoc.ContentControls(1).Range.Text
'geöfnete Excelanwendung einer Variablen zuweisen
Set xlApp = VBA.GetObject(, "Excel.Application")
xlApp.Visible = True
'Active Arbeitsmappe einer Variablen zuweisen
Set xlWorkbook = xlApp.activeworkbook
'1. Tabellenblatt der Mappe einer Variablen zuweisen
Set xlWorksheet = xlWorkbook.worksheets(1)
With xlWorksheet
'Typ aus Word in Spalte A des Tabellenblatts suchen
Set xlRange = .Columns(1).Find(What:=varTyp, LookIn:=-4163, lookat:=1) '-4163=xlvalues,  _
1 = xlWhole
If xlRange Is Nothing Then
'            wdDoc.Bookmarks("Spalte_B").Range.Text = ""
'            wdDoc.Bookmarks("Spalte_C").Range.Text = ""
MsgBox "Type """ & varTyp & """ in Excelliste nicht vorhanden"
Else
xlZeile = xlRange.Row
'Namen der Textmarken anpassen'
wdDoc.Bookmarks("Spalte_B").Range.Text = .Cells(xlZeile, 2).Text
wdDoc.Bookmarks("Spalte_C").Range.Text = .Cells(xlZeile, 3).Text
End If
End With
Fehler:
With Err
Select Case .Number
Case 0 'alles OK
Case 429 ' Active-X komponente kann nicht erstellt werden (Excel ist nicht geöfnet)
Set xlApp = VBA.CreateObject("Excel.Application")
xlApp.Visible = True
Resume Next
Case 91 'Objektfehler - in Excel ist keine Datei geöffnet
'Dateiauswahldialog anzeigen
With xlApp.FileDialog(msoFileDialogOpen)
.AllowMultiSelect = False
.Title = "Bitte Datei mit den Typ-Daten für Word öffnen"
If .Show = -1 Then
xlApp.Visible = True
Set xlWorkbook = xlApp.Workbooks.Open(.SelectedItems(1))
Resume
Else
Exit Sub
End If
End With
Case Else
MsgBox "Fehler-Nr.: " & .Number & vbLf & .Description, _
vbOKOnly, "Makro: Test_Daten_von_Excel_holen"
End Select
End With
End Sub

Beliebteste Forumthreads (12 Monate)

3 Beiträge zum Forumthread Beiträge zu diesem Forumthread

Beliebteste Forumthreads (12 Monate)

Beliebteste Forumthreads (12 Monate)

3
Beiträge zum Forumthread

Beiträge zu diesem Forumthread