Listbox mit indirekten Bezug

Private Sub ReadWrite_ListBox_DB_select(ByVal bolRead As Boolean)
'markierte Zeilen in Listbox selektieren (bolRead = True) _
oder Listbox-Auswahl in Tabelle eintragen bolRead = False)
Dim iItem As Integer
Dim strSource As String
Dim wksSource As Worksheet, strRange As String
'Datenquelle aus Eigenschaften der Listbox in Variable einlesen und ggf _
Hochkommata entfernen
strSource = Replace(Me.ListBox_DB_select.RowSource, "'", "")
'Tabellenblatt mit Quelldaten setzen
Set wksSource = ThisWorkbook.Worksheets(Left(strSource, InStr(1, strSource, "!") - 1))
'Zellbereich der Quelle auslesen
strRange = Mid(strSource, InStr(1, strSource, "!") + 1)
With wksSource.Range(strRange)
For iItem = 0 To Me.ListBox_DB_select.ListCount - 1
If bolRead = True Then
'ggf. Eintrag in Listbox markieren
Me.ListBox_DB_select.Selected(iItem) = _
LCase(.Cells(iItem + 1, 1).Offset(0, 3).Value) = "x"
Else
'Eintrag in Tabellenblatt markieren
If Me.ListBox_DB_select.Selected(iItem) = True Then
.Cells(iItem + 1, 1).Offset(0, 3).Value = "x"
Else
.Cells(iItem + 1, 1).Offset(0, 3).Value = "o"
End If
End If
Next
End With
End Sub

Private Sub CommandButton1_Click()
If bolInit = True Then Exit Sub
Call ReadWrite_ListBox_DB_select(bolRead:=False)
End Sub

Private Sub CommandButton2_Click()
Unload Me
End Sub

Private Sub UserForm_Initialize()
'markierte Zeilen in Tabelle in Listbox selektieren
bolInit = True
Call ReadWrite_ListBox_DB_select(bolRead:=True)
bolInit = False
End Sub