Microsoft Excel

Herbers Excel/VBA-Archiv

Informationen und Beispiele zum Thema ListBox
BildScreenshot zu ListBox ListBox-Seite mit Beispielarbeitsmappe aufrufen
Informationen und Beispiele zum Thema SpinButton
BildScreenshot zu SpinButton SpinButton-Seite mit Beispielarbeitsmappe aufrufen

pdf umbenennen und verschieben | Herbers Excel-Forum


Betrifft: pdf umbenennen und verschieben von: Florian
Geschrieben am: 18.01.2010 15:32:39

Hallo Gemeinde,

wieder mal eine Frage, die ich nicht so ganz lösen kann: in einem Ordner liegt eine pdf-Datei (alternativ jpg,...) mit unbekanntem Namen. Diese möchte ich gerne per Makro umbenennen und in einen anderen Ordner verschieben. Geht das? Wann ja, wie?

Danke Euch allen schon mal für die Hilfe!

Gruss

Florian

  

Betrifft: AW: pdf umbenennen und verschieben von: Josef Ehrensberger
Geschrieben am: 18.01.2010 16:21:17

Hallo Florian,

Sub moveFile()
  Dim strFileToMove As String, strNewFile As String, strFileName As String
  
  strFileName = "NeuerName.pdf"
  
  strFileToMove = _
    Application.GetOpenFilename("PDF Dateien (*.pdf),*.pdf),Alle Dateien (*.*),*.*")
  
  If strFileToMove = CStr(False) Then Exit Sub
  
  strNewFile = Application.GetSaveAsFilename(strFileName, _
    "PDF Dateien (*.pdf),*.pdf),Alle Dateien (*.*),*.*")
  
  If strNewFile = CStr(False) Then Exit Sub
  
  Name strFileToMove As strNewFile
  
End Sub



Gruß Sepp



  

Betrifft: AW: pdf umbenennen und verschieben von: Florian
Geschrieben am: 18.01.2010 17:27:11

Hi Sepp,

erstmal besten Dank. Etwas hilft das auch schon, aber noch nicht ganz, deswegen erklär ich's vielleicht noch ein bisschen detaillierter:

Habe eine Auftragsnummer und zu jeder Auftragsnummer verschiedene Dokumenttypen (z.B. Kaufvertrag, Abbestellung, ... ) als pdf. Mein Ziel ist es nun, dass der Anwender nur die Dateien in dem jeweiligen Ordner "Abbestellungen", "Kaufverträge" legt (der jeweils immer nur genau ein pdf enthält), die Auftragsnummer eingibt und alles pdfs automatisch benannt und verschoben,...). Das ganze sollte dann i Idealfall ohne Fenster geschehen...
Geht das??

Danke
Florian


  

Betrifft: AW: pdf umbenennen und verschieben von: Josef Ehrensberger
Geschrieben am: 18.01.2010 17:34:40

Hallo Florian,

ja genau!

Dann musst du aber schon mit mehr Info's rüberrücken, weil ich nicht glaube,
das du es entsprechend anpassen kannst.

1.: Wo oder wie wird die Auftragsnummer eingegeben?
2.: Wo befindet sich der "jeweilige" Ordner?
3.: Wohin sollen die pdf's verschoben werden?
4.: Wie sollen die pdf's benannt werden?
5.: Warum sagst du "die pdf's" wenn immer nur eine im Ordner liegt?


Gruß Sepp



  

Betrifft: AW: pdf umbenennen und verschieben von: Florian
Geschrieben am: 18.01.2010 21:01:10

Hi Sepp,

am einfachsten ists wohl ich antworte dirket auf Deine Fragen:

1.: Wo oder wie wird die Auftragsnummer eingegeben?
Die Auftragsnummer ist der Inhalt einer bestimmten Zelle einer xls-Datei. Es wird per Auftrag eine xls-Datei geöffnet, der Inhalt der Zelle A1(= Auftragsnummer) an eine Variable übergeben (auch diese Datei wird im Rahmen dieses Ablaufs umbenannt, nämlich nach der Auftragsnummer, unabhängig davon, wie sie vorher geheissen hat)

2.: Wo befindet sich der "jeweilige" Ordner?
Der Ordner befindet sich im Unterverzeichnis direkt unter der Steuerdatei, die die Makro enthält, also z.B. MyPath & "/vertrag", wenn das pdf der Vertrag sein soll

3.: Wohin sollen die pdf's verschoben werden?
In den Ordner ".../Dok/Auftrag-XXXXX/Vertrag/" [je Auftragnummer also eine Unterordnerstruktur mit z.B. Ordner "Vertrag", ...]

4.: Wie sollen die pdf's benannt werden?
In dem Fall "XXXXX_vertrag.pdf" (also Auftragsnummer + "_vertrag")

5.: Warum sagst du "die pdf's" wenn immer nur eine im Ordner liegt?
Vielleicht unklar ausgedrückt. Das ganze soll eine Userhilfe sein: egal, wie die xls-Datei heisst (Dateiname wird ohne System von anderen vergeben), wird sie immer nach der Auftragsnummer benannt, es wird ein Ordner in einem Verzeichnis angelegt, der wiederum nach der Auftragsnummer heisst. Dorthin sollen alle Dokumente STRUKTURIERT gespeichert werden. Mit strukturiert meine ich, dass alle Dateinamen einer Logik folgen müssen, so dass die Existenz aller pdfs via Makro überprüft werden kann (also z.B. nur wenn im Ordner ".../XXXXXX/vertrag/" ein pdf mit dem Namen "XXXXX-vertrag" ist. liegt ein Vertrag vor. Deshalb das Ganze (User soll es einfach haben + Tippfehler sollen vermieden werden)

In jedem Fall danke ich Dir schon mal für Deine Hilfe!!

Gruss, und schönen Abend!

Florian


  

Betrifft: Sorry, noch offen von: Florian
Geschrieben am: 18.01.2010 21:01:51

--


  

Betrifft: AW: Sorry, noch offen von: Florian
Geschrieben am: 18.01.2010 21:02:20

-


  

Betrifft: AW: pdf umbenennen und verschieben von: Josef Ehrensberger
Geschrieben am: 18.01.2010 21:39:41

Hallo Florian,

na dann probier mal.

' **********************************************************************
' Modul: Modul3 Typ: Allgemeines Modul
' **********************************************************************

Option Explicit

Private Declare Function MakeSureDirectoryPathExists Lib "imagehlp.dll" (ByVal _
  lpPath As String) As Long

Sub MoveAndName_pdf()
  Dim strAuftrag As String, strPathPDF As String, strNewPathPDF As String
  Dim strFilePDF As String, strNewFilePDF As String
  
  strAuftrag = Sheets("Tabelle1").Range("A1").Text 'Tabelle und Zelle mit der Auftragsnummer
  
  strPathPDF = ThisWorkbook.Path & "\Vertrag\" '! Wichtig - \ zum Abschluss!
  
  strNewPathPDF = ThisWorkbook.Path & "\Dok\Auftrag-" & strAuftrag & "\Vertrag\" '! Wichtig - \ zum Abschluss!
  
  strNewFilePDF = strAuftrag & "_Vertrag.pdf"
  strFilePDF = Dir(strPathPDF & "*.pdf", vbNormal)
  
  If strFilePDF <> "" Then
    MakeSureDirectoryPathExists strNewPathPDF
    Name strPathPDF & strFilePDF As strNewPathPDF & strNewFilePDF
  End If
  
End Sub



Gruß Sepp



  

Betrifft: Super!! Funzt, Danke!! (oT) von: Florian
Geschrieben am: 19.01.2010 16:22:44

...


Beiträge aus den Excel-Beispielen zum Thema "pdf umbenennen und verschieben"