Pulldown-Menü/CommondBars

Hallo!
Habe ein paar Fragen zu den commondbars.
Benutze folgenden Code:
' Objektavariable für Arbeitsblattmenüleiste besetzen
Set cbrMain = Application.CommandBars("Worksheet Menu Bar")
' Neues Menü vor dem letzten Menüelement hinzufügen
Set ctlMain = cbrMain.Controls.Add( _
Type:=msoControlPopup, _
Before:=cbrMain.Controls.Count)
' Aufschrift festlegen
ctlMain.Caption = "Test Menü"

Set ctlSub = ctlMain.Controls.Add(Type:=msoControlButton)
With ctlSub
.Caption = "Test Makro wird gestartet"
.OnAction = "Test_Makro"
End With
-----------------------------------------------------------
Kann man hier auch bei with ctlsub .caption den text einfärben oder Fett schreiben?
Ist es möglich dem ControlButton ein Bild anzuzeigen (wie bei Einfügen/Diagramm)?
Wie kann man bei mehreren Controlbuttons eine Trennlinie erzeugen (wie bei Einfügen, zwischen Symbol und Seitenumbruch)?
Wie kann ich Untermnenüs erzeugen (wie bei Format/Zeile) ?
Habe 2 ControlButton, einen für alle Blätter schützen und einen für alle Blätter entschützen. Wie kann ich vor den jeweils aktiven Button einen Hacken erzeugen. Beim Start soll immer vor dem Blätter schützen ein Hacken sein.
Danke!
Berger

Beiträge zum Forumthread

Beiträge zu diesem Forumthread

Betreff

Datum

Anwender

Hallo,
Schrift in Menüs fett/farbig geht nicht!
hier mal ein Beispiel, das deine Fragen beantwortet:
Option Explicit
Const MENUNAME As String = "Testmenü"


Sub Beisielmenu()
Dim cb As CommandBar, cbb As CommandBarControl
On Error Resume Next
CommandBars(MENUNAME).Delete
On Error GoTo 0
'Commandbar erstellen
Set cb = CommandBars.Add(MENUNAME)
'Button 1 Icon und Text erzeugen
Set cbb = cb.Controls.Add(msoControlButton)
With cbb
.OnAction = "Test1"
.Caption = "Taste"
.FaceId = 222
.Style = msoButtonIconAndCaption
.TooltipText = "Taste mit Icon und Caption"
End With
'Button 2 nur Icon erzeugen
Set cbb = cb.Controls.Add(msoControlButton)
With cbb
.OnAction = "Test1"
.FaceId = 333
.Style = msoButtonIcon
.TooltipText = "Taste nur Icon"
.BeginGroup = True
End With
'Menü erzeugen
Set cbb = cb.Controls.Add(msoControlPopup)
With cbb
.Caption = "Ich bin ein Popup Menü"
.Tag = "Pop1"
.BeginGroup = True
End With
'Menüzeilen erstellen
With CommandBars.FindControl(Tag:="Pop1")
'erste Menüzeile erzeugen
Set cbb = .Controls.Add(Before:=1, Type:=msoControlButton)
With cbb
.Caption = "erste Aktion"
.OnAction = "Test1"
.FaceId = 444
.BeginGroup = True
End With
'zweite Menüzeile erzeugen
Set cbb = .Controls.Add(Before:=2, Type:=msoControlButton)
With cbb
.Caption = "zweite Aktion"
.OnAction = "Test1"
.FaceId = 445
End With
'dritte Menüzeile erzeugen bzw. Untermenü
Set cbb = .Controls.Add(msoControlPopup)
With cbb
.Caption = "Ich bin ein Flyout"
.BeginGroup = True
.Tag = "Fly1"
End With
'Untermenüzeilen erstellen
With CommandBars.FindControl(Tag:="Fly1")
'erste Untermenüzeile erzeugen
Set cbb = .Controls.Add(Before:=1, Type:=msoControlButton)
With cbb
.Caption = "Flyout Button1"
.OnAction = "Test1"
.FaceId = 24
End With
'zweite Untermenüzeile erzeugen
Set cbb = .Controls.Add(Before:=2, Type:=msoControlButton)
With cbb
.Caption = "Flyout Button2"
.OnAction = "Test1"
.FaceId = 610
End With
End With
End With
With cb
'Togglebutton (Umschaltfläche) erzeugen.
Set cbb = .Controls.Add(msoControlButton)
With cbb
.Caption = "Position"
.Style = msoButtonIconAndCaption
.FaceId = 40
.OnAction = "Ein_Aus"
.State = msoButtonUp
.BeginGroup = True
.Tag = "Tog1"
End With
.Visible = True
.Position = msoBarTop
.Protection = 9
End With
End Sub


Sub Commandbar_löschen()
On Error Resume Next
CommandBars(MENUNAME).Delete
End Sub


Sub Ein_Aus()
With CommandBars.FindControl(Tag:="Tog1")
If .State = msoButtonDown Then
.State = msoButtonUp
.FaceId = 40
CommandBars(MENUNAME).Position = msoBarTop
Else
.State = msoButtonDown
.FaceId = 38
CommandBars(MENUNAME).Position = msoBarBottom
End If
End With
End Sub


Sub Test1()
MsgBox "Control in neuer Leiste geklickt!"
End Sub

Gruß K.Rola

Beliebteste Forumthreads (12 Monate)

4 Beiträge zum Forumthread Beiträge zu diesem Forumthread

Beliebteste Forumthreads (12 Monate)

Beliebteste Forumthreads (12 Monate)

4
Beiträge zum Forumthread

Beiträge zu diesem Forumthread