Werte herausziehen

Forumthread: Werte herausziehen

Werte herausziehen

08.05.2006 16:54:27

Frank

Hallo habe von einem Großrechner zahlen, die wie folgt aufgebaut sind:
A B C
ga 12 234000
bh 23 345600
zh 14 565655
....
Nun sollen die Werte in eine Tabelle übernommen werden, wenn die beiden ersten Spalten übereinstimmen, in etwa so:
A B C D E
12 14 16 23
ga
bh
zh
er
Also: suche in der ersten Tabelle nach dem Wert für ga-12 und setze ihn in Zelle B2 etc.
Es kann auch sein, das eine "Kreuzung" keine Werte in der Quelltabelle hat (z.B.bh-16)
Würde mich sehr über einen Lösungsvorschlag freuen. Habs schon mit SUMMEWENN, INDEX etc. versucht - bisher ohne Erfolg.
Schon mal Danke
Frank

2
Beiträge zum Forumthread

Beiträge zu diesem Forumthread

Betreff

Datum

Anwender

AW: Werte herausziehen

08.05.2006 18:59:39

Erich
AW: Werte herausziehen

10.05.2006 13:37:39

Frank

AW: Werte herausziehen

08.05.2006 18:59:39

Erich

Hallo Frank,
zwei mögliche Lösungen (& "|" habe ich nur für die 1. Lösung eingefügt, ist evtl. unnötig):

Quelle

	A	B	C
1	ga	12	234000
2	bh	23	345600
3	zh	14	565655
4	bh	16	77777

Erg1

	A	B	C	D	E
1		12	14	16	23
2	ga	234000
3	bh			77777	345600
4	zh		565655
5	er

Formeln der Tabelle

B2 : {=WENN(ISTNV(VERGLEICH($A2&"|"&B$1;Quelle!$A$1:$A$10&"|"&Quelle!$B$1:$B$10;0));""; INDEX(Quelle!$C$1:$C$10;VERGLEICH($A2&"|"&B$1;Quelle!$A$1:$A$10&"|"&Quelle!$B$1:$B$10;0)))}
C2 : {=WENN(ISTNV(VERGLEICH($A2&"|"&C$1;Quelle!$A$1:$A$10&"|"&Quelle!$B$1:$B$10;0));""; INDEX(Quelle!$C$1:$C$10;VERGLEICH($A2&"|"&C$1;Quelle!$A$1:$A$10&"|"&Quelle!$B$1:$B$10;0)))}
B3 : {=WENN(ISTNV(VERGLEICH($A3&"|"&B$1;Quelle!$A$1:$A$10&"|"&Quelle!$B$1:$B$10;0));""; INDEX(Quelle!$C$1:$C$10;VERGLEICH($A3&"|"&B$1;Quelle!$A$1:$A$10&"|"&Quelle!$B$1:$B$10;0)))}
Enthält Matrixformel:
Umrandende { } nicht miteingeben,
sondern Formel mit STRG+SHIFT+RETURN abschließen!

Erg2

	A	B	C	D	E
1		12	14	16	23
2	ga	234000
3	bh			77777	345600
4	zh		565655
5	er

Formeln der Tabelle

B2 : =WENN(ISTNV(VERWEIS(2;1/(Quelle!$A$1:$A$10&Quelle!$B$1:$B$10=$A2&B$1);Quelle!$C$1:$C$10));""; VERWEIS(2;1/(Quelle!$A$1:$A$10&Quelle!$B$1:$B$10=$A2&B$1);Quelle!$C$1:$C$10))
C2 : =WENN(ISTNV(VERWEIS(2;1/(Quelle!$A$1:$A$10&Quelle!$B$1:$B$10=$A2&C$1);Quelle!$C$1:$C$10));""; VERWEIS(2;1/(Quelle!$A$1:$A$10&Quelle!$B$1:$B$10=$A2&C$1);Quelle!$C$1:$C$10))
B3 : =WENN(ISTNV(VERWEIS(2;1/(Quelle!$A$1:$A$10&Quelle!$B$1:$B$10=$A3&B$1);Quelle!$C$1:$C$10));""; VERWEIS(2;1/(Quelle!$A$1:$A$10&Quelle!$B$1:$B$10=$A3&B$1);Quelle!$C$1:$C$10))

Diagramm - Grafik - Excel Tabellen einfach im Web darstellen Excel Jeanie HTML 3.0 Download
Rückmeldung wäre nett! - Grüße von Erich aus Kamp-Lintfort

AW: Werte herausziehen

10.05.2006 13:37:39

Frank

Hallo Erich,
hat wunderbar geklappt: vielen lieben Dank (kann erst heute antworten, da ich gestern auf ner Veranstaltung in Köln war)
Gruß
Frank

Beliebteste Forumthreads (12 Monate)

Forumthread: Werte herausziehen

2 Beiträge zum Forumthread Beiträge zu diesem Forumthread

Beliebteste Forumthreads (12 Monate)

2
Beiträge zum Forumthread

Beiträge zu diesem Forumthread