Live-Forum - Die aktuellen Beiträge
Anzeige
Archiv - Navigation
1088to1092
Aktuelles Verzeichnis
Verzeichnis Index
Übersicht Verzeichnisse
Vorheriger Thread
Rückwärts Blättern
Nächster Thread
Vorwärts blättern
Anzeige
HERBERS
Excel-Forum (Archiv)
20+ Jahre Excel-Kompetenz: Von Anwendern, für Anwender
Inhaltsverzeichnis

Kopfzeilenformat

Kopfzeilenformat
thomas3
Hallo zusammen,
in einem Ordner sind viele Dateien gespeichert. Diese Dateien muß ich alle aufmachen, Kopf- und Fußzeile löschen, neue Kopf- und Fußzeile vergeben und unter neuen Namen an einem anderen Ort abspeichern
Fast alles kein Problem.
Kopf- und Fußzeile haben nun das "Problem", dass es unterschiedliche Formate gibt. Also unterschiedliche Schriftypen, -größen und z.B. Fett oder nicht. Unten stehend meine Zeile, wie ich die einzelnen Zeilen auslese und dann in den entsprechenden Kopf- / Fußzellenbereich beame.
Die Frage ist nun, wie kann ich die Formate mitübernehmen ?
Liebe Grüße
Thomas
'linker Bereich
'in den Zeilen 12 bis 17 steht der entsprechende Text
'Text auslesen
For r = 12 To 17
inhkl = inhkl & Cells(r, 3) & Chr(13)
Next r
und
With ActiveSheet.PageSetup
.LeftHeader = inhkl
End With

5
Beiträge zum Forumthread
Beiträge zu diesem Forumthread

Betreff
Benutzer
Anzeige
AW: Kopfzeilenformat
26.07.2009 09:13:07
Hajo_Zi
Hallo Thomas,
benutze doch einfach den Makrorecorder, der liefert oft auch gute Ansätze.

AW: Kopfzeilenformat
26.07.2009 10:08:07
fcs
Hallo Thomas,
hier ein Beispiel, wie du die einzelnen Zeilen unterschiedlich formatieren kannst.
Die genau Bezeichnung der Schriften ermittels du am besten durch Aufzeichnen per Makro.
Gruß
Franz
'
'Text auslesen und formatieren
For r = 12 To 17
Select Case r
Case 12
'Zeile 12 in Times New Roman, Standard, Größe 12 + Zeilenschaltung nach Text
inhkl = inhkl & "&""Times New Roman,Standard""&12" & Cells(r, 3) & Chr(10)
Case 13
'Zeile 13 in Arial, Fett, Größe 10 + Zeilenschaltung nach Text
inhkl = inhkl & "&""Arial,Fett""&10" & Cells(r, 3) & Chr(10)
Case 14
'Zeile 14 in Arial, Standard, Größe unverändert + Zeilenschaltung nach Text
inhkl = inhkl & "&""Arial,Standard""" & Cells(r, 3) & Chr(10)
Case 15
'Zeile 15 Schriftart unverändert, Größe 8 + Zeilenschaltung nach Text
inhkl = inhkl & "&8" & Cells(r, 3) & Chr(10)
Case 16
'Zeile 16 Formatierung unverändert + Zeilenschaltung nach Text
inhkl = inhkl & Cells(r, 3) & Chr(10)
Case 17
'Formatierung unverändert, keine Zeilenschaltung nach Text
inhkl = inhkl & Cells(r, 3)
End Select
Next r
'In Koppfzeile links eintragen
With ActiveSheet.PageSetup
.LeftHeader = inhkl
End With
End Sub

Anzeige
AW: Kopfzeilenformat
26.07.2009 10:29:36
Herby
Hallo Thomas,
beim auslesen der einzelen Kopf- und Fusszeilen werden auch
die Steuerungszeichen für Schriftgrösse, etc. mit ausgelesen.
Der String, der die Kopfzeile enthält sieht z.B. so aus:
.LeftHeader = "&""Arial,Fett""&14Meine Überschrift"
.CenterHeader = "&""Courier,Kursiv""&12&E&XDie Mitte"
.RightHeader = "&""Becker Fraktur,Standard""&24&UDie rechte Seite"
und wenn du diesen String in die neue Mappe kopierst, hast du
auch das entsprechende Format mit übernommen.
Die Liste mit den Steuerzeichen gibts in der Hilfe.
Unterschiedliche Farben können m.W. nicht dargestellt werden
Viele Grüße
Herby
Anzeige
AW: Kopfzeilenformat
26.07.2009 10:58:22
Josef
Hallo Thomas,
eine weitere Möglichkeit wäre, die Kopfzeilen als Bild einzufügen.
Sub header()
  Dim objChrt As Chart, objChrtObj As ChartObject
  Dim objShp As Shape, objWS As Worksheet
  
  Application.ScreenUpdating = False
  Set objWS = ActiveSheet
  
  objWS.Range("C12:C17").Copy
  objWS.Pictures.Paste
  
  Set objShp = objWS.Shapes(objWS.Shapes.Count)
  
  Set objChrt = Charts.Add
  Set objChrtObj = ActiveChart.ChartObjects.Add(0, 0, objShp.Width, objShp.Height)
  objShp.Copy
  With objChrtObj
    With .Chart
      .ChartArea.Border.LineStyle = xlLineStyleNone
      .ChartTitle.Delete
      .HasLegend = False
      .ChartArea.ClearContents
      .Paste
      .Export FileName:=Environ("Temp") & "\header.gif", _
        FilterName:="GIF", Interactive:=False
    End With
    .Delete
  End With
  
  Application.DisplayAlerts = False
  objChrt.Delete
  Application.DisplayAlerts = True
  objShp.Delete
  Application.CutCopyMode = False
  
  With objWS.PageSetup
    .LeftHeaderPicture.FileName = Environ("Temp") & "\header.gif"
    .LeftHeader = "&G"
  End With
  
  Kill Environ("Temp") & "\header.gif"
  
  Application.ScreenUpdating = True
  
  Set objChrt = Nothing
  Set objChrtObj = Nothing
  Set objShp = Nothing
  Set objWS = Nothing
End Sub

Gruß Sepp

Anzeige
AW: Kopfzeilenformat
26.07.2009 19:03:46
thomas3
Hallo zusammen,
ist das Wahnsinn. Soviele Tipps.
Herzlichen Dank an alle.
Ich wede alles ausprobieren und sehen, was passt.
Einen schönen Sonntag noch
Thomas3

Beliebteste Forumthreads (12 Monate)

Anzeige

Beliebteste Forumthreads (12 Monate)

Anzeige
Anzeige
Anzeige