Microsoft Excel

Herbers Excel/VBA-Archiv

Bewerten Sie hier bitte das Excel-Portal
Auftragsprogrammierung: Nehmen Sie hier Kontakt auf

Zählenwenn mit Hindernissen | Herbers Excel-Forum


Betrifft: Zählenwenn mit Hindernissen von: Herbert
Geschrieben am: 16.10.2008 09:13:10

Hallo Formelkünstler

Ich habe eine große Tabelle mit folgenden Einträgen:
231
231
232
232
2x 231
3x 232
lot8
233
lot8
231
2x lot8

etc.

Mein Problem: Mit Zählenwenn z.B. 231 bekomme ich logischerweise als Ergebnis 2, aber mein
"Wunsch" wäre Ergebnis 4. (2 Zellen mit 231 "alleine" + eine Zelle 2x 231 = 4)
Ich kann die Tabelle nicht verändern und meine Formelkünste sind beschr....
Mit LINKS kann ich die Zahl rausziehen, aber wie konstuiert man das ganze zusammen um eine
Summe zu bekommen, die zählt und innerhalt der Zelle multipliziert?

Danke für Hilfe im Voraus

Gruß Herbert

  

Betrifft: AW: Zählenwenn mit Hindernissen von: Bertram
Geschrieben am: 16.10.2008 10:21:33

Hallo Herbert,

meinst du so was? https://www.herber.de/bbs/user/56054.xls

In deinem Bsp. wäre das Ergebnis allerdings 5 (3 "alleine" + 2x 231)

Gruß
Bertram


  

Betrifft: AW: Zählenwenn mit Hindernissen von: fcs
Geschrieben am: 16.10.2008 10:23:12

Hallo Herbert,

folgende Formel als Matrix-Formel (Formeleingabe mit Shift+Strg+Enter abschließen) summiert nach deinen Wünschen. Sie funktioniert mit Zahlen und Texteinträgen.

=SUMME(WENN(B1=$A$2:$A$13;1;WENN(ISTFEHLER(SUCHEN("x ";$A$2:$A$13;1));0;
WENN(RECHTS($A$2:$A$13;LÄNGE($A$2:$A$13)-SUCHEN("x ";$A$2:$A$13;1)-1)=
LINKS(B1;LÄNGE(B1));WERT(LINKS($A$2:$A$13;SUCHEN("x ";$A$2:$A$13;1)-1));0))))


In Zelle B1 steht hierbei der Wert für den die Anzahl berechnet werden soll, im Bereich A2:A13 die auszuwertenden Werte.

Formelvariante, ebenfalls als Matrixformel. Funktioniert jedoch nur, wenn die gesuchten Zahlen mindestens 3 bzw. 2 Ziffern beinhalten und die Anzahl vor dem "x" max. 99 bzw. 9 ist.

=SUMME(WENN(ISTFEHLER(SUCHEN(B1;A2:A13;1));0;
WENN(ISTFEHLER(SUCHEN("x ";A2:A13;1));1;WERT(LINKS(A2:A13;SUCHEN("x ";A2:A13;1)-1)))))


Gruß
Franz


  

Betrifft: AW: Zählenwenn mit Hindernissen von: JogyB
Geschrieben am: 16.10.2008 10:40:21

Ich bin jetzt nicht der große Formelkünstler (kann also etwas umständlich sein), aber es funktioniert auf jeden Fall mal. Ich bin von Zelle A1 bis A11 ausgegangen, den Bereich mußt Du entsprechend anpassen.

{=SUMME(WENN(ISTFEHLER(FINDEN("231";A1:A11));0;1)*WENN(ISTFEHLER(FINDEN("x ";A1:A11));1;LINKS(A1:A11; FINDEN("x ";A1:A11)-1))) }

Die {} nicht eingeben, sondern die Eingabe mit Strg+Shift+Enter abschliessen, dann erscheinen diese automatisch (zeigt an, dass es eine Matrixformel ist).

Wenn noch Eingaben wie "abcx def" oder ein x and erster Stelle abgefangen werden sollen, dann wäre die Formel:

{=SUMME(WENN(ISTFEHLER(FINDEN("231";A1:A11));0;1)*WENN(ISTFEHLER(FINDEN("231";A1:A11));0;1) *WENN(ISTFEHLER(FINDEN("x";A1:A11));1;WENN(ISTZAHL(1*LINKS(A1:A11;FINDEN("x";A1:A11)-1)); LINKS(A1:A11;FINDEN("x";A1:A11)-1);1))) }

Ich bekomme als Ergebnis mit Deinem Beispiel dann 5 (nicht 4, sind ja drei einzelne 231).

Gruss, Jogy


  

Betrifft: Ihr seit einfach Klasse ! ! ! ! Danke o.T. von: Herbert
Geschrieben am: 16.10.2008 11:36:14




  

Betrifft: Ihr seit einfach Klasse ! ! ! ! Danke o.T. von: Herbert
Geschrieben am: 16.10.2008 11:36:21