Anzeige
Anzeige
HERBERS
Excel-Forum (Archiv)
20+ Jahre Excel-Kompetenz: Von Anwendern, für Anwender
Inhaltsverzeichnis

Text in anderer Datei suchen, kopiertes rechts ein

Text in anderer Datei suchen, kopiertes rechts ein
12.09.2008 15:29:00
Rudolf
Hallo an alle, bin neu hier und benötige Hilfe.
Wie kann ich in Spalte A einen Text z.B. K1 (Kommt immer nur 1x vor) suchen.
Das aus anderer Datei kopierte dann rechts in Sp. C gleiche Zeile einfügen,
so das Range("C45").Select wegfallen kann.
Ich hätte dann die Möglichkeit beliebig Zeilen einfügen zu können.
das habe ich schon:
......
On Error GoTo Ende
Range("B6:O6").Select
Selection.Copy _____________ 'aus Datei 1
Windows("Neu Bestell-Formular.xls").Activate _____________ 'in Datei 2
Sheets("Dienstag").Select
Range("C45").Select
ActiveSheet.Paste
Range("A1").Select
GoTo End2
........ usw
Puh, ich hoffe ihr steigt durch was ich geschrieben habe.
Danke!
Gruß
Rudolf
Ps. Das Forum und das Archiv sind einfach SUPER!

14
Beiträge zum Forumthread
Beiträge zu diesem Forumthread

Betreff
Datum
Anwender
Anzeige
AW: Text in anderer Datei suchen, kopiertes rechts ein
12.09.2008 18:16:00
fcs
Hallo Rudolf,
hier mein Vorschlag.
Voraussetzung für die Ausführung: zum Zeitpunkt, zu dem diese Makrosektion abgearbeitet wird ist das Blatt aktiv in dem die zu kopierenden Daten im Bereich B6:O6 stehen.
Wenn du Name von Quell-Datei und -Tabellenblatts genau kennst, dann kannst du auch die als Kommentar eingebaute Variante verwenden. So kannst ist das Makro unabhängig vom gerade aktiven Blatt ausführen.
Gruß
Franz

Sub aaTest()
Dim varSuchen, lngZeileZiel As Long, rngSuchen As Range
Dim wbZiel As Workbook, wksZiel As Worksheet
Dim wbQuelle As Workbook, wksQuelle As Worksheet
On Error GoTo ende
Set wksQuelle = ActiveSheet 'aktives Blatt in Datei 1
'oder auch
'  Set wbQuelle = Workbooks("Dateiname1.xls")' Datei 1
'  Set wksQuelle = wbQuelle.Worksheets("Tabelle1") 'Quellen-Blatt in Datei 1
Set wbZiel = Workbooks("Neu Bestell-Formular.xls")
Set wksZiel = wbZiel.Worksheets("Dienstag")
'Suchwert für Zieltabelle eingeben
varSuchen = InputBox("Suchwert für Spalte A in Mappe ""Neu Bestell-Formular.xls""")
'oder auch aus einer Zelle im Quell-Blatt auslesen
'  varSuchen = wksQuelle.Range("A6").Value
If varSuchen  "" Then
'Eingabewert im Zielblatt Spalte A suchen
Set rngSuchen = wksZiel.Columns(1).Find(what:=varSuchen, LookIn:=xlValues, lookat:=xlWhole)
If rngSuchen Is Nothing Then
MsgBox "Suchebegriff im Zielblatt nicht gefunden!"
Else
'Daten aus Datei 1 in gefundener Zeile in Zieltabelle Spalte C kopieren
lngZeileZiel = rngSuchen.Row
wksQuelle.Range("B6:O6").Copy Destination:=wksZiel.Cells(lngZeileZiel, 3)
End If
'Zieltabelle anzeigen falls erforderlich/gewünscht
wbZiel.Activate
wksZiel.Activate
End If
GoTo end2
end2:
ende:
If Err.Number  0 Then
MsgBox "Fehler: " & Err.Number & vbLf & Err.Description
End If
End Sub


Anzeige
AW: Text in anderer Datei suchen, kopiertes rechts ein
12.09.2008 19:26:23
Rudolf
Hallo Franz,
danke für die rasche Antwort.
Jetz habe ich erst mal 1 Woche arbeit mit der Aufgabe.
So fitt bin ich noch nicht.
Msg Boxen können vernachlässigt werden gesuchte Namen sind immer vorhanden. (Bei der Masse der Dateien die ich nach diesem Muster abarbeiten muß würde das sehr aufhalten)
Ich muß in Datei 1.xls Tabelle1 den Bereich B6:O6 kopieren (Tabelle aktiv)
dann in (muß Aktivirt werden) Datei 2.xls in Tabelle2 Spalte A einen Namen suchen Z.B. Anton jetzt rechts davon in Spalte C das kopierte einfügen. (schreibt bzw. fügt sich ja dann nach rechts weiter ein)
Zur besseren Übersicht der Tabelle soll dann Zelle A1 Angesprungen werden.
In Datei 1 muß nicht zurückgegangen werden.
Die Krönung des ganzen wäre naürlich wenn in Datei 1 Tabelle1 in A3 der Name "XYZ" ausgelesen würde,
dann in Datei 2 Tabelle2 gesucht und wie oben geschildert weiterverarbeitet wird.
wenn du magts und es etwas vorbereiten könntes wäre ich echt froh.
Danke für deine Mühe.
Gruß
Rudolf
Anzeige
AW: Text in anderer Datei suchen, kopiertes rechts ein
12.09.2008 20:59:44
fcs
Hallo Rudolf,
wenn du sehr viele Dateien nach dem Schema bearbeiten willst, dann solltest du auch das Öffnen der Quelldateien (Datei1) und Zieldatei (Datei2) per Makro steuern.
Zuerst die Zieldatei per Makro öffnen.
Danach per Makro die Quelldateien, deren Daten du in die Zieldatei kopieren willst, öffnen. Nach dem Öffnen der Datei wird nach Bestätigung sofort der Kopiervorgang gestartet und die Quelldatei wieder geschlossen.
Gruß
Franz

'Deklaration von Variablen, die in allen Prozduren des Moduls gültig sind
Private wbZiel As Workbook
Private wbQuelle As Workbook
Sub OeffnenQuelldatei()
If Application.Dialogs(xlDialogOpen).Show  False Then
Set wbQuelle = ActiveWorkbook
If MsgBox("Daten kopieren", vbOKCancel, "Daten nach Zieldatei kopieren") = vbOK Then
Call DatenKopieren
End If
wbQuelle.Close savechanges:=False
Set wbQuelle = Nothing
End If
End Sub
Sub OeffnenZieldatei()
If Application.Dialogs(xlDialogOpen).Show  False Then
Set wbZiel = ActiveWorkbook
End If
End Sub
Private Sub DatenKopieren()
Dim varSuchen, lngZeileZiel As Long, rngSuchen As Range
Dim wksQuelle As Worksheet
Dim wksZiel As Worksheet
On Error GoTo ende
If wbZiel Is Nothing Then
MsgBox "Bitte Zieldatei vor der Quelldatei per Makro öffnen!"
Else
Set wksQuelle = wbQuelle.Worksheets("Tabelle1") 'Quellen-Blatt in Datei 1
'Suchwert aus Zelle A3 in Quelldatei-Tabelle1 auslesen
varSuchen = wksQuelle.Range("A3").Value
If varSuchen  "" Then
'Tabellenblatt in der Zieldatei setzen
Set wksZiel = wbZiel.Worksheets("Tabelle2")
'Zieldatei anzeigen
wbZiel.Activate
'Zieltabelle anzeigen
wksZiel.Activate
'Eingabewert im Zielblatt Spalte A suchen
Set rngSuchen = wksZiel.Columns(1).Find(what:=varSuchen, LookIn:=xlValues, lookat:= _
xlWhole)
If rngSuchen Is Nothing Then
MsgBox "Suchbegriff im Zielblatt nicht gefunden!"
Else
'Daten aus Datei 1 in gefundener Zeile in Zieltabelle Spalte C kopieren
lngZeileZiel = rngSuchen.Row
wksQuelle.Range("B6:O6").Copy Destination:=wksZiel.Cells(lngZeileZiel, 3)
End If
wksZiel.Range("A1").Select
End If
End If
GoTo end2
end2:
ende:
If Err.Number  0 Then
MsgBox "Fehler: " & Err.Number & vbLf & Err.Description
End If
End Sub


Anzeige
AW: Text in anderer Datei suchen, kopiertes rechts ein
12.09.2008 22:39:00
Rudolf
Hallo Franz,
danke mal wieder!
Gute Idee mit dem Datei öffnen.
Wird leider bei mir nicht gehen.
Ich versuche es mal darzustellen.
1 Büro Pc hat eine offene Datei für Wäscheanforderungen (Ort=Desktop) um diese dann an eine externe Firma zu senden. (Datei mehrere Std. offen, je nachdem wie die Meldungen eintrudeln)
ca. 30 Stationen melden per E-Mail in einer eigenen vorgefertigten Exeldatei (die das Makro beinhaltet) ihren Bedarf an das Büro.
Das Büro öffnet jede Datei aus Outlook, klickt auf einen Button in der Datei daraufhin werden die Werte kopiert und in die Datei auf dem Büro Pc eingefügt. (Datei "Station" hat jetzt keine Verwendung mehr.)
wird jetzt in der Datei Wäscheanforderung mal eine Zeile eingfügt stimmt die ganze Zuordnung nicht mehr.
(Spalten werden nicht eingefügt)
deswegen das Suchen nach dem Namen.
Ich hatte mit Hilfe eures Arcivs schon mal geschafft, die Dateien aber nicht in der Firma eingspielt.
Was jetzt kommt kannst du dir denken Festplatte von 2002 hat den Geist aufgegeben und futsch war die Geschichte. Ausgerechnet das hatte ich noch nicht gesichert.
Ich glaube es war nur etwas kleines was ich damal eingefügt habe.
Ich habe wenig Ahnung, kann mir aber manchmal etwas zusammenkopieren.
Gruß
Rudolf
Anzeige
AW: Text in anderer Datei suchen, kopiertes rechts ein
12.09.2008 23:38:00
Rudolf
bei Bedarf könnte ich die 2 Dateien ja mal hochladen um die Funktion zu sehen
Gruß
Rudolf
AW: Text in anderer Datei suchen, kopiertes rechts ein
15.09.2008 09:35:00
fcs
Hallo Rudolf,
wenn die Zieldatei immer den gleichen Namen hat, dann kann man eine Prüfung einbauen ob die Datei schon geöffnet ist.
Alternativ könnte man in den geöffneten Dateien (verschieden von wbQuelle) den Inhalt einer bestimmten Zelle prüfen, die die Zieldatei eindeutig kennzeichnet, und ggf. die Zieldatei öffnen.
Gruß
Franz

Private Sub DatenKopieren()
Dim varSuchen, lngZeileZiel As Long, rngSuchen As Range
Dim wbZiel As Workbook
Dim wbQuelle As Workbook
Dim wksQuelle As Worksheet
Dim wksZiel As Worksheet
Const strPfad As String = "C:\Lokale Daten\XYZ"  'Verzeichnis der Zieldatei
Const strZieldatei As String = "Zieldatei.xls"   'Name der Zieldatei
On Error GoTo ende
Set wbQuelle = ActiveWorkbook
If MsgBox("Daten kopieren", vbOKCancel, "Daten nach Zieldatei kopieren") = vbOK Then
'Prüfen, ob Zieldatei schon geöffnet
For Each wbZiel In Workbooks
If LCase(wbZiel.Name) = LCase(strZieldatei) Then Exit For
Next
If wbZiel Is Nothing Then
'Zieldatei öffnen, wenn nocht geöffnet
Set wbZiel = Workbooks.Open(Filename:=strPfad & "\" & strZieldatei)
End If
Set wksQuelle = wbQuelle.Worksheets("Tabelle1") 'Quellen-Blatt in Datei 1
'Suchwert aus Zelle A3 in Quelldatei-Tabelle1 auslesen
varSuchen = wksQuelle.Range("A3").Value
If varSuchen  "" Then
'Tabellenblatt in der Zieldatei setzen
Set wksZiel = wbZiel.Worksheets("Tabelle2")
'Zieldatei anzeigen
wbZiel.Activate
'Zieltabelle anzeigen
wksZiel.Activate
'Eingabewert im Zielblatt Spalte A suchen
Set rngSuchen = wksZiel.Columns(1).Find(what:=varSuchen, LookIn:=xlValues, lookat:= _
xlWhole)
If rngSuchen Is Nothing Then
MsgBox "Suchbegriff im Zielblatt nicht gefunden!"
Else
'Daten aus Datei 1 in gefundener Zeile in Zieltabelle Spalte C kopieren
lngZeileZiel = rngSuchen.Row
wksQuelle.Range("B6:O6").Copy Destination:=wksZiel.Cells(lngZeileZiel, 3)
End If
wksZiel.Range("A1").Select
End If
End If
wbQuelle.Close savechanges:=False
Set wbQuelle = Nothing
GoTo end2
end2:
ende:
If Err.Number  0 Then
MsgBox "Fehler: " & Err.Number & vbLf & Err.Description
End If
End Sub


Anzeige
AW: Text in anderer Datei suchen, kopiertes rechts ein
15.09.2008 10:57:00
Rudolf
Sprachlos!!!
genau das ist es. Vielen Dank Franz.
Ich traue mich fast nicht zu fragen.
Könntest du in der Quelldatei in B3 in der der Tabellenblattname steht auch das Tabellenblatt (später geänert in Dienstag oder Mittwoch) in dem gesucht werden soll mit auslesen lassen?
So könnte ich für die Datei für verschiedene Stationen anpassen ohne das Makro ändern zu müssen.
nach dem Motto Name und Tabellenblatt in der Quelldatei ändern, speichern unter neuem Namen, fertig.
Das war es aber auch dann wirklich.
Gruß
Rudolf
AW: Text in anderer Datei suchen, kopiertes rechts ein
15.09.2008 18:17:00
fcs
Hallo Rudolf,
ich hab deine Wunschliste (Tabellenblattname auslesen) eingebaut. Angepasste/ergänzte Zeilen sind mit '### markiert.
Die Quelldatei wird jetzt nur noch automatisch geschlossen, wenn Werte erfolgreich in die Zieltabelle übertragen wurden.
Die Fehlerbehandlung hab ich etwas modifiziert, so dass der Hinweis "Nur für Frau Romes" nur bei einer bestimmten Fehlernummer erscheint.
Gruß
Franz

Sub DatenKopieren()
Dim varSuchen, lngZeileZiel As Long, rngSuchen As Range
Dim wbZiel As Workbook
Dim wbQuelle As Workbook
Dim wksQuelle As Worksheet
Dim wksZiel As Worksheet
Dim strTabelleZiel As String                  '###
Const strPfad As String = "D:\Test2\"  'Verzeichnis der Zieldatei
Const strZieldatei As String = "Ziel_neu.xls"   'Name der Zieldatei
On Error GoTo ende
Set wbQuelle = ActiveWorkbook
If MsgBox("Daten kopieren", vbOKCancel, "Daten nach Zieldatei kopieren") = vbOK Then
'Prüfen, ob Zieldatei schon geöffnet
For Each wbZiel In Workbooks
If LCase(wbZiel.Name) = LCase(strZieldatei) Then Exit For
Next
If wbZiel Is Nothing Then
'Zieldatei öffnen, wenn nicht geöffnet
Set wbZiel = Workbooks.Open(Filename:=strPfad & "\" & strZieldatei)
End If
Set wksQuelle = wbQuelle.Worksheets("Tabelle1") 'Quellen-Blatt in Datei 1
'Suchwert aus Zelle A3 in Quelldatei-Tabelle1 auslesen
varSuchen = wksQuelle.Range("A3").Value
'Ziel-Tabellenname aus Zelle B3 in Quelldatei-Tabelle1 auslesen
strTabelleZiel = wksQuelle.Range("B3").Text
'Prüfung auf die zulässigen Tabellennamen
Select Case strTabelleZiel
Case ""
MsgBox "In der Quell-Tabelle ist in Zelle B3 kein Tabellename eingetragen!"
GoTo ende
Case "Dienstag", "Mittwoch" 'u.s.w
'Zulässige Blattnamen für Zieltabelle, ggf. Liste anpassen
Case Else
MsgBox "In der Quell-Tabelle ist in Zelle B3 ein unzulässiger Tabellename eingetragen!"
GoTo ende
End If
If varSuchen  "" Then
'Tabellenblatt in der Zieldatei setzen
Set wksZiel = wbZiel.Worksheets(strTabelleZiel)             '####
'Zieldatei anzeigen
wbZiel.Activate
'Zieltabelle anzeigen
wksZiel.Activate
'Eingabewert im Zielblatt Spalte A suchen
Set rngSuchen = wksZiel.Columns(1).Find(what:=varSuchen, LookIn:=xlValues, _
lookat:=xlWhole)
If rngSuchen Is Nothing Then
MsgBox "Suchbegriff im Zielblatt nicht gefunden!"
Else
'Daten aus Datei 1 in gefundener Zeile in Zieltabelle Spalte C kopieren
lngZeileZiel = rngSuchen.Row
wksQuelle.Range("B6:O6").Copy Destination:=wksZiel.Cells(lngZeileZiel, 3)
wksZiel.Range("A1").Select
'Quelldatei wieder schliessen     '####
wbQuelle.Close savechanges:=True  '####
Set wbQuelle = Nothing            '####
End If
Else                                   '####
MsgBox "In Zelle A3 der Quell-Tabelle ist kein Suchbegriff eingetragen!"     '####
End If
End If
'Zeilen mit Sprungadressen gelöscht '####
ende:
If Err.Number  0 Then
Select Case Err.Number
Case 1004 'Zieldatei konnte nicht geöffnet werden
MsgBox " Nur für Fr. Romes! "
Case Else
MsgBox "Fehler: " & Err.Number & vbLf & Err.Description
End Select
End If
End Sub


Anzeige
AW: Text in anderer Datei suchen, kopiertes rechts ein
15.09.2008 19:04:49
Rudolf
Hallo Franz,
Danke für die schnelle Antwort.
Ich glaube jetzt ist ein kleiner Fehler drinn.
Ich lade mal die Testdateien hoch.
Gruß
Rudolf
AW: Text in anderer Datei suchen, kopiertes rechts ein
16.09.2008 11:25:00
fcs
Hallo Rudolf,
da hatte ich vergessen, bei der Prüfung der Namen für die Zieltabelle aus einem "End If" ein "End Select" zu machen.
Außerdem müssen im Code die zulässigen Namen für die Zieltabelle vorgegeben werden.
Gruß
Franz

Sub DatenKopieren()
Dim varSuchen, lngZeileZiel As Long, rngSuchen As Range
Dim wbZiel As Workbook
Dim wbQuelle As Workbook
Dim wksQuelle As Worksheet
Dim wksZiel As Worksheet
Dim strTabelleZiel As String                  '###
'  Const strPfad As String = "D:\Test2\"  'Verzeichnis der Zieldatei
Const strPfad As String = "C:\Lokale Daten\Test\Zwischenordner"  'Verzeichnis der Zieldatei
Const strZieldatei As String = "Ziel_neu.xls"   'Name der Zieldatei
On Error GoTo ende
Set wbQuelle = ActiveWorkbook
If MsgBox("Daten kopieren", vbOKCancel, "Daten nach Zieldatei kopieren") = vbOK Then
'Prüfen, ob Zieldatei schon geöffnet
For Each wbZiel In Workbooks
If LCase(wbZiel.Name) = LCase(strZieldatei) Then Exit For
Next
If wbZiel Is Nothing Then
'Zieldatei öffnen, wenn nicht geöffnet
Set wbZiel = Workbooks.Open(Filename:=strPfad & "\" & strZieldatei)
End If
Set wksQuelle = wbQuelle.Worksheets("Tabelle1") 'Quellen-Blatt in Datei 1
'Suchwert aus Zelle A3 in Quelldatei-Tabelle1 auslesen
varSuchen = wksQuelle.Range("A3").Value
'Ziel-Tabellenname aus Zelle B3 in Quelldatei-Tabelle1 auslesen
strTabelleZiel = wksQuelle.Range("B3").Text
'Prüfung auf die zulässigen Tabellennamen
Select Case strTabelleZiel
Case ""
MsgBox "In der Quell-Tabelle ist in Zelle B3 kein Tabellename eingetragen!"
GoTo ende
Case "Dienstag", "Mittwoch", "Tabelle2" 'u.s.w
'Zulässige Blattnamen für Zieltabelle, ggf. Liste anpassen
Case Else
MsgBox "In der Quell-Tabelle ist in Zelle B3 ein unzulässiger Tabellename eingetragen!"
GoTo ende
End Select
If varSuchen  "" Then
'Tabellenblatt in der Zieldatei setzen
Set wksZiel = wbZiel.Worksheets(strTabelleZiel)             '####
'Zieldatei anzeigen
wbZiel.Activate
'Zieltabelle anzeigen
wksZiel.Activate
'Eingabewert im Zielblatt Spalte A suchen
Set rngSuchen = wksZiel.Columns(1).Find(what:=varSuchen, LookIn:=xlValues, _
lookat:=xlWhole)
If rngSuchen Is Nothing Then
MsgBox "Suchbegriff im Zielblatt nicht gefunden!"
Else
'Daten aus Datei 1 in gefundener Zeile in Zieltabelle Spalte C kopieren
lngZeileZiel = rngSuchen.Row
wksQuelle.Range("B6:O6").Copy Destination:=wksZiel.Cells(lngZeileZiel, 3)
wksZiel.Range("A1").Select
'Quelldatei wieder schliessen     '####
wbQuelle.Close savechanges:=True  '####
Set wbQuelle = Nothing            '####
End If
Else                                   '####
MsgBox "In Zelle A3 der Quell-Tabelle ist kein Suchbegriff eingetragen!"     '####
End If
End If
'Zeilen mit Sprungadressen gelöscht '####
ende:
If Err.Number  0 Then
Select Case Err.Number
Case 1004 'Zieldatei konnte nicht geöffnet werden
MsgBox " Nur für Fr. Romes! "
Case Else
MsgBox "Fehler: " & Err.Number & vbLf & Err.Description
End Select
End If
End Sub


Anzeige
AW: Text in anderer Datei suchen, kopiertes rechts ein
16.09.2008 12:02:21
Rudolf
Hallo Franz,
vielen vielen Dank.
Genau das ist es!!
Spuper und mit viel Geduld gemacht.
Ich wünsche dir noch eine schöne Woche.
Gruß
Rudolf
AW: Text in anderer Datei suchen, kopiertes rechts ein
15.09.2008 12:04:25
Rudolf
Hallo Franz,
ich habe gerade festgestellt (Office 2007) wenn mann den kopiervorgang mit nein abbricht
und es ist nur die Quelldatei offen stürzt Excel ab.
ist jedoch noch eine datei offen so wird diese aktiv.
Vorschlag: schließen entfernen.
Gruß
Rudolf
AW: Text in anderer Datei suchen, kopiertes rechts ein
15.09.2008 12:26:03
Rudolf
Hab es mal so Laienhaft geändert.
Die Stationen haben ja auch nicht die Zieldatei und so habe sie wenn sie auf den Button klicken der nur für das Büro gedacht ist dann nur die Meldung "Nur für Fr.Romes"

Sub DatenKopieren()  hab hier Private weggeholt (wußte sonst nicht wie ich das ansprechen  _
konnte, sorry)
Dim varSuchen, lngZeileZiel As Long, rngSuchen As Range
Dim wbZiel As Workbook
Dim wbQuelle As Workbook
Dim wksQuelle As Worksheet
Dim wksZiel As Worksheet
Const strPfad As String = "D:\Test2\"  'Verzeichnis der Zieldatei
Const strZieldatei As String = "Ziel_neu.xls"   'Name der Zieldatei
On Error GoTo ende
Set wbQuelle = ActiveWorkbook
If MsgBox("Daten kopieren", vbOKCancel, "Daten nach Zieldatei kopieren") = vbOK Then
'Prüfen, ob Zieldatei schon geöffnet
For Each wbZiel In Workbooks
If LCase(wbZiel.Name) = LCase(strZieldatei) Then Exit For
Next
If wbZiel Is Nothing Then
'Zieldatei öffnen, wenn nicht geöffnet
Set wbZiel = Workbooks.Open(Filename:=strPfad & "\" & strZieldatei)
End If
Set wksQuelle = wbQuelle.Worksheets("Tabelle1") 'Quellen-Blatt in Datei 1
'Suchwert aus Zelle A3 in Quelldatei-Tabelle1 auslesen
varSuchen = wksQuelle.Range("A3").Value
If varSuchen  "" Then
'Tabellenblatt in der Zieldatei setzen
Set wksZiel = wbZiel.Worksheets("Tabelle2")
'Zieldatei anzeigen
wbZiel.Activate
'Zieltabelle anzeigen
wksZiel.Activate
'Eingabewert im Zielblatt Spalte A suchen
Set rngSuchen = wksZiel.Columns(1).Find(what:=varSuchen, LookIn:=xlValues, lookat:= _
xlWhole)
If rngSuchen Is Nothing Then
MsgBox "Suchbegriff im Zielblatt nicht gefunden!"
Else
'Daten aus Datei 1 in gefundener Zeile in Zieltabelle Spalte C kopieren
lngZeileZiel = rngSuchen.Row
wksQuelle.Range("B6:O6").Copy Destination:=wksZiel.Cells(lngZeileZiel, 3)
End If
wksZiel.Range("A1").Select
GoTo end3
End If
End If
' wbQuelle.Close savechanges:=True
' Set wbQuelle = Nothing
GoTo end2
end2:
ende:
If Err.Number  0 Then
MsgBox " Nur für Fr. Romes! "
'MsgBox "Fehler: " & Err.Number & vbLf & Err.Description
End If
end3:
End Sub


Fett die Änderungen.
Gruß
Rudolf

Anzeige
Anzeige

Links zu Excel-Dialogen

Beliebteste Forumthreads (12 Monate)

Anzeige

Beliebteste Forumthreads (12 Monate)

Anzeige
Anzeige
Anzeige
Archiv - Verwandte Themen