Microsoft Excel

Herbers Excel/VBA-Archiv

Auswahlliste | Herbers Excel-Forum


Betrifft: Auswahlliste von: Andreas
Geschrieben am: 19.06.2009 12:23:32

Hallo an alle

ich hab da mal ne Frage.
Ich habe eine Liste mit Namen(ab A30), Telefonnummer(ab C30), Mobilnummer(ab D30) - (ca 500 Einträge)
Ich möchte In Zelle A2 einenNamen eingeben und ab Zelle B2 die passenden Einträge aufgelistet bekommen.
Ich habe eine Formel hier aus dem Forum bekommen - leider macht sie es nicht so richttig.
Ecventuell kann sich diese Liste mal jemand ansehenund mir einen Tip geben.
Für jegliche Hilfe wäre ich dankbar.

Eine Datei habe ich zum besseren Verständnis mit hochgeladen.

Andreas
https://www.herber.de/bbs/user/62571.xls

  

Betrifft: AW: Auswahlliste von: Hajo_Zi
Geschrieben am: 19.06.2009 12:29:59

Hallo Andreas,

gebe die Bereiche absolut an.

Rufnummern

 BCD
2AA-Egon01239
3AA-Fred012348
4     
5     
6     
7     

verwendete Formeln
Zelle Formel
B2 {=WENN(ZEILE()>SUMME(ISTZAHL(SUCHEN(A$2;A$30:A$500))*1);"";INDEX(A:A; KKLEINSTE(WENN(ISTZAHL(SUCHEN(A$2;A$30:A$500));ZEILE(A$30:A$500));ZEILE(A1))))}
C2 =WENN(ISTFEHLER(SVERWEIS($B2;$A$22:$D$300;SPALTE();0));"";SVERWEIS($B2;$A$22:$D$300;SPALTE();0))
D2 =WENN(ISTFEHLER(SVERWEIS($B2;$A$22:$D$300;SPALTE();0));"";SVERWEIS($B2;$A$22:$D$300;SPALTE();0))
B3 {=WENN(ZEILE()>SUMME(ISTZAHL(SUCHEN(A$2;A$30:A$500))*1);"";INDEX(A:A; KKLEINSTE(WENN(ISTZAHL(SUCHEN(A$2;A$30:A$500));ZEILE(A$30:A$500));ZEILE(A2))))}
C3 =WENN(ISTFEHLER(SVERWEIS($B3;$A$22:$D$300;SPALTE();0));"";SVERWEIS($B3;$A$22:$D$300;SPALTE();0))
D3 =WENN(ISTFEHLER(SVERWEIS($B3;$A$22:$D$300;SPALTE();0));"";SVERWEIS($B3;$A$22:$D$300;SPALTE();0))
B4 {=WENN(ZEILE()>SUMME(ISTZAHL(SUCHEN(A$2;A$30:A$500))*1);"";INDEX(A:A; KKLEINSTE(WENN(ISTZAHL(SUCHEN(A$2;A$30:A$500));ZEILE(A$30:A$500));ZEILE(A3))))}
C4 =WENN(ISTFEHLER(SVERWEIS($B4;$A$22:$D$300;SPALTE();0));"";SVERWEIS($B4;$A$22:$D$300;SPALTE();0))
D4 =WENN(ISTFEHLER(SVERWEIS($B4;$A$22:$D$300;SPALTE();0));"";SVERWEIS($B4;$A$22:$D$300;SPALTE();0))
B5 {=WENN(ZEILE()>SUMME(ISTZAHL(SUCHEN(A$2;A$30:A$500))*1);"";INDEX(A:A; KKLEINSTE(WENN(ISTZAHL(SUCHEN(A$2;A$30:A$500));ZEILE(A$30:A$500));ZEILE(A4))))}
C5 =WENN(ISTFEHLER(SVERWEIS($B5;$A$22:$D$300;SPALTE();0));"";SVERWEIS($B5;$A$22:$D$300;SPALTE();0))
D5 =WENN(ISTFEHLER(SVERWEIS($B5;$A$22:$D$300;SPALTE();0));"";SVERWEIS($B5;$A$22:$D$300;SPALTE();0))
B6 {=WENN(ZEILE()>SUMME(ISTZAHL(SUCHEN(A$2;A$30:A$500))*1);"";INDEX(A:A; KKLEINSTE(WENN(ISTZAHL(SUCHEN(A$2;A$30:A$500));ZEILE(A$30:A$500));ZEILE(A5))))}
C6 =WENN(ISTFEHLER(SVERWEIS($B6;$A$22:$D$300;SPALTE();0));"";SVERWEIS($B6;$A$22:$D$300;SPALTE();0))
D6 =WENN(ISTFEHLER(SVERWEIS($B6;$A$22:$D$300;SPALTE();0));"";SVERWEIS($B6;$A$22:$D$300;SPALTE();0))
B7 {=WENN(ZEILE()>SUMME(ISTZAHL(SUCHEN(A$2;A$30:A$500))*1);"";INDEX(A:A; KKLEINSTE(WENN(ISTZAHL(SUCHEN(A$2;A$30:A$500));ZEILE(A$30:A$500));ZEILE(A6))))}
C7 =WENN(ISTFEHLER(SVERWEIS($B7;$A$22:$D$300;SPALTE();0));"";SVERWEIS($B7;$A$22:$D$300;SPALTE();0))
D7 =WENN(ISTFEHLER(SVERWEIS($B7;$A$22:$D$300;SPALTE();0));"";SVERWEIS($B7;$A$22:$D$300;SPALTE();0))
{} Matrixformel mit Strg+Umschalt+Enter abschließen

Tabellendarstellung in Foren Version 1.7


GrußformelHomepage


  

Betrifft: AW: Auswahlliste von: Andreas
Geschrieben am: 19.06.2009 12:53:47

Hallo Hajo

auch Dir schönen Dank für die Mühen

schönes Wocheende

Andreas


  

Betrifft: Zeile()-1 und absolute Zellbezüge von: NoNet
Geschrieben am: 19.06.2009 12:39:13

Hallo Andreas,

in Deiner Tabelle befinden sich 2 Fehler :
- Die Funktion in B2 muss folgendermassen lauten :

=WENN(ZEILE()-1>SUMME(ISTZAHL(SUCHEN(A$2;A$30:A$500))*1);"";INDEX(A:A; KKLEINSTE(WENN(ISTZAHL(SUCHEN(A$2;A$30:A$500));ZEILE(A$30:A$500));ZEILE(A1))))

Diese Funktion bitte nach unten kopieren !

Die Funktion in C2 muss so lauten : =SVERWEIS(B2;A$30:D$500;3;0)
Die Funktion in D2 muss so lauten : =SVERWEIS(B2;A$30:D$500;4;0)
Beide Funktionen nach unten kopieren !

Gruß, NoNet


  

Betrifft: AW: Zeile()-1 und absolute Zellbezüge von: Andreas
Geschrieben am: 19.06.2009 12:52:53

Hallo NoNet

ich glaub das war es - jetzt scheint es zu funktionieren

DANKE und ein schönes Wochenende

Andreas


  

Betrifft: AW: Zeile()-1 und absolute Zellbezüge von: andreas
Geschrieben am: 19.06.2009 15:08:00

Hallo nochmal

hab da doch noch eine Frage

wenn ich zwischen den Zeilen zur besseren Übersicht noch jeweils eine Zeile einfüge,
dann gibt er mir wieder nicht alle Namen an.
Die Formel hab ich - nach meiner Meinung - in letzter Angabe jeweils richtig angegeben ( "A1" "A2" usw.)
Vielleicht gibt es da noch einen Trick - Hängt das mit der Matrixformel zusammen.
Ich bekomme es leider nicht hin
Für eventuelle Hilfe wäre ich dankbar

Andreas


  

Betrifft: Zwischen welchen Zeilen wird eine eingefügt ? von: NoNet
Geschrieben am: 19.06.2009 15:45:50

_oT


  

Betrifft: AW: Zwischen welchen Zeilen wird eine eingefügt ? von: Andreas
Geschrieben am: 19.06.2009 18:37:04

Hallo

ich wollte ca. 20 Zeilen untereinander haben, wo die Namen aufgelistet werden, und dazwischen wollte ich
eine Leerzeile einfügen, damit ich diese Angaben dann besser lesen kann.
War halt so eine Idee...
Würde das denn gehen

Andreas


  

Betrifft: ändere einfach die zeilenhöhe... gruß von: robert
Geschrieben am: 19.06.2009 18:49:13




  

Betrifft: AW: Zeile()-1 und absolute Zellbezüge von: Andreas
Geschrieben am: 19.06.2009 20:19:15

Hallo Robert

das möchte ich ja gerade nicht machen, da ich die Ausgabefelde einen 3-D Effekt geben möchte.
Und das geht am besten, wenn man eine Zelle zwischen fügt.

Andreas


  

Betrifft: Frage zur Formel in B2... von: robert
Geschrieben am: 20.06.2009 07:57:57

hi,

hast du ein anderes ergebnis ? -siehe datei

Müller,a kann nicht stimmen-oder ?

gruß
robert

https://www.herber.de/bbs/user/62591.xls


  

Betrifft: AW: Zeile()-1 und absolute Zellbezüge von: Andreas
Geschrieben am: 20.06.2009 14:37:42

Hallo Robert



ich hab die Tabelle mal so gemacht, wie ich sie mir vorstelle.

Wenn ich "AA" eingebe erscheinen nur sechs Einträge, obwohl mehr vorhanden sind.

Wenn ich nur "A" eingebe, kommen fünf Einträge mit AA am Anfang und der "Müller, A" - wegen dem "A"



Wäre aber nicht O.K.



Und da komme ich nicht weiter..... habe die Datei mal angehängt.



Andreas

https://www.herber.de/bbs/user/62595.xls


  

Betrifft: AW: Zeile()-1 und absolute Zellbezüge von: Josef Ehrensberger
Geschrieben am: 20.06.2009 14:57:50

Hallo Andreas,

Rufnummern

 ABCDEFGHI
1 Eingabe Suchname in A2 gefundene Einträge Nummer mobil / alternativ 
2 aa AA-1 123 9 
3        
4  AA-2 1234 8 
5         
6   AA_3 1 1 
7         
8   AA_4 2 11 
9         
10   AA_5 3 22 
11         
12   AA_6 4 33 
13         
14   AA_7 5 44 
15         
16   AA_8 6 55 
17         
18   AA_9 7 66 
19         
20   AA_10 8 77 
21         
22   AA_11 9 88 
23         
24         
25         
26         
27         
28         
29         
30         
31         
32         
33         

Formeln der Tabelle
ZelleFormel
D2{=WENN(ZEILE()/2>SUMME(ISTZAHL(SUCHEN(B$2;B$36:B$504))*1); "";INDEX(B:B; KKLEINSTE(WENN(ISTZAHL(SUCHEN(B$2;B$36:B$504)); ZEILE(B$36:B$504)); ZEILE()/2)))}
F2=WENN(D2="";"";SVERWEIS(D2;B$35:H$504;5;0))
H2=WENN(D2="";"";SVERWEIS(D2;B$34:H$504;7;0))
Enthält Matrixformel:
Umrandende
{ } nicht miteingeben,
sondern Formel mit STRG+SHIFT+RETURN abschließen!
Matrix verstehen


Excel Tabellen im Web darstellen >> Excel Jeanie HTML 4




Gruß Sepp



  

Betrifft: AW: Zeile()/2 ist gut, aber warum.. von: robert
Geschrieben am: 20.06.2009 15:47:53

hi sepp

..kommt bei A auch Müller,anton ? - wegen a

wie könnte man das lösen?

gruß robert


  

Betrifft: AW: Zeile()/2 ist gut, aber warum.. von: Josef Ehrensberger
Geschrieben am: 20.06.2009 16:00:49

Hallo Robert,

sicher wegen dem "a", warum wohl sonts ;-))

Lösung gibt's auch, suchenwir halt nur am Anfang des Zellinhaltes und immer so viele Buchstaben,
wie in B2 stehen.

Rufnummern

 ABCDEFGH
1 Eingabe Suchname in A2 gefundene Einträge Nummer mobil / alternativ
2 aa AA-1 123 9
3       
4  AA-2 1234 8
5        
6   AA_3 1 1
7        
8   AA_4 2 11
9        
10   AA_5 3 22
11        
12   AA_6 4 33
13        
14   AA_7 5 44
15        
16   AA_8 6 55
17        
18   AA_9 7 66
19        
20   AA_10 8 77
21        
22   AA_11 9 88
23        
24        
25        
26        
27        
28        
29        
30        
31        
32        

Formeln der Tabelle
ZelleFormel
D2{=WENN(ZEILE()/2>SUMME(ISTZAHL(SUCHEN(B$2;LINKS(B$36:B$504;LÄNGE(B$2))))*1); "";INDEX(B:B; KKLEINSTE(WENN(ISTZAHL(SUCHEN(B$2;LINKS(B$36:B$504;LÄNGE(B$2)))); ZEILE(B$36:B$504)); ZEILE()/2)))}
Enthält Matrixformel:
Umrandende
{ } nicht miteingeben,
sondern Formel mit STRG+SHIFT+RETURN abschließen!
Matrix verstehen


Excel Tabellen im Web darstellen >> Excel Jeanie HTML 4




Gruß Sepp



  

Betrifft: Danke Sepp-super :-)) owT von: robert
Geschrieben am: 20.06.2009 16:13:24




  

Betrifft: Problem:die eingefügten Zeilen.. von: robert
Geschrieben am: 20.06.2009 15:32:58

hi,

habs soweit hinbekommen, dass jetz alle kommen , wenn du 2 buchstaben eingibst-zB. AA

bei nur A kommen alle,die ein A enthalten-habe keine lösung,
aber viell.kannst du mit den 2 buchstaben leben.....:-)

probier es einfach aus..

gruß
robert

https://www.herber.de/bbs/user/62596.xls


  

Betrifft: Danke an alle von: Andreas
Geschrieben am: 21.06.2009 12:19:37

Guten Tag an alle

Ich konnte heute erst Eure Nachricht lesen und wollte mich bei allen bedanken, die mir bei meinem
Problem geholfen haben.
Danke nochmals an robert, Josef Ehrensberger und noNet.

Ich wünsche euch einen schönen Tag noch, mal sehen, bei welchen Problem ich demnächst stehe :-))

Andreas