Tabellenblätter einzeln als PDF speichern

Informationen und Beispiele zu den hier genannten Dialog-Elementen:
MsgBox
Bild

Betrifft: Tabellenblätter einzeln als PDF speichern
von: Jack Bleff
Geschrieben am: 20.05.2015 14:41:16

Hallo,
ich habe wieder mal eine Aufgabe bei der ich Eure Hilfe brauche.
Ich habe eine Tabelle mit ziemlich vielen Tabellenblättern (ca. 100 und ansteigend).
Um die Navigtion zu vereinfachen habe ich ein Blatt mit Namen "Index" erstellt,
von dem man über Buttons zu den Tabellenblättern und zurück springen kann.
Das funktioniert soweit alles.
Was mir fehlt ist jedoch die Möglichkeit alle vorhandenen Tabellenblätter (bis auf "Index"
und zwei weitere) mit einem Knopfdruck als jeweils einzelne PDF auszugeben.
Da es in Excel 2010 die Möglcihkeit gibt dies ohne einen externen Drucker zu realisieren,
würde ich es gern darüber lösen. Ich habe schon viel gegooglet, aber meist nur Lösungen
gefunden für externe PDF-Drucker (siehe: http://www.wbrnet.info/db/1152.html).
Da ich aber in der Firma keine weiteren Zusatzmittel installieren darf/will möchte ich
auf das Boardmittel zurückgreifen.
Folgende Randbedingungen sollte der Code erfüllten:
* die Auswahl des Speicherorts so wie im Code unten
* der Dateiname sollte sich aus folgenden Bestandteilen zusammensetzen: 20150520_#Los#_#Name#_#Excel-Dateiname# (die Informationen für #Los# und #Name# stehen jeweils in den Zellen D1 und D4) --> das Datum müsste sich günstigerweise immer wie beschrieben zusammensetzen, um tagesaktuell PDF's ausgeben zu können
* PDF-Druck für alle Dateien außer Index (Tabelle1) / ddddd (Tabelle5) / xxxx (Tabelle6)
Bisher habe ich mit folgendem Code herumexperimentiert:


Sub saveAsPDF()
  Dim vntFile As Variant
  
  vntFile = Application.GetSaveAsFilename(ThisWorkbook.Path & "\" & ActiveSheet.Name & ".pdf",   _
 _
_
_
    "PDF Dateien (*.pdf), *.pdf", Title:="Als PDF Speichern")
  
  If vntFile <> False Then
    ActiveSheet.ExportAsFixedFormat _
      Type:=xlTypePDF, _
      Filename:=vntFile, _
      Quality:=xlQualityStandard, _
      IncludeDocProperties:=True, _
      IgnorePrintAreas:=False, _
      OpenAfterPublish:=False
  End If
End Sub

und

Sub PDF_MultiPrint_Sheet()
    'Modifiziert
    Dim wks As Worksheet
    For Each wks In Worksheets
        With wks
            .Select
            .ExportAsFixedFormat Type:=xlTypePDF, Filename:= _
            "C:\Users\" & Environ("Username") & "\Desktop\" & .Name & ".pdf", Quality:= _
xlQualityStandard, _
            IncludeDocProperties:=True, IgnorePrintAreas:=False, OpenAfterPublish:=False
        End With
    Next wks
End Sub

Leider kriege ich die beiden Codeschnipsel nicht zusammengefügt. Ich hätte gern die Auswahl des Speicherorts so wie in dem oberen Beispiel.
Ein weiteres Probelem ist, dass ich den Namen nicht wie gewünscht ändern kann (bei der Verwendung des zweiten Codes).
Ich wäre auf Eure Hilfe angewiesen.
mfg
TraumaXB

Bild

Betrifft: AW: Tabellenblätter einzeln als PDF speichern
von: fcs
Geschrieben am: 25.05.2015 20:58:28
Hallo Jeff,
dein Makro müsste etwa wie folgt aussehen.
Gruß
Franz

Sub saveAsPDF()
    Dim vntFolder As Variant
    Dim wks As Worksheet
    Dim strFileName As String
    
    'Ordner für PDF-Datei auswählen
    With Application.FileDialog(msoFileDialogFolderPicker)
        .Title = "Bitte Ordner für zu erstellende PDF-Dateien auswählen/anlegen"
        .InitialFileName = ThisWorkbook.Path & "\"
        If .Show = -1 Then
            vntFolder = .SelectedItems(1)
        Else
            Exit Sub
        End If
    End With
    'Modifiziert
    For Each wks In Worksheets
        Select Case wks.CodeName
            Case "Tabelle1", "Tabelle5", "Tabelle6" 'ggf. anpassen
            
            Case Else
        With wks
            strFileName = vntFolder & "\" & Format(Date, "YYYYMMDD") _
                & "_" & .Range("D1").Text & "_" & .Range("D4").Text & "_" _
                & Left(ActiveWorkbook.Name, InStrRev(ActiveWorkbook.Name, ".") - 1) & ".pdf"
            
            .ExportAsFixedFormat Type:=xlTypePDF, Filename:=strFileName, _
                Quality:=xlQualityStandard, IncludeDocProperties:=True, _
                IgnorePrintAreas:=False, OpenAfterPublish:=False
        End With
        End Select
    Next wks
    MsgBox "PDF-Dateien sind erstellt"
End Sub


 Bild

Beiträge aus den Excel-Beispielen zum Thema "Tabellenblätter einzeln als PDF speichern"