Microsoft Excel

Herbers Excel/VBA-Archiv

Informationen und Beispiele zum Thema Frame
BildScreenshot zu Frame Frame-Seite mit Beispielarbeitsmappe aufrufen

Datei innerhalb von Excel maximieren

Betrifft: Datei innerhalb von Excel maximieren von: Werner Brauns
Geschrieben am: 05.06.2008 15:44:42

Hallo zusammen!

Folgendes Problem stellt sich mir dauernd:
Ich öffne eine Exceldatei aus unserem Intranet heraus. Es sind immer schon ein oder zwei andere Excel-Dateien offen.
Die neue Datei wird dann INNERHALB von Excel nicht maximiert dargestellt. Excel an sich ist schon groß. Aber die einzelnen Dateien innerhalb liegen hintereinander und sind teilweise sichtbar.
Kann man das mit einem Makro ändern? Die neue Datei soll Excel ganz ausfüllen.

Noch eine Sache:
Kann man nach dem Aufruf der Datei aus dem Intranet heraus den IE per VBA verkleinern?

Gruß und DANKE

Werner

  

Betrifft: AW: Datei innerhalb von Excel maximieren von: Nepumuk
Geschrieben am: 05.06.2008 16:24:14

Hallo Werner,

1. In das Modul "DieseArbeitsmappe"

Private Sub Workbook_Open()
    Me.Windows(1).WindowState = xlMaximized
End Sub


2. Klar geht das. allerdings nicht selektiv, sondern nur alle Explorerfenster, außer der Titel des Fensters ist bekannt, dann könnte ich gezieht danach suchen. Ansonsten so:

Private Declare Function EnumWindows Lib "user32.dll" ( _
    ByVal lpEnumFunc As Long, _
    ByVal lParam As Long) As Boolean
Private Declare Function GetClassName Lib "user32.dll" Alias "GetClassNameA" ( _
    ByVal hwnd As Long, _
    ByVal lpClassName As String, _
    ByVal nMaxCount As Long) As Long
Private Declare Function ShowWindow Lib "user32.dll" ( _
    ByVal hwnd As Long, _
    ByVal nCmdShow As Long) As Long

Private Const GCCLASSNAMEMSIEXPLORER = "IEFrame"
Private Const SW_MINIMIZE = 6

Public Sub Minimize_Internetexplorer()
    EnumWindows AddressOf WindowCallBack, ByVal 0&
End Sub

Private Function WindowCallBack(ByVal hwnd As Long, ByVal lParam As Long) As Boolean
    Dim lngReturn As Long
    Dim strClassNameTemp As String * 256, strClassName As String
    lngReturn = GetClassName(hwnd, strClassNameTemp, 256)
    strClassName = Left$(strClassNameTemp, lngReturn)
    If strClassName = GCCLASSNAMEMSIEXPLORER Then _
        Call ShowWindow(hwnd, SW_MINIMIZE)
    WindowCallBack = True
End Function

Gruß
Nepumuk


  

Betrifft: AW: Datei innerhalb von Excel maximieren von: Werner Brauns
Geschrieben am: 06.06.2008 07:09:24

Hallo Nepumuk

Wohin kopiere ich den Code mit dem IE?
Auch in das Modul Arbeitsmappe und da gleich als aller oberstes?

Gruß

Werner


  

Betrifft: AW: Datei innerhalb von Excel maximieren von: Nepumuk
Geschrieben am: 06.06.2008 08:08:32

Hallo Werner,



nein, der hat da nichts zu suchen, denn das ist keine Ereignisroutine. Das kommt in ein Standardmodul. Du kannst ihn aber aus dem Open-Ereignis heraus aufrufen (Call Minimize_Internetexplorer).



Gruß

Nepumuk


  

Betrifft: AW: Datei innerhalb von Excel maximieren von: Werner Brauns
Geschrieben am: 06.06.2008 08:43:32

Ok
Danke für deine Hilfe!
Es klappt

Gruß

Werner


 

Beiträge aus den Excel-Beispielen zum Thema "Datei innerhalb von Excel maximieren"