Felder auslesen

Forumthread: Felder auslesen

Felder auslesen

19.04.2007 16:11:19

Marcel

Hallo zusammen,
ich hab 200 Adressen in einer einzigen Spalte in Excel die wie folgt aufgebaut ist:
A1 = Name
A2 = Straße
A3 = PLZ & Ort
A4 - A8 = Informationen die ich nicht brauche
A9 = Leer
A10 = Name
A11 = Straße
A12 = PLZ & Ort
A13 - A17 = Informationen die ich nicht brauche
A18 = Leer
usw.
Die Abstände sind immer die gleichen also A1, A1+9, A10+9 usw. da steht immer der Name. A2, A2+9, A11+9 usw. da steht immer die Straße.
Ich würde gerne in einem zweiten Arbeitsblatt nur Name, Straße und PLZ & Ort auslesen.
A1_Tabelle1 = A1_Tabelle2, A10_Tabelle1 = A2_Tabelle2 usw. - nur Namen sollen in Spalte A
A2_Tabelle1 = B1_Tabelle2, A11_Tabelle1 = B2_Tabelle2 usw. - nur Namen sollen in Spalte B
A3_Tabelle1 = C1_Tabelle2, A12_Tabelle1 = C2_Tabelle2 usw. - nur Namen sollen in Spalte C
Ganz schön schwer zu beschreiben. Aber im Prinzip ganz simpel.
Ich weiss nur nicht wie ich Excel das beibringen soll :)
Gruß
Marcel

2
Beiträge zum Forumthread

Beiträge zu diesem Forumthread

Betreff

Datum

Anwender

AW: Felder auslesen

19.04.2007 16:38:00

Peter
AW: Felder auslesen

19.04.2007 16:54:26

Peter

AW: Felder auslesen

19.04.2007 16:38:00

Peter

Hallo Marcel,
das beigefügte Makro sollte helfen:

Option Explicit
'
'   A1 = Name
'   A2 = Straße
'   A3 = PLZ & Ort
'   A4 - A8 = Informationen die ich nicht brauche
'   A9 = Leer
'
'   A10 = Name
'   A11 = Straße
'   A12 = PLZ & Ort
'   A13 - A17 = Informationen die ich nicht brauche
'   A18 = Leer
'
'   usw.
'
Public Sub Trennen()
Dim WkSh_Q    As Worksheet
Dim Wksh_Z    As Worksheet
Dim lZeile_Q  As Long
Dim lZeile_Z  As Long
   Application.ScreenUpdating = False
   Set WkSh_Q = Worksheets("Tabelle1") ' <=== den Tabellenblattnamen ggf. anpassen !!!
   Set Wksh_Z = Worksheets("Tabelle2") ' <=== den Tabellenblattnamen ggf. anpassen !!!
   lZeile_Z = 2  ' der Beginn der Ausgabedaten ist Zeile 2 - ggf. anpassen
   WkSh_Q.Activate
   For lZeile_Q = 1 To Range("A65536").End(xlUp).Row Step 9
      Wksh_Z.Range("A" & lZeile_Z).Value = WkSh_Q.Range("A" & lZeile_Q + 0).Value
      Wksh_Z.Range("B" & lZeile_Z).Value = WkSh_Q.Range("A" & lZeile_Q + 1).Value
      Wksh_Z.Range("C" & lZeile_Z).Value = WkSh_Q.Range("A" & lZeile_Q + 2).Value
      lZeile_Z = lZeile_Z + 1
   Next lZeile_Q
   Application.ScreenUpdating = True
End Sub

Gruß Peter

AW: Felder auslesen

19.04.2007 16:54:26

Peter

Hallo Marcel,
wenn du Postleitzahl und Straßennamen getrennt haben möchtest und die Postlz immer 5-stellig ist,
dann ändere so:
Wksh_Z.Range("C" & lZeile_Z).Value = _
Left(WkSh_Q.Range("A" & lZeile_Q + 2).Value, 5)
Wksh_Z.Range("D" & lZeile_Z).Value = _
Mid(WkSh_Q.Range("A" & lZeile_Q + 2).Value, 7)
Gruß Peter

Beliebteste Forumthreads (12 Monate)

Forumthread: Felder auslesen

2 Beiträge zum Forumthread Beiträge zu diesem Forumthread

VBA Beispiele zu diesem und ähnlichen Themen

Beliebteste Forumthreads (12 Monate)

2
Beiträge zum Forumthread

Beiträge zu diesem Forumthread