Auswertung größere Datenmenge über Monate hinweg

Beiträge zum Forumthread

Beiträge zu diesem Forumthread

Betreff

Datum

Anwender

Hallo zusammen,
Ich konnte gestern leider nicht antworten weil ich unterwegs war...
die Datei ist leider mit 4,9 MB zu groß zum hochladen und auch gezippt schafft sie es leider nicht.
Dankeschonmal für die erste Antwort.
Punkt 1: die Berechnungen (Kostenarte-, stellen- trägerechnung) können sich immer nur auf einen Zeitraum beziehen, daher wird der Ansatz am Enfang des Prozesses die Datenmenge zu erhöhen durch "Sammeln der importe" wohl wenig bringen.
Zur Erklärung die "Schritte im Prozess"
a) GuV über 1 Zeitraum holen
b) importieren
c) Kostenartenrechnung automatisch (Abgrenzung der Kosten)
d) Kostenstellenrechnung automatisch (Zuweisung auf Kostenstellen und Profit Center)
e) Kostenträgerrechnung automatisch ( Zuweisung auf Produkte)
f) Ergebnisse - fertig
Also was ich sammeln muss is quasi das "Prozessergebnis".
Das Bild, was ich vor Augen habe ist so:
Ein Tabellenblatt mit den einzelnen Monaten als Überschrift. Ein Makro prüft im Datenimport GuV ab, zu welchem Monat die Ergebnisse passen und trägt dann die Werte aus den Berechnungen in die einzelnen Spalten ein. Er trägt Sie so ein, dass Sie "gefixt" sind. Als wie wenn man copy paste und dann Werte einfügen macht. D.h. Ich habe zum beispiel einmal Januar durchrechnen lassen - Werte stehen drin. dann kommt die GuV von Februar, die Importdaten von Januar werden überspielt, neue Ergebnisse werden berechnet. In die Spalte Februar kommen die neuen ergebnisse rein, Januar werte bleiben drin stehen weil gefixt. Jetzt hat sich im Nachhinhein etwas an der GuV Januar geändert und ich will das nochmal neu durchspielen lassen. Also Januar importieren. Durchrechnen lassen neue Ergebnisse - in Spalte Januar werden die alten Ergebnisse durch die neuen ersetzt.
Punkt 2: Also Auslagern können wir gerne machen. Ding is, dass irgendwie sichergestellt werden muss, dass die "Prozesschritte" eingehalten werden.
Grüße,
Lucia

Hallo Lucia,
hier mal eine kleine Beispieldatei mit dem unten geposteten Makro. Das Blatt mit den Monatsergebnissen ist dabei in der gleichen Datei angelegt wie das Blatt mit den Rohdaten und den Berechnungsergebnissen. Nach jeder neuen Monatsberechnung wird zusätzlich das Blatt mit den Monatsergebnissen in eine neue Arbeitsmappe kopiert und mit Zeitstempel im Dateinamen gesichert. So kannst du notfalls Ergebnisse wieder reparieren.
https://www.herber.de/bbs/user/62611.xls
Prinzipiell könnte man die Monatsergebnisse auch in einer externen Datei verwalten. Im Makro müsste dann zusätzlich das Öffnen und Schliessen der entsprechenden Datei eingebaut werden.
Gruß
Franz
P.S. Eswas zu spät ist mir eingefallen, dass auch der Blattschutz für das Blatt mit den Monatsergebnissen aktiviert werden sollte. Diese Anpassung fehlt in der Datei noch, ist aber im Code unten enthalten.


'Erstellt mit Excel 2007 im Kompatibilitätsmodus für Version 97-2003
Option Explicit
Sub Monatsdaten_nach_Statistik()
'Daten für den Monat aus dem Ergebnisblatt in das Statistikblatt übertragen
Dim wksErgebnis As Worksheet, wksStatistik As Worksheet
Dim lngSpalteStat As Long, varMonat
Set wksErgebnis = Worksheets("Ergebnisse")
Set wksStatistik = Worksheets("Statistik")
'Monat aus Ergebnisblatt auslesen
varMonat = wksErgebnis.Range("B2")
If MsgBox(Prompt:="Ergebnisdaten für Monat """ & varMonat & """ jetzt übertragen?", _
Buttons:=vbQuestion + vbYesNo, Title:="Monatsdaten nach Statistik") = vbYes Then
With wksStatistik
'Spalte des Monats im Statistikblatt in Zeile 2 ab Spalte 2 suchen
.Unprotect
Application.ScreenUpdating = False
For lngSpalteStat = 2 To .Cells(2, .Columns.Count).End(xlToLeft).Column
If varMonat = .Cells(2, lngSpalteStat).Value Then Exit For
Next
'Monat eintragen, falls noch nicht vorhanden
If IsEmpty(.Cells(2, lngSpalteStat)) Then .Cells(2, lngSpalteStat) = varMonat
'Daten von Ergebnis nach Statistik kopieren (nur Werte)
'Bereich D4:D31 ab Zeile 3 eintragen
wksErgebnis.Range("D4:D31").Copy
.Cells(3, lngSpalteStat).PasteSpecial Paste:=xlPasteValues
'Bereich D35:D41 ab Zeile 34 eintragen
wksErgebnis.Range("D35:D41").Copy
.Cells(34, lngSpalteStat).PasteSpecial Paste:=xlPasteValues
'ggf. weitere Bereiche nach gleichem Schema übertragen
.Protect
Application.CutCopyMode = False
Application.ScreenUpdating = False
End With
'Sicherungskopie vom Blatt Statistik erstellen
Call Statistik_Sicherungskopie
End If
End Sub
Sub Statistik_Sicherungskopie()
'Blatt Statistik wird in eine neue Arbeitsmappe kopiert
Dim wbCopy As Workbook, wks As Worksheet
Dim strDatei, strVerzeichnis As String
strVerzeichnis = ActiveWorkbook.Path 'Verzeichnis der Sicherungskopie
strDatei = strVerzeichnis & Application.PathSeparator & "GuV_Statistik_" _
& Format(Now, "YYYYMMDD_hhmmss")
Set wks = Worksheets("Statistik")
wks.Copy
Set wbCopy = ActiveWorkbook
With wbCopy
.BuiltinDocumentProperties("Title") = "Sicherungskopie " & Format(Now, "YYYY-MM-DD hh:mm:ss" _
)
.BuiltinDocumentProperties("Subject") = "GuV Test Gesellschaft GmbH & Co KG"
.SaveAs Filename:=strDatei, FileFormat:=-4143, ReadOnlyRecommended:=True
.Close savechanges:=False
End With
End Sub

Beliebteste Forumthreads (12 Monate)

Auswertung größere Datenmenge über Monate hinweg

3 Beiträge zum Forumthread Beiträge zu diesem Forumthread

VBA Beispiele zu verwandten Themen

Beliebteste Forumthreads (12 Monate)

Beliebteste Forumthreads (12 Monate)

3
Beiträge zum Forumthread

Beiträge zu diesem Forumthread