Makro für flexiblen Druckbereich

Beiträge zum Forumthread

Beiträge zu diesem Forumthread

Betreff

Datum

Anwender

Erstmals vielen Dank,
es ist so, alle Zeilen die gedruckt werden sollen weisen in der Spalte a eine 1 auf. Alle anderen sind mit einer 0 versehen. Das ist aber nicht immer gleich, je nach dem was der Benutzer des Sheets eingibt seht das eine mal im Bereich 1 und im Bereich 5 und 7 eine eins und das andere mal im Bereich 1,3 und 4.
Insgesamt gibt es 10 mögliche Bereiche, wobei der Bereich 1 immer gedruckt werden muss.
Bereich 1: Zeile 2-29
Bereich 2: Zeile 30-49
Bereich 3: Zeile 50-69
Bereich 4: Zeile 70-89
Bereich 5: Zeile 90-109
Bereich 6: Zeile 110-129
Bereich 7: Zeile 130-149
Bereich 8: Zeile 150-169
Bereich 9: Zeile 170-189
Bereich 10: Zeile 190-209
Ich brauche das ganze eben für einen Plakettendrucker. Wenn der dazwischen leere Seiten druckt, dann ist werden da irrsinnig viele Plaketten verschwendet.
Vielleicht gibt's ja ne möglichkeit
Vielen Dank nochmal
lg Patricia

Hallo Patricia,
ich hab mal zwei Varianten gebastelt. Beide Varianten setzen die Seitenumbrüche entsprechend und blenden auch die Zeilen ab Zeile 30 entsprechend ein/aus. Den Tabellennamen im Code ggf. noch anpassen.
Variante 1 wird automatisch vor dem Drucken/der Seitenvorschau ausgeführt. Einfügen muss du sie im VBA-Editor unter "DieseArbeitsmappe".
Variante 2 ist ein "normales" Makro, dass du ggf. auch per Makro-Button im Tabellenblatt starten könntest.
Gruß
Franz


'Variante 1
Private Sub Workbook_BeforePrint(Cancel As Boolean)
Dim wks As Worksheet, Zeile As Long
Select Case ActiveSheet.Name
Case "Tabelle1" 'Name der Tabelle die vor dem Drucken aufbereitet werden soll
If MsgBox("Plaketten drucken?", vbQuestion + vbYesNo) = vbYes Then
Set wks = ActiveSheet
Application.ScreenUpdating = False
With wks
.Cells.PageBreak = xlPageBreakNone
For Zeile = 30 To 209
If .Cells(Zeile, 1) = 0 Then
.Rows(Zeile).Hidden = True
ElseIf .Cells(Zeile, 1) = 1 Then
.Rows(Zeile).Hidden = False
Else
'do nothing
End If
Select Case Zeile
Case 30, 50, 70, 90, 110, 130, 150, 170, 190 'Zeilen mit ggf. Seitenwechsel
If .Cells(Zeile, 1) = 1 Then
.Cells(Zeile, 1).PageBreak = xlPageBreakManual
End If
Case Else
'do nothing
End Select
Next
End With
Application.ScreenUpdating = True
Else
Cancel = True
End If
Case Else
'do nothing
End Select
End Sub
'Variante 2
Sub DruckenPlaketten()
Dim wks As Worksheet, Zeile As Long
If MsgBox("Plaketten drucken?", vbQuestion + vbYesNo) = vbYes Then
Set wks = Worksheets("Tabelle1")
Application.ScreenUpdating = False
With wks
.Cells.PageBreak = xlPageBreakNone
For Zeile = 30 To 209
If .Cells(Zeile, 1) = 0 Then
.Rows(Zeile).Hidden = True
ElseIf .Cells(Zeile, 1) = 1 Then
.Rows(Zeile).Hidden = False
Else
'do nothing
End If
Select Case Zeile
Case 30, 50, 70, 90, 110, 130, 150, 170, 190 'Zeilen mit ggf. Seitenwechsel
If .Cells(Zeile, 1) = 1 Then
.Cells(Zeile, 1).PageBreak = xlPageBreakManual
End If
Case Else
'do nothing
End Select
Next
.PrintOut
'        .PrintPreview
.Rows.Hidden = False 'Alle Zeilen wieder einblenden
End With
Application.ScreenUpdating = True
End If
End Sub

Beliebteste Forumthreads (12 Monate)

Makro für flexiblen Druckbereich

4 Beiträge zum Forumthread Beiträge zu diesem Forumthread

VBA Beispiele zu verwandten Themen

Beliebteste Forumthreads (12 Monate)

Beliebteste Forumthreads (12 Monate)

4
Beiträge zum Forumthread

Beiträge zu diesem Forumthread