AW: die nächsten 10 Termine
28.08.2007 21:17:36
fcs
Hallo Steffen,
die Formel ist schon relativ komplex. Dadurch, dass die Matrix, die als Eingabe für die Funktion KKLEINSTE erforderlich ist durch die als Matrixformel arbeitende WENN-Formel generiert wird.
Die WENN-Bedingung
WENN(B$1:B$99<=HEUTE();9^9;B$1:B$99)
sorgt dafür, dass allen Werten im Bereich B1:B99, die älter oder gleich Heute sind der Wert 9^9 (9 hoch 9 = 387420489) zugewiesen wird, während alle zukünftigen Tage Ihren Wert behalten. Gültige Datumswerte in Excel vom 1.1.1900 bis zum 31.12.9999 haben excelintern die Werte 1 bis 2958465. 9^9 ist größer als der max. Datumswert und so werden durch die KKLEINSTE-Funktion die in der Vergangenheit liegenden Datums-Werte erst am Ende der Reihenfolge berücksichtigt. Für korrekte Funktion könntets du statt 9^9 auch 3000000 in der Formel eingeben.
Du wolltest ja eigentlich nicht nur die Datumswerte der nächsten 10 Tage ermitteln, sondern auch die zugehörigen Namen und ggf. andere Daten in der Liste.
Hierzu benötigst du eine weiter Hilfsspalte in der berechnet wird in welcher Tabellenzeile die gefundenen Datumswerte stehen. Über die Tabellenzeile kannst du dann mit der Funktion INDEX die zugehörigen Daten ermitteln.
Gruß
Franz
Nachfolgend ein Tabellenbeispiel mit den entsprechenden Formeln
Tabellenblattname: Tab1
A B C D E F G H
1 Name Vorname Fälligkeit Datum Name Vorname Hilfsspalte
2 Name 23 Vorname 23 03.09.07 29.08.07 Name 10 Vorname 10 15
3 Name 22 Vorname 22 10.09.07 30.08.07 Name 12 Vorname 12 13
4 Name 21 Vorname 21 09.09.07 30.08.07 Name 11 Vorname 11 14
5 Name 20 Vorname 20 08.09.07 01.09.07 Name 13 Vorname 13 12
6 Name 19 Vorname 19 07.09.07 02.09.07 Name 14 Vorname 14 11
7 Name 18 Vorname 18 06.09.07 03.09.07 Name 23 Vorname 23 2
8 Name 17 Vorname 17 05.09.07 03.09.07 Name 15 Vorname 15 10
9 Name 16 Vorname 16 04.09.07 04.09.07 Name 16 Vorname 16 9
10 Name 15 Vorname 15 03.09.07 05.09.07 Name 17 Vorname 17 8
11 Name 14 Vorname 14 02.09.07 06.09.07 Name 18 Vorname 18 7
12 Name 13 Vorname 13 01.09.07 07.09.07 Name 19 Vorname 19 6
13 Name 12 Vorname 12 30.08.07 08.09.07
14 Name 11 Vorname 11 30.08.07 09.09.07
15 Name 10 Vorname 10 29.08.07 10.09.07
Benutzte Formeln:
E2: =KKLEINSTE(WENN(C$2:C$99<=HEUTE();9^9;C$2:C$99);ZEILE(A1))
F2: =WENN(E2<=HEUTE()+10;INDEX($A$1:$B$99;H2;1);"")
G2: =WENN(E2<=HEUTE()+10;INDEX($A$1:$B$99;H2;2);"")
H2: =WENN(E2>HEUTE()+10;"";WENN(E2=E1;H1+VERGLEICH(E2;INDIREKT("Z" & H1+1
& "S3:Z99S3";FALSCH);FALSCH);VERGLEICH(E2;$C$1:$C$99;FALSCH)))
Die Formel in E2 muss du als Matrixformel eingeben (Tastenkombi Strg+Shift+Enter). Die Formeln im Bereich E2:H2 kannst du dann nach unten kopieren.