Live-Forum - Die aktuellen Beiträge
Datum
Titel
29.03.2024 13:14:12
28.03.2024 21:12:36
28.03.2024 18:31:49
Anzeige
Archiv - Navigation
944to948
Aktuelles Verzeichnis
Verzeichnis Index
Übersicht Verzeichnisse
Vorheriger Thread
Rückwärts Blättern
Nächster Thread
Vorwärts blättern
Anzeige
HERBERS
Excel-Forum (Archiv)
20+ Jahre Excel-Kompetenz: Von Anwendern, für Anwender
944to948
944to948
Aktuelles Verzeichnis
Verzeichnis Index
Verzeichnis Index
Übersicht Verzeichnisse
Inhaltsverzeichnis

Bedingter Mittelwert Sprintzeiten

Bedingter Mittelwert Sprintzeiten
25.01.2008 12:43:00
Gilligan
Hallo Forumler,
ich stehe vor einem ähnlichen Problem wie am 23.01.
Ich habe 3 Datenreihen (Sprintzeiten) a 4 Werte bspw. E4-H4 I4-L4 und M4-P4.
Nun sollen nur die Mittelwerte der Zwischenzeiten (E4 I4 M4; F4 J4 N4; G4 K4 N4; H4 L4 P4) der besten beiden Endzeiten (H4 L4 P4) berechnet werden. Wenn nur 1 Lauf existiert, dann nur den.
Kann ich mir die Spalte von KKLEINSTE(H4 L4 P4; 1) ausgeben lassen?
Bin etwas verwirrt.
Gilligan

3
Beiträge zum Forumthread
Beiträge zu diesem Forumthread

Betreff
Datum
Anwender
Anzeige
AW: Bedingter Mittelwert Sprintzeiten
25.01.2008 14:02:00
Josef
Hallo Gilligan,
ich weiß nicht, ob ich dich richtig verstanden habe.
Tabelle1

 DEFGHIJKLMNOP
3 Zeit 1Zeit 2Zeit 3Zeit 4Zeit 1Zeit 2Zeit 3Zeit 4Zeit 1Zeit 2Zeit 3Zeit 4
4 00:15,2300:32,3600:46,0601:05,3500:15,1400:31,7900:45,9901:00,8900:14,2000:31,9700:45,8901:00,75
5             
6             
7             
8             
9Mittelwert            
10Zeit 100:14,86           
11Zeit 200:32,04           
12Zeit 300:45,98           
13Zeit 401:02,33           
14Mittelwert beste zwei Zeiten            
15Zeit 100:14,67           
16Zeit 200:31,88           
17Zeit 300:45,94           
18Zeit 401:00,82           
19             

Formeln der Tabelle
ZelleFormel
E10{=MITTELWERT(WENN(($E$3:$P$3=D10)*($E$4:$P$4>0); $E$4:$P$4))}
E11{=MITTELWERT(WENN(($E$3:$P$3=D11)*($E$4:$P$4>0); $E$4:$P$4))}
E12{=MITTELWERT(WENN(($E$3:$P$3=D12)*($E$4:$P$4>0); $E$4:$P$4))}
E13{=MITTELWERT(WENN(($E$3:$P$3=D13)*($E$4:$P$4>0); $E$4:$P$4))}
E15{=MITTELWERT(KKLEINSTE(WENN(($E$3:$P$3=D15)*($E$4:$P$4>0); $E$4:$P$4); {1.2}))}
E16{=MITTELWERT(KKLEINSTE(WENN(($E$3:$P$3=D16)*($E$4:$P$4>0); $E$4:$P$4); {1.2}))}
E17{=MITTELWERT(KKLEINSTE(WENN(($E$3:$P$3=D17)*($E$4:$P$4>0); $E$4:$P$4); {1.2}))}
E18{=MITTELWERT(KKLEINSTE(WENN(($E$3:$P$3=D18)*($E$4:$P$4>0); $E$4:$P$4); {1.2}))}
Enthält Matrixformel:
Umrandende
{ } nicht miteingeben,
sondern Formel mit STRG+SHIFT+RETURN abschließen!
Matrix verstehen
Excel Tabellen im Web darstellen  Excel Jeanie HTML
Gruß Sepp

Anzeige
AW: Bedingter Mittelwert Sprintzeiten
25.01.2008 14:47:00
Gilligan
Hallo Sepp,
Danke für Deine Antwort. Allerdings muss erst nach den zwei besten (kleinsten) Endzeiten (Zeit 4)geschaut werden und die dazugehörigen Zeiten müssen dann gemittelt werden.
Habe mich wohl etwas kompliziert ausgedrückt.
Besten beiden Endzeiten ermitteln.
Die beiden Zeitreihen mitteln.
Wenn nur eine Endzeit vorhanden, dann die Zahlenreihe nehmen.
Hast Du eine Idee?

AW: Bedingter Mittelwert Sprintzeiten
25.01.2008 15:31:00
Josef
Hallo Gilligan,
dann vielleicht so.
Tabelle1

 DEFGHIJKLMNOP
2             
3 Zeit 1Zeit 2Zeit 3Zeit 4Zeit 1Zeit 2Zeit 3Zeit 4Zeit 1Zeit 2Zeit 3Zeit 4
4 00:15,2300:32,3600:46,0601:05,3500:15,1400:31,7900:45,9901:00,7500:14,2000:31,9700:45,8901:00,75
5             
6             
7             
8             
9             
10 Bestzeiten           
11 Zeit 4Zeit 1Zeit 2Zeit 3        
12101:00,7500:15,1400:31,7900:45,99        
13201:00,7500:14,2000:31,9700:45,89        
14Mittelwert01:00,7500:14,6700:31,8800:45,94        
15             

Formeln der Tabelle
ZelleFormel
E12{=KKLEINSTE(WENN(($E$3:$P$3=$E$11)*($E$4:$P$4>0); $E$4:$P$4+SPALTE($E:$P)/10^15); ZEILE(A1))}
F12{=INDEX($E$4:$P$4;;VERGLEICH($E12;$E$4:$P$4+SPALTE($E:$P)/10^15;0)-4+SPALTE(A1))}
G12{=INDEX($E$4:$P$4;;VERGLEICH($E12;$E$4:$P$4+SPALTE($E:$P)/10^15;0)-4+SPALTE(B1))}
H12{=INDEX($E$4:$P$4;;VERGLEICH($E12;$E$4:$P$4+SPALTE($E:$P)/10^15;0)-4+SPALTE(C1))}
E13{=WENN(SUMMENPRODUKT(($E$3:$P$3=$E$11)*($E$4:$P$4>0)*1)>1;KKLEINSTE(WENN(($E$3:$P$3=$E$11)*($E$4:$P$4>0); $E$4:$P$4+SPALTE($E:$P)/10^15); ZEILE(A2)); "")}
F13{=WENN($E$13<>"";INDEX($E$4:$P$4;;VERGLEICH($E13;$E$4:$P$4+SPALTE($E:$P)/10^15;0)-4+SPALTE(A2)); "")}
G13{=WENN($E$13<>"";INDEX($E$4:$P$4;;VERGLEICH($E13;$E$4:$P$4+SPALTE($E:$P)/10^15;0)-4+SPALTE(B2)); "")}
H13{=WENN($E$13<>"";INDEX($E$4:$P$4;;VERGLEICH($E13;$E$4:$P$4+SPALTE($E:$P)/10^15;0)-4+SPALTE(C2)); "")}
E14=MITTELWERT(E12:E13)
F14=MITTELWERT(F12:F13)
G14=MITTELWERT(G12:G13)
H14=MITTELWERT(H12:H13)
Enthält Matrixformel:
Umrandende
{ } nicht miteingeben,
sondern Formel mit STRG+SHIFT+RETURN abschließen!
Matrix verstehen
Excel Tabellen im Web darstellen  Excel Jeanie HTML
Gruß Sepp

Anzeige

Beliebteste Forumthreads (12 Monate)

Anzeige

Beliebteste Forumthreads (12 Monate)

Anzeige
Anzeige
Anzeige