Das Archiv des Excel-Forums

Ordnerdialog und Dateidialog

Informationen und Beispiele zu den hier genannten Dialog-Elementen:
Bild

Betrifft: Ordnerdialog und Dateidialog
von: Dirk Räder

Geschrieben am: 17.02.2008 00:46:12

Liebes Forum, ich habe folgendes Problem:
Ich möchte einen Ordnerdialog über ein CommandButton ausführen. das Ergebnis (Pfad) soll in Tabelle1 in der Zelle A1 ausgegeben werden. Anschließend möchte ich einen Dateidialog über ein CommandButton aufrufen. Das Startverzeichnis des Dateidialoges soll sich auf das Verzeichnis in A1 beziehen. In dem Dateidialog möchte ich Bilddateien aussuchen. Das Ergebnis des Dateidialoges soll nun in der Zelle B1 ausgegeben werden.
Könnt ihr mir helfen?!
LG
Dirk

Bild

Betrifft: AW: Ordnerdialog und Dateidialog
von: Case
Geschrieben am: 17.02.2008 02:56:21
Hallo,
ab Excel 2002 (XP) funktioniert folgendes:


Option Explicit
Public Sub Ordner()
Dim strVerzeichnis As String
If Ordnerwahl(strVerzeichnis) <> "" Then
ActiveSheet.Cells(1, 1).Value = strVerzeichnis
Else
MsgBox "Es wurde kein Ordner ausgewaehlt!"
End If
End Sub
Public Sub Datei()
Dim strBildDatei As String
If Trim$(ActiveSheet.Cells(1, 1).Value) = "" Then Exit Sub
If Dateiwahl(strBildDatei) <> "" Then
ActiveSheet.Cells(1, 2).Value = strBildDatei
Else
MsgBox "Es wurde keine Datei ausgewaehlt!"
End If
End Sub
Public Function Ordnerwahl(strOrdner As String) As String
With Application.FileDialog(msoFileDialogFolderPicker)
.InitialFileName = "C:\"
.Title = "Ordnerauswahl"
.ButtonName = "Auswahl..."
.InitialView = msoFileDialogViewList
If .Show = -1 Then
strOrdner = .SelectedItems(1)
If Right(strOrdner, 1) <> "\" Then strOrdner = strOrdner & "\"
Else
Exit Function
End If
End With
Ordnerwahl = strOrdner
End Function
Public Function Dateiwahl(strDatei As String) As String
With Application.FileDialog(msoFileDialogFilePicker)
.InitialFileName = ActiveSheet.Cells(1, 1).Value
.Title = "Dateiauswahl"
.ButtonName = "Auswahl..."
.InitialView = msoFileDialogViewDetails
.Filters.Add "Bilder", "*.gif; *.jpg; *.jpeg; *.bmp", 1
.FilterIndex = 1
If .Show = -1 Then
strDatei = Mid(.SelectedItems(1), _
InStrRev(.SelectedItems(1), "\", -1) + 1)
Else
Exit Function
End If
End With
Dateiwahl = strDatei
End Function


Servus
Case



Bild

Betrifft: AW: Ordnerdialog und Dateidialog
von: Dirk Räder

Geschrieben am: 17.02.2008 04:01:17
Super, funktioniert einwandfrei! :-)
Vielen Dank
Grüße
Dirk

 Bild

Excel-Beispiele zum Thema "Ordnerdialog und Dateidialog"

Ordnerdialog mit nachfolgendem Dateidialog aufrufen download