makros ins kontextmenü

eddie · 1970-01-01T00:00:00+00:00

Hallo, wie kann man fertige makros (die Ausführung) in das Kontextmenü einbauen? Ich habe verschiedene makros, die ich über eine Tastenkombination oder den Klassiker "Extras - makros..." ausführen kann. Ich fände es aber ergonomischer, wenn man die Ausführung von makros über das Kontextmenü (rechte Maustaste) veranlassen könnte. Ist das möglich? Danke für einen Tipp Manfred

Hallo Manfred,
ein Beispiel.
' **********************************************************************
' Modul: DieseArbeitsmappe Typ: Element der Mappe(Sheet, Workbook, ...)
' **********************************************************************

Option Explicit

Private Sub Workbook_BeforeClose(Cancel As Boolean)
Application.CommandBars("Cell").Reset
End Sub

Private Sub Workbook_Open()
Dim objCBar As CommandBar, objCPop As CommandBarPopup, objcBtn As CommandBarButton

Application.CommandBars("Cell").Reset

Set objCBar = Application.CommandBars("Cell")

Set objCPop = objCBar.Controls.Add(msoControlPopup, Before:=1, Temporary:=True)

objCPop.Caption = "Makros >>"

Set objcBtn = objCPop.Controls.Add(msoControlButton)

With objcBtn
    .Caption = "Makroname1"
    .FaceId = 186
    .OnAction = "NameDes1Makros"
End With

Set objcBtn = objCPop.Controls.Add(msoControlButton)

With objcBtn
    .Caption = "Makroname2"
    .FaceId = 186
    .OnAction = "NameDes2Makros"
End With

Set objCBar = Nothing
Set objCPop = Nothing
Set objcBtn = Nothing
End Sub

Gruß Sepp

Hallo Manfred,
würde ich so machen:

' **********************************************************************
' Modul: DieseArbeitsmappe Typ: Element der Mappe(Sheet, Workbook, ...)
' **********************************************************************

Option Explicit

Private Sub Workbook_Activate()
    Call SetCommandbar
End Sub

Private Sub Workbook_Deactivate()
    Call ResetCommandbar
End Sub

' **********************************************************************
' Modul: Modul1 Typ: Allgemeines Modul
' **********************************************************************

Option Explicit

Public Sub SetCommandbar()
    Dim objButton As CommandBarButton
    Set objButton = CommandBars("Cell").Controls.Add(Type:=msoControlButton, Temporary:=True)
    With objButton
        .Caption = "Mein Button"
        .FaceId = 59
        .OnAction = "MeinMakro"
        .Tag = "Finde mich"
        .TooltipText = "Klick mich"
    End With
End Sub

Public Sub ResetCommandbar()
    Dim objControls As CommandBarControls, objControl As CommandBarControl
    Set objControls = CommandBars.FindControls(Tag:="Finde mich")
    If Not objControls Is Nothing Then
        For Each objControl In objControls
            objControl.Delete
        Next
    End If
End Sub

Public Sub MeinMakro()
    MsgBox "Hallo"
End Sub

@Sepp
wenn ich Workbook_BeforeClose abbreche, ist dein Eintrag weg :-(
wenn du meine Commandbar resetest sind die Einträge aus meinen Addins weg :-(
Gruß
Nepumuk

Forumthread: makros ins kontextmenü

13
Beiträge zum Forumthread

Beiträge zu diesem Forumthread

Forumthreads zu verwandten Themen

Infobox / Tutorial

Makros im Kontextmenü einfügen

Schritt-für-Schritt-Anleitung

Häufige Fehler und Lösungen

Alternative Methoden

Praktische Beispiele

Tipps für Profis

FAQ: Häufige Fragen

Beliebteste Forumthreads (12 Monate)