Hilfe beim INDEX - Verweis | HERBERS Excel Forum

Forumthread: Hilfe beim INDEX - Verweis

Hilfe beim INDEX - Verweis

17.03.2006 16:56:41

Meister

Hallo zusammen,
habe mal wieder eine Denk-Blockade und hoffe jemand kann mir helfen.
Habe ein Beispiel hochgeladen:
https://www.herber.de/bbs/user/31994.xls
Gesucht ist die Zelle C3 (bei der Zelle B2 hat alles funktioniert)
Vielen Dank an alle
Greetz Daniel

8
Beiträge zum Forumthread

Beiträge zu diesem Forumthread

Betreff

Datum

Anwender

AW: Hilfe beim INDEX - Verweis

17.03.2006 17:32:40

HermannZ
AW: Hilfe beim INDEX - Verweis

17.03.2006 17:36:40

Pepper
AW: Hilfe beim INDEX - Verweis

17.03.2006 17:48:14

Pepper
AW: Hilfe beim INDEX - Verweis

17.03.2006 18:00:14

HermannZ
AW: Hilfe beim INDEX - Verweis

17.03.2006 18:16:07

Meister
AW: Hilfe beim INDEX - Verweis

17.03.2006 19:14:59

HermannZ
AW: DANKE!!!!!

17.03.2006 20:37:11

Daniel
AW: Hilfe beim INDEX - Verweis

17.03.2006 17:38:03

PeTeR

AW: Hilfe beim INDEX - Verweis

17.03.2006 17:32:40

HermannZ

Hallo Daniel;
eine Möglickeit; =INDEX(A7:A11;VERGLEICH(B3;WAHL(VERGLEICH(A3;B6:F6);B7:B11;C7:C11;D7:D11;E7:E11;F7:F11);0);1)
Gruß hermann

AW: Hilfe beim INDEX - Verweis

17.03.2006 17:36:40

Pepper

Vielen Dank......jetzt kann ich weiterarbeiten

AW: Hilfe beim INDEX - Verweis

17.03.2006 17:48:14

Pepper

Vielen Dank......jetzt kann ich weiterarbeiten
sorry ich muss mich nocheinmal korregieren.....
jetzt können nur die tatsächlich vorhandenen Werte wiedergefunden werden.
was ist aber, wenn ich eine zahl wie 17,5 oder ähnliches suche.....gibt es eine Rundungsfunktion?

AW: Hilfe beim INDEX - Verweis

17.03.2006 18:00:14

HermannZ

Hallo Daniel;
was soll denn in dem Fall zurückgegeben werden?
z.B für den nächst kleineren Wert =INDEX(A7:A11;VERGLEICH(B3;WAHL(VERGLEICH(A3;B6:F6);B7:B11;C7:C11;D7:D11;E7:E11;F7:F11));1)
oder für den nächst grösseren Wert =INDEX(A7:A11;VERGLEICH(B3;WAHL(VERGLEICH(A3;B6:F6);B7:B11;C7:C11;D7:D11;E7:E11;F7:F11))+1;1)
gruß hermann

AW: Hilfe beim INDEX - Verweis

17.03.2006 18:16:07

Meister

Hallo Hermann,
am liebsten wäre mir ein Mittelwert, d.H. >0,5 Aufrunden und Danke für deine Mühe.....
Gruß Daniel

AW: Hilfe beim INDEX - Verweis

17.03.2006 19:14:59

HermannZ

Hallo Daniel;
dazu fällt mir im Moment nur eine Lösung mit zwei Hilfszelle ein;
Beispiel;

	A	B	C	D	E	F
1	Kleinbuchst.	Zahl	Großbuchst.
2	c	18	D
3	c	9	B	8	13	<< Hilfszellen
4
5	Suchmatrix
6		a	b	c	d	e
7	A	1	2	3	4	5
8	B	6	7	8	9	10
9	C	11	12	13	14	15
10	D	16	17	18	19	20
11	E	21	22	23	24	25
12

Formeln der Tabelle

B2 : =INDEX(B7:F11;VERGLEICH(C2;A7:A11;0);VERGLEICH(A2;B6:F6;0))
C3 : =WENN(B3=D3;INDEX(A7:A11;VERGLEICH(B3;WAHL(VERGLEICH(A3;B6:F6);B7:B11;C7:C11;D7:D11;E7:E11;F7:F11);0);1);WENN(MITTELWERT(D3:E3)>B3;INDEX(A7:A11;VERGLEICH(D3;WAHL(VERGLEICH(A3;B6:F6);B7:B11;C7:C11;D7:D11;E7:E11;F7:F11);0);1);INDEX(A7:A11;VERGLEICH(E3;WAHL(VERGLEICH(A3;B6:F6);B7:B11;C7:C11;D7:D11;E7:E11;F7:F11);0);1)))
D3 : =INDEX(B7:F11;VERGLEICH(B3;WAHL(VERGLEICH(A3;B6:F6);B7:B11;C7:C11;D7:D11;E7:E11;F7:F11));VERGLEICH(A3;B6:F6))
E3 : =INDEX(B7:F11;VERGLEICH(B3;WAHL(VERGLEICH(A3;B6:F6);B7:B11;C7:C11;D7:D11;E7:E11;F7:F11))+1;VERGLEICH(A3;B6:F6))

Diagramm - Grafik - Excel Tabellen einfach im Web darstellen Excel Jeanie HTML 3.0 Download
Gruß hermann

AW: DANKE!!!!!

17.03.2006 20:37:11

Daniel

Hallo Hermann,
ja jetzt funktioniert es.....war bestimmt net so einfach.
Aber ich hab noch keine andere lösung gefunden...und VB kenntnisse hab ich auch keine.
Tausend Dank. bis demnächst !!!
Gruß Daniel

AW: Hilfe beim INDEX - Verweis

17.03.2006 17:38:03

PeTeR

Hallo Daniel,
die Formel lautet:
=INDEX(B7:F11;VERGLEICH(C2;A7:A11;0);VERGLEICH(A3;B6:F6;0))
Schönes Wochenende
PeTeR

Beliebteste Forumthreads (12 Monate)

Hilfe beim INDEX - Verweis

Forumthread: Hilfe beim INDEX - Verweis

8 Beiträge zum Forumthread Beiträge zu diesem Forumthread

VBA Beispiele zu diesem und ähnlichen Themen

Beliebteste Forumthreads (12 Monate)

8
Beiträge zum Forumthread

Beiträge zu diesem Forumthread