Microsoft Excel

Herbers Excel/VBA-Archiv

Makro Workbook_Open läuft nicht

Betrifft: Makro Workbook_Open läuft nicht von: Werner H.
Geschrieben am: 22.02.2008 12:37:47

Hallo zusammen,

wahrscheinlich mache ich einen saublöden Fehler, aber mein Code, der bei Workbook_Open das Kontextmenü erweitern soll, läuft nicht automatisch. Wenn ich ihn händisch anstoße, klappt aber alles. Warum das so ist, kapiere ich nicht - für Hilfe wäre ich sehr dankbar!!

Private Sub Workbook_Open()

Dim sPfad As String
Dim sdate As String
sdate = Format(Date, "dd/mm/yyyy")

sPfad = "Y:\Das\Die\Der\" & sdate & ".xls"

If Dir(sPfad) <> "" Then GoTo Weiter
ActiveWorkbook.SaveCopyAs Filename:=sPfad


Weiter:
Application.CommandBars("Cell").Enabled = True
 Application.CommandBars("Cell").Reset
   Dim Kontext As Object
    Set Kontext = Application.CommandBars("Cell").Controls.Add(Before:=1)
     Kontext.BeginGroup = True
        With Kontext
        .Caption = "DPL Web"
        .OnAction = "DPLWeb2"
        .FaceId = 351
    End With

  Dim Kontext2 As Object
    Set Kontext2 = Application.CommandBars("Cell").Controls.Add(Before:=2)


     Kontext2.BeginGroup = True
        With Kontext2
        .Caption = "TP Web"
        .OnAction = "TPAktExcel"
        .FaceId = 352
    End With

 Dim Kontext3 As Object
    Set Kontext3 = Application.CommandBars("Cell").Controls.Add(Before:=3)
     Kontext3.BeginGroup = True
        With Kontext3
        .Caption = "DPL"
        .OnAction = "GeheZuDPL"
        .FaceId = 481
    End With

End Sub



Danke im Voraus
Werner

  

Betrifft: AW: Makro Workbook_Open läuft nicht von: mumpel
Geschrieben am: 22.02.2008 12:47:14

Hallo!

Wo steht der Code? Das Workbook_Open-Ereignis muss in "DieseArbeitsmappe" stehen, nicht im Standardmodul.

Gruß, Rene


  

Betrifft: AW: Makro Workbook_Open läuft nicht von: Werner H.
Geschrieben am: 22.02.2008 12:54:20

Hallo Rene,

leider steht er da auch... der erste Teil mit der Sicherungskopie läuft auch schon lange anstandslos.

Gruß
Werner


  

Betrifft: AW: Makro Workbook_Open läuft nicht von: Ramses
Geschrieben am: 22.02.2008 13:05:36

Hallo

"...der erste Teil mit der Sicherungskopie läuft auch schon lange anstandslos...."

Auch nur durch Zufall, weil EXCEL in der deutschen Ausführung "/" automatisch gegen "." austauscht.

Ansonsten funktioniert der Code einwandfrei.

Gruss Rainer


  

Betrifft: AW: Makro Workbook_Open läuft nicht von: Nepumuk
Geschrieben am: 22.02.2008 13:05:53

Hallo Walter,

nicht nachvollziehbar. Läuft einwandfrei. Nur ein bisschen aufgeräumter könnte es sein.

' **********************************************************************
' Modul: DieseArbeitsmappe Typ: Element der Mappe(Sheet, Workbook, ...)
' **********************************************************************

Option Explicit

Private Sub Workbook_BeforeClose(Cancel As Boolean)
    With Application.CommandBars("Cell")
        .Enabled = True
        .Reset
    End With
End Sub

Private Sub Workbook_Open()
    Dim sPfad As String
    Dim oButton As CommandBarButton
    
    sPfad = "Y:\Das\Die\Der\" & Format(Date, "dd/mm/yyyy") & ".xls"
    If Dir$(sPfad) = "" Then ThisWorkbook.SaveCopyAs Filename:=sPfad
    
    With Application.CommandBars("Cell")
        
        .Enabled = True
        .Reset
        
        Set oButton = .Controls.Add(Before:=1)
        With oButton
            .BeginGroup = True
            .Caption = "DPL Web"
            .OnAction = "DPLWeb2"
            .FaceId = 351
        End With
        
        Set oButton = .Controls.Add(Before:=2)
        With oButton
            .BeginGroup = True
            .Caption = "TP Web"
            .OnAction = "TPAktExcel"
            .FaceId = 352
        End With
        
        Set oButton = .Controls.Add(Before:=3)
        With oButton
            .BeginGroup = True
            .Caption = "DPL"
            .OnAction = "GeheZuDPL"
            .FaceId = 481
        End With
        
    End With
End Sub

Du solltest mal alles aus der Mappe löschen bis auf eine leere Tabelle und dieses Modul um sie hochzuladen. Eventuell lässt sich so etwas erkennen.

Gruß
Nepumuk


  

Betrifft: AW: klappt jetzt! von: Werner H.
Geschrieben am: 22.02.2008 14:03:47

Hallo Nepomuk,

von wegen nicht aufgeräumt - Du kennst meine anderen Codes nicht ...;-))

Danke für die Hilfe; ich bin beim Austesten mehr oder weniger zufällig in einem Modul auf ein Sub Auto_open gestossen, das offenbar dazwischen gefunkt hat (hab ich irgendwann mal geklaut und eingebaut und danach komplett vergessen, da bis dato alles funktionierte).
Wird mir eine Lehre sein.

@Nepomuk: Danke auch für den Tipp mit den /

Grüße und ein schönes Wochende


 

Beiträge aus den Excel-Beispielen zum Thema "Makro Workbook_Open läuft nicht"