Änderunge nachverfolgen

Hallo,
wir möchten alle Änderungen einer Arbeitsmappe in dieser Datei "protokollieren", ohne jedoch ständig die Änderungen freigeben (annehmen und ablehnen) zu müssen.
Auch eine gleichzeitige Bearbeitung soll nicht stattfinden können.
1. Kann man das ohne die Änderungen tun, die von Makros verursacht wurden?
2. Werden bei mehr als 65.536 Änderungen mehrere Tabellenblätter "Änderungsprotokoll" erstellt?
3. Kann man einen Supervisor ernennen, der die Änderungen nachverfolgt oder können das immer alle?
Ich möchte eigentlich eine Liste erzeugen mit allen manuellen Änderungen (ohne Markoänderungen):
wer, wann, welche Anderung wo! Und diese Liste kann nur ich sehen!
Wie mache ich das?
MfG
Oliver

Beiträge zum Forumthread

Beiträge zu diesem Forumthread

Betreff

Benutzer

Hallo Oliver,
ich hoffe, du verwendest das nicht um deine Mitarbeiter zu überwachen, da könntest du probleme mit dem Datenschutz bekommen.
In allen Makros die Werte in die Tabelle schreiben sezt du am Anfang 'Application.EnableEvents = False'
und am Ende 'Application.EnableEvents = True'.
Dann kopierts du diesen Code in die Datei (Module beachten!)

' **********************************************************************
' Modul: DieseArbeitsmappe Typ: Element der Mappe(Sheet, Workbook, ...)
' **********************************************************************

Option Explicit

Private Sub Workbook_SheetChange(ByVal Sh As Object, ByVal Target As Range)
  Dim rng As Range

  For Each rng In Target
    watchChanges Sh.Name, rng.Address(0, 0), rng.Value
  Next
End Sub

' **********************************************************************
' Modul: Modul1 Typ: Allgemeines Modul
' **********************************************************************

Option Explicit

Sub watchChanges(sSheet As String, sCell As String, vValue As Variant)
  Dim strFile As String, strUser As String, strDateTime As String
  Dim strMsg As String, strSep As String

  strUser = Environ("Username")
  strDateTime = Format(Now, "dd.MM.yy - hh:mm:ss")
  strSep = ";" 'Trennzeichen
  strFile = "E:\Temp\watch.txt" 'Ausgabedatei - Pfad und Name anpassen! (wid automatisch angelegt)

  strMsg = strDateTime & strSep & strUser & strSep & sSheet & _
    strSep & sCell & strSep & CStr(vValue)

  Open strFile For Append Shared As #1
  Print #1, strMsg
  Close #1
End Sub

Passe den Pfad zur Textdatei an.
Dann hast du die Protokollierung in einer separaten Datei unabhängig von der Tabelle.

Gruß Sepp

Beliebteste Forumthreads (12 Monate)

4 Beiträge zum Forumthread Beiträge zu diesem Forumthread

VBA Beispiele zu verwandten Themen

Beliebteste Forumthreads (12 Monate)

Beliebteste Forumthreads (12 Monate)

4
Beiträge zum Forumthread

Beiträge zu diesem Forumthread