Add-In's aufrufen...



Excel-Version: 10.0 (Office XP)
nach unten

Betrifft: Add-In's aufrufen...
von: Vitali
Geschrieben am: 26.05.2002 - 17:50:50

hi
ist bestimmt ne blöde frage:

ich habe nun mein erstes Add-In erstellt. wie binde ich es überhaupt an eine schaltfläche an? kann man das auch irgendwie automatisieren.
in der hilfe habe ich was gesehen, daß man auch setup-anweisungen machen kann.

schon mal danke :)

mfg vitali

nach oben   nach unten

Mit eigener Symbolleiste...
von: Rolf Kersjes
Geschrieben am: 26.05.2002 - 18:45:43

Hallo Vitali,

du solltest dem AddIn eine eigene Symbolleiste nach folgendem Muster verpassen:


Private Sub Workbook_Open()
    Dim objCB As CommandBar
    On Error Resume Next
    'Symbolleiste löschen
    CommandBars(Deine_Leiste).Delete
    'Symbolleiste neu anlegen
    Set objCB = CommandBars.Add(Name:=Deine_Leiste)
    With objCB
        'Symbolleiste mit Makrostart-Schaltflächen bestücken
        Call ButtonAnlegen("Auträge aus Grobplanung", 530, "TransferAuftr", False)
        Call ButtonAnlegen("Pos. sortieren", 653, "PosSortieren", True)
        Call ButtonAnlegen("Pos. entfernen", 214, "PosEntfernen", True)
        Call ButtonAnlegen("Rezepte drucken", 19, "DruckRezepte", False)
        Call ButtonAnlegen("Bedarfe ermitteln", 2572, "AufbBedarfe", False)
        Call ButtonAnlegen("Speichern", 3, "ZwischSpeich", True)
        Call ButtonAnlegen("Belegung beenden", 2151, "EndeBelegung", False)
        'Symbolleiste am oberen Rand andocken und sichtbar machen
        .Position = msoBarTop
        .Visible = True
    End With
End Sub
Private Sub Workbook_BeforeClose(Cancel As Boolean)
    On Error Resume Next
    CommandBars(Deine_Leiste).Delete
End Sub
Private Sub ButtonAnlegen(strCaption As String, intFaceID As Integer, strMakro As String, blnGruppe As Boolean)
    Dim objCTL As CommandBarControl
    'Schaltfläche anlegen
    Set objCTL = CommandBars(Deine_Leiste).Controls.Add(Type:=msoControlButton)
    With objCTL
        .BeginGroup = blnGruppe 'Gruppenbildung
        .Caption = strCaption 'Beschriftung festlegen
        .FaceId = intFaceID 'Grafisches Symbol festlegen
        .OnAction = strMakro 'Makro zuweisen
    End With
End Sub

Die Prozeduren müssen in das Klassenmodul "Diese Arbeitsmappe".


Rolf

nach oben   nach unten

Re: Mit eigener Symbolleiste...
von: Vitali
Geschrieben am: 26.05.2002 - 19:55:49

DANKE!!! funzt :)
 nach oben

Beiträge aus den Excel-Beispielen zum Thema "Automatische Ergänzung der Zeile"