Pfad per Formel aufteilen

Forumthread: Pfad per Formel aufteilen

02.07.2024 15:47:39

Dino

Hallo Leute,

wie kann ich bitte per Formel das letzte Verzeichnis und, von links aus gesehen, das dritte Verzeichnis auslesen?

A1=M:\Vorlagen\BA-SAR01\Einstellungen\projects\Sanofi\18-LOG\08_Planunterlagen\B-000549_tm1_stz\E04\etagenliste.txt

B1 als Ergebnis soll: E04 sein
C1 als Ergebnis soll: Einstellungen sein

Beste Grüße,
Dino

4
Beiträge zum Forumthread

Beiträge zu diesem Forumthread

Betreff

Datum

Anwender

AW: Pfad per Formel aufteilen

02.07.2024 16:22:58

daniel
AW: Pfad per Formel aufteilen

02.07.2024 18:12:48

Uduuh
AW: Pfad per Formel aufteilen

03.07.2024 10:58:13

daniel
AW: Pfad per Formel aufteilen

02.07.2024 21:01:14

Dino

AW: Pfad per Formel aufteilen

02.07.2024 16:22:58

daniel

B1:

=INDEX(XMLFILTERN("&ltx&gt&lty&gt"&WECHSELN(A1;"\";"&lt/y&gt&lty&gt")&"&lt/y&gt&lt/x&gt";"//x/y");ANZAHL2(XMLFILTERN("&ltx&gt&lty&gt"&WECHSELN(A1;"\";"&lt/y&gt&lty&gt")&"&lt/y&gt&lt/x&gt";"//x/y"))-1)

C1:

=INDEX(XMLFILTERN("&ltx&gt&lty&gt"&WECHSELN(A1;"\";"&lt/y&gt&lty&gt")&"&lt/y&gt&lt/x&gt";"//x/y");4)

Gruß Daniel

AW: Pfad per Formel aufteilen

02.07.2024 18:12:48

Uduuh

Hallo,
oder mit einfachen Textfunktionen

B1: =LINKS(TEIL(WECHSELN(A1;"\";"#";3);FINDEN("#";WECHSELN(A1;"\";"#";3))+1;99);FINDEN("\";TEIL(WECHSELN(A1;"\";"#";3);FINDEN("#";WECHSELN(A1;"\";"#";3))+1;99))-1)

C1: =LINKS(TEIL(WECHSELN(A1;"\";"#";LÄNGE(A1)-LÄNGE(WECHSELN(A1;"\";""))-1);FINDEN("#";WECHSELN(A1;"\";"#";LÄNGE(A1)-LÄNGE(WECHSELN(A1;"\";""))-1))+1;99);FINDEN("\";TEIL(WECHSELN(A1;"\";"#";LÄNGE(A1)-LÄNGE(WECHSELN(A1;"\";""))-1);FINDEN("#";WECHSELN(A1;"\";"#";LÄNGE(A1)-LÄNGE(WECHSELN(A1;"\";""))-1))+1;99))-1)

Wahrscheinlich würde ich die sich wiederholenden Formelbestandteile um der Übersicht willen in Hilfszellen auslagern.

Gruß aus'm Pott
Udo

AW: Pfad per Formel aufteilen

03.07.2024 10:58:13

daniel

Hallo
bei aktuellem Excel mit den verbesserten Textfunktionen könnten die Formeln so aussehen:

B1:
=TEXTNACH(TEXTVOR(A1;"\";-1);"\";-1)
=LET(x;TEXTTEILEN(A1;"\");INDEX(x;ANZAHL2(x)-1))

C1:
=TEXTVOR(TEXTNACH(A1;"\";3);"\")
=INDEX(TEXTTEILEN(A1;"\");4)

nur falls jemand sich fragt, ob es sich lohnt auf die neuen Excelversionen umzusteigen.

Gruß Daniel

AW: Pfad per Formel aufteilen

02.07.2024 21:01:14

Dino

Vielen Dank Daniel und Udo

Beliebteste Forumthreads (12 Monate)

Forumthread: Pfad per Formel aufteilen

4 Beiträge zum Forumthread Beiträge zu diesem Forumthread

VBA Beispiele zu diesem und ähnlichen Themen

Beliebteste Forumthreads (12 Monate)

4
Beiträge zum Forumthread

Beiträge zu diesem Forumthread