Live-Forum - Die aktuellen Beiträge
Anzeige
Archiv - Navigation
756to760
Aktuelles Verzeichnis
Verzeichnis Index
Übersicht Verzeichnisse
Vorheriger Thread
Rückwärts Blättern
Nächster Thread
Vorwärts blättern
Anzeige
HERBERS
Excel-Forum
20+ Jahre Excel-Kompetenz: Von Anwendern, für Anwender
756to760
756to760
Aktuelles Verzeichnis
Verzeichnis Index
Verzeichnis Index
Übersicht Verzeichnisse
Inhaltsverzeichnis

Sverweis per VBA

Sverweis per VBA
30.04.2006 23:08:06
ronaldo
Hallo,
ich weiss, dass schon viel über Sverweis im Archiv steht, aber ich finde einfach nicht die richtige Lösung für mein "einfaches" Problem. Ich habe zwei Dateien Datei1.xls und Datei2.xls
In Datei1.xls Spalte A stehen Zahlen. In Datei2.xls stehen ebenfalls Zahlen und daneben (also in Spalte B) stehen andere Werte. Per VBA muss jetzt überprüft werden, ob die Zahlen aus Datei1.xls in Datei2.xls vorhanden sind, wenn ja, muss der Wert daneben (aus Spalte B) in die Datei1.xls Spalte B übernommen werden.
Klingt kompliziert, ist es aber eigentlich nicht. Per Sverweis bekomme ich das hin, da es aber eine sehr große Datei ist, muss ich es per VBA machen.
Vielen Dank für Eure Hilfe im voraus
Gruss
Ronaldo

2
Beiträge zum Forumthread
Beiträge zu diesem Forumthread

Betreff
Datum
Anwender
Anzeige
AW: Sverweis per VBA
30.04.2006 23:39:51
Josef
Hallo Ronaldo!
Ich hab' mal angenommen, das die Daten ab Zeile zwei stehen!
Probier es mal so.
' **********************************************************************
' Modul: Modul2 Typ: Allgemeines Modul
' **********************************************************************

Option Explicit

Sub GetData()
Dim objWB As Workbook
Dim objShA As Worksheet, objShB As Worksheet
Dim strFile As String
Dim varB As Variant
Dim lngC As Long
Dim rng As Range

On Error GoTo ErrExit

With Application
  .ScreenUpdating = False
  .EnableEvents = False
  .DisplayAlerts = False
  .Calculation = xlCalculationManual
  .Cursor = xlWait
End With

strFile = "F:\Temp\test\Datei2.xls" ' Pfad zur Datei - Anpassen!

Set objShA = ThisWorkbook.Sheets("Tabelle1") ' Tabelle in Datei1 - Anpassen!
Set objWB = GetObject(strFile)
Set objShB = objWB.Sheets("Tabelle1") ' Tabelle in Datei2 - Anpassen!

With objShB
  varB = .Range("A2:B" & .Cells(Rows.Count, 1).End(xlUp).Row)
End With

objWB.Close False

objShA.Range("B2:B65536").ClearContents

For lngC = 1 To UBound(varB, 1)
  If varB(lngC, 1) <> "" Then
    Set rng = objShA.Range("A:A").Find(varB(lngC, 1))
    If Not rng Is Nothing Then rng.Offset(0, 1) = varB(lngC, 2)
  End If
Next

ErrExit:

If Err.Number > 0 Then
  MsgBox Err.Number & vbLf & Err.Description, , "Fehler"
  Err.Clear
End If

Set objShA = Nothing
Set objWB = Nothing
Set objShB = Nothing

With Application
  .ScreenUpdating = True
  .EnableEvents = True
  .DisplayAlerts = True
  .Calculation = xlCalculationAutomatic
  .Cursor = xlDefault
End With

End Sub


'******************************
'* Gruß Sepp
'*
'* Rückmeldung wäre nett!
'******************************

Anzeige
AW: Sverweis per VBA
01.05.2006 00:52:33
ronaldo
Hallo Josef,
vielen vielen Dank für Deine Antwort ! Ich bin schon die ganze Zeit am testen.
Es funktioniert ! :-)
Vielen Dank nochmal !
Gruss
Ronaldo

Beliebteste Forumthreads (12 Monate)

Anzeige

Beliebteste Forumthreads (12 Monate)

Anzeige
Anzeige
Anzeige