txt-Datei

Forumthread: txt-Datei

txt-Datei

03.09.2007 14:32:58

Felix

Hallo,
ich bin leider kein großer Experte im Makroschreiben und habe deshalb eine (evtl. dämliche) Frage. Ich möchte ein Excelsheet als txt-Datei abspeichern. Wichtig ist, dass jede Spalte dabei durch ein Semikolon getrennt ist. Ich möchte explizit keine csv-Datei sondern eine txt-Datei erstellen, da ein anderes Programm txt-Files mit Semikolons als Input benötigt. Ich gehe bisher so vor, dass ich die "concatenate"-Funktion benute (Bsp: concatenate(A1,";",B1,";",C1,";") etc. und dann alles als txt-Datei abspeicher. Geht das auch irgendwie einfacher?
Vielen Dank für eure Hilfe.
Felix

4
Beiträge zum Forumthread

Beiträge zu diesem Forumthread

Betreff

Datum

Anwender

AW: txt-Datei

03.09.2007 14:45:00

Rudi
AW: txt-Datei

03.09.2007 14:55:00

Felix
AW: txt-Datei

03.09.2007 14:59:00

Rudi
AW: txt-Datei

03.09.2007 15:08:00

Felix

AW: txt-Datei

03.09.2007 14:45:00

Rudi

Hallo,


Public Sub prcCreateTXT()
Dim intFileNumber As Integer
Dim lngRow As Long
Dim vntArray As Variant
Dim strText As String
Dim i As Integer
Const strPre As String = ";"
Reset
intFileNumber = FreeFile
With ThisWorkbook
.Save
Open .Path & "\" & Left$(.Name, Len(.Name) - 4) & _
".txt" For Output As #intFileNumber
End With
With ActiveSheet.UsedRange
For lngRow = 1 To .Row + .Rows.Count - 1
vntArray = Range(Cells(lngRow, 1), _
Cells(lngRow, .Column + .Columns.Count - 1))
vntArray = WorksheetFunction.Transpose( _
WorksheetFunction.Transpose(vntArray))
strText = Join(vntArray, strPre)
Print #intFileNumber, strText
Next
End With
Close #intFileNumber
End Sub

Gruß
Rudi
Eine Kuh macht Muh, viele Kühe machen Mühe

AW: txt-Datei

03.09.2007 14:55:00

Felix

Hi Rudi,
vielen Dank für Deine schnelle Antwort. Mir ist jedoch nicht ganz klar, was Dein Makro genau macht. Wo speichert es die Datei? Kann ich das irgendwie mit darein schreiben?
Vielen Dank
Felix

AW: txt-Datei

03.09.2007 14:59:00

Rudi

Hallo,


Open .Path & "\" & Left$(.Name, Len(.Name) - 4) & _
".txt" For Output As #intFileNumber

Die Textdatei wird im gleichen Pfad unter dem gleichen Namen (nur eben als .txt) wie die Datei mit dem Makro gespeichert.
Kannst du aber auch ändern.


Open "c:\MeinPfad\MeineDatei.txt" for Output As #intFileNumber

Gruß
Rudi
Eine Kuh macht Muh, viele Kühe machen Mühe

AW: txt-Datei

03.09.2007 15:08:00

Felix

Hi Rudi,
funktioniert einwandfrei!!!! Vielen, vielen Dank!
Gruß
Felix

Beliebteste Forumthreads (12 Monate)

Forumthread: txt-Datei

4 Beiträge zum Forumthread Beiträge zu diesem Forumthread

Beliebteste Forumthreads (12 Monate)

4
Beiträge zum Forumthread

Beiträge zu diesem Forumthread