2 Codes zu einem zusammenführen



Excel-Version: 9.0 (Office 2000)
nach unten

Betrifft: 2 Codes zu einem zusammenführen
von: Heinrich
Geschrieben am: 26.05.2002 - 17:23:03

Hallo,

habe folgende Codes aus dem Forum kopiert.
Einzeln funktionieren sie einwandfrei.
Bekomme es aber nicht hin, das beide gleichzeitig in einem Tabellenblatt funktionieren.

Kann mir jemand helfen ??

Gruß
Heinrich

'Cursor Bewegung

Private Sub Worksheet_Change(ByVal Target As Excel.Range)
If Target.Column <> 6 And Target.Column <> 7 Then Exit Sub
If Target.Column = 6 Then
ActiveCell.Offset(-1, 1).Select
Else
ActiveCell.Offset(0, -1).Select
End If
End Sub

'Uhrzeit ohne Doppelpunkt eingeben
'Soll nur bei einer Eingabe in Spalte F & G wirksam werden:

Private Sub Worksheet_Change(ByVal Target As Excel.Range)
Dim s%, m%
If Target.Column <> 6 And Target.Column <> 7 Then Exit Sub
With Cells(Target.Row, Target.Column)
If .Value = "" Then Exit Sub
If IsNumeric(.Value) And InStr(.Value, ":") = 0 And InStr(.Value, ",") = 0 Then
.NumberFormat = "[hh]:mm"
If Len(.Value) > 2 Then
s = Left(.Value, Len(.Value) - 2)
m = Right(.Value, 2)
Else
s = .Value
m = 0
End If
.Value = s & ":" & m
End If
End With

End Sub

nach oben   nach unten

Re: 2 Codes zu einem zusammenführen
von: Peter
Geschrieben am: 26.05.2002 - 17:33:10

Hallo Heinrich,

wie hast Du sie denn zusammen gebracht?


Private Sub Worksheet_Change(ByVal Target As Excel.Range)
Dim s%, m%
If Target.Column <> 6 And Target.Column <> 7 Then Exit Sub
If Target.Column = 6 Then
ActiveCell.Offset(-1, 1).Select
Else
ActiveCell.Offset(0, -1).Select
End If
With Cells(Target.Row, Target.Column)
If .Value = "" Then Exit Sub
If IsNumeric(.Value) And InStr(.Value, ":") = 0 And InStr(.Value, ",") = 0 Then
.NumberFormat = "[hh]:mm"
If Len(.Value) > 2 Then
s = Left(.Value, Len(.Value) - 2)
m = Right(.Value, 2)
Else
s = .Value
m = 0
End If
.Value = s & ":" & m
End If
End With
End Sub

So funktioniert es bei mir einwandfrei.

Gruß
Peter

nach oben   nach unten

Re: 2 Codes zu einem zusammenführen
von: heinrich
Geschrieben am: 26.05.2002 - 17:49:39

Hallo Peter

Estmal vielen Dank für die schnelle Anwort

Habe es so gemacht wie Du auch.
Das Problem !
Der Cursor bewegt sich bei betätigen der Eingabetaste
(Cursor steht in Spalte F) 2 Zellen nach recht und eine nach oben
Möchte aber, das er von z.B. F6 nach G6 dann F7,G7 usw.,springt.
Wenn ich den Code 'Cursor Bewegung ' einzeln im Tabellenblatt
stehen habe funktioniert es

Gruß
Heinrich


nach oben   nach unten

Re: 2 Codes zu einem zusammenführen
von: WernerB.
Geschrieben am: 26.05.2002 - 18:07:24

Hallo Heinrich,

teste mal diesen Code:


Private Sub Worksheet_Change(ByVal Target As Excel.Range)
Dim s%, m%, c%
    If Target.Column <> 6 And Target.Column <> 7 Then Exit Sub
    c = Target.Column
    With Cells(Target.Row, Target.Column)
      If .Value = "" Then Exit Sub
      If IsNumeric(.Value) And InStr(.Value, ":") = 0 And InStr(.Value, ",") = 0 Then
        .NumberFormat = "[hh]:mm"
        If Len(.Value) > 2 Then
          s = Left(.Value, Len(.Value) - 2)
          m = Right(.Value, 2)
        Else
          s = .Value
          m = 0
        End If
        Application.EnableEvents = False
        .Value = s & ":" & m
      End If
    End With
    If c = 6 Then
      ActiveCell.Offset(-1, 1).Select
    Else
      ActiveCell.Offset(0, -1).Select
    End If
    Application.EnableEvents = True
End Sub

Viel Erfolg wünscht
WernerB.
nach oben   nach unten

Re: 2 Codes zu einem zusammenführen
von: Peter,
Geschrieben am: 26.05.2002 - 18:12:05

Heinrich,

durch die Ausführung des ersten Teiles ändert sich das Blatt und der Code wird nochmal ausgeführt.

Beschreib bitte Dein Problem, sollen in F und G lediglich Werte in Uhrzeit umgewandelt werden, sind in F und G andere Eingaben möglich? Hast Du es für diese Spalten schon mal mit bedingter Formatierung versucht?

Gruß
Peter


nach oben   nach unten

2 Codes zu einem zusammenführen
von: Heinrich
Geschrieben am: 26.05.2002 - 18:22:27

Hallo Werner
Hallo Peter

Werner hat den Nagel auf den Kopf getroffen.
Genau so sollte es sein !!
Bedanke mich recht herzlich für Euere schnelle Hilfe
und wünsche noch einen schönen Sonntag

Gruß
Heinrich


 nach oben

Beiträge aus den Excel-Beispielen zum Thema "Automatische Ergänzung der Zeile"