mp3 in Excel abspielen

Tobias Schleifer · 2005-12-25T22:42:45+00:00

Hallo zusammmen, ich habe eine ganz verrückte Idee (habe aber keine Idee, ob das überhaupt umsetzbar ist): Gibt es die Mögöichkeit in Excel eine mp3-Datei automatisch abspielen zu lassen, wenn in einem bestimmten Feld (z.B. A1) der Feldinhalt den Wert 20 übersteigt ? Gruß Tobias PS: Ich bin neu in diesem Forum und ganz begeistert, was man in Excel so alles realisieren kann.

Hallo Tobias!
Ich nehme mal an, das der Wert in "A1" durch eine Formel errechnet wird!
Achte darauf, wo die einzelnen Codeteile hingehören!
' **********************************************************************
' Modul: DieseArbeitsmappe Typ: Element der Mappe(Sheet, Workbook, ...)
' **********************************************************************

Option Explicit

Private Sub Workbook_Deactivate()

' MP3-Wiedergabe stoppen
MP3_Stop "MyAlias"

End Sub

' **********************************************************************
' Modul: Tabelle1 Typ: Element der Mappe(Sheet, Workbook, ...)
' **********************************************************************

Option Explicit
Const myMP3 As String = "F:\iTunes\Bob Seger\Greatest Hits\09 Against The Wind.mp3" '<<-- deine mp3 - anpassen

Dim blnDontPlayAgain As Boolean

Private Sub Worksheet_Calculate()
If [A1] > 20 Then
  If Not blnDontPlayAgain Then

    ' MP3 abspielen
    MP3_Play myMP3, "MyAlias"

    blnDontPlayAgain = True

  End If

Else

  ' MP3-Wiedergabe stoppen
  MP3_Stop "MyAlias"

  blnDontPlayAgain = False

End If
End Sub

' **********************************************************************
' Modul: mdlPlayMP3 Typ: Allgemeines Modul
' **********************************************************************

' Modul MP3-Play and Stop via API
'Quelle: http://www.vbarchiv.net/archiv/tipp_499.html

Option Explicit

' zunächst die benötigte API-Deklaration
Private Declare Function mciSendString Lib "winmm.dll" _
  Alias "mciSendStringA" (ByVal lpszCommand As String, _
  ByVal lpszReturnString As String, _
  ByVal cchReturnLength As Long, _
  ByVal hwndCallback As Long) As Long

Private Declare Function GetShortPathName Lib "kernel32" _
  Alias "GetShortPathNameA" (ByVal lpszLongPath As String, _
  ByVal lpszShortPath As String, _
  ByVal cchBuffer As Long) As Long

' MP3-Datei abspielen
Public Function MP3_Play(ByVal sFile As String, _
  ByVal sAlias As String) As Boolean

Dim bResult As Boolean

' Dateinamen in DOS 8.3 Format, da z.B. Sonderzeichen
' wie Leerzeichen Probleme machen
Dim sBuffer As String
Dim lResult As Long

sBuffer = Space$(255)
lResult = GetShortPathName(sFile, sBuffer, Len(sBuffer))

If lResult <> 0 Then
  sFile = Left$(sBuffer, InStr(sBuffer, vbNullChar) - 1)

  ' MCI öffnen
  lResult = mciSendString("open " & sFile & _
    " type MPEGVideo alias " & sAlias, 0, 0, 0)

  If lResult = 0 Then
    ' MP3 abspielen
    If mciSendString("play " & sAlias & _
      " from 0", 0, 0, 0) = 0 Then
      bResult = True
    End If
  End If
End If

MP3_Play = bResult
End Function

' Wiedergabe stoppen und MCI schließen
Public Sub MP3_Stop(ByVal sAlias As String)
mciSendString "stop " & sAlias, 0, 0, 0
mciSendString "close " & sAlias, 0, 0, 0
End Sub

'******************************
'* Gruß Sepp
'*
'* Rückmeldung wäre nett!
'******************************

Ich bekomme nun einen Fehler beim Kompilieren, dass die Variable blnDontPlayAgain nicht definiert sei. Ich glaube es ist einfacher, wenn ich mein Dokument mal mitschicke. Innerhalb der Excel-Datei habe ich ein Arbeitsblatt "Tabelle1" eingerichtet, wo eben in A1 ein Wert steht (für diesen Test jetzt einfach die Summe aus (a2-a10). Es geht mir in dieser Datei um Sportwetten, später würde ich den Gewinn aus der aktuellen Woche da rein tun. Damit ich die Datei hier ins Forum stellen kann, habe ich sie deutlich abgespeckt.

Die Datei https://www.herber.de/bbs/user/29542.xls wurde aus Datenschutzgründen gelöscht

Meine mp3-Datei, die abgespielt werden soll, habe ich jetzt mal als abc.mp3 auf C: abgespeichert.

Forumthread: mp3 in Excel abspielen

9
Beiträge zum Forumthread

Beiträge zu diesem Forumthread

Infobox / Tutorial