Live-Forum - Die aktuellen Beiträge
Anzeige
Anzeige
HERBERS
Excel-Forum (Archiv)
20+ Jahre Excel-Kompetenz: Von Anwendern, für Anwender
Als PDF speichern
04.03.2021 10:40:20
Markus
Hallo,
ich habe eine Arbeitsmappe, die mehrere Tabellenblätter beinhaltet. jetzt möchte ich über einen CommandButton, dass gewisse Tabellenblätter ausgewählt werden und als PDF gespeichert werden.
Zu den Vorraussetzungen:
In meinem Tabellenblatt "Übersicht" stehen in der Spalte A nummern, diese sind identisch zu den Bezeichnungen der anderen Tabellenblättern. Wenn jetzt bei meinem Tabellenblatt "Übersicht" in der Spalte G etwas steht, soll in der Spalte A nach der nummer geschaut werden und das demendsprechende Tabellenblatt + meinem Tabellenblatt "Zusammenstellung" ausgewählt werden und als PDF gespeichert werden.
In meiner Bsp Datei wäre es dann Tabellenblatt 1 + 3 + Zusammenfassung.
https://www.herber.de/bbs/user/144434.xlsm
Ich hoffe es ist einigermaßen verständlich, was ich möchte.
MfG
Markus

9
Beiträge zum Forumthread
Beiträge zu diesem Forumthread

Betreff
Datum
Anwender
Anzeige
AW: Als PDF speichern
04.03.2021 10:53:25
Nepumuk
Hallo Markus,
in deiner Tabelle "Übersicht" steht in Spalte G sowohl in Zeile 8 und Zeile 10 etwas. Sollen dann 2 PDF's erstellt werden?
Gruß
Nepumuk

AW: Als PDF speichern
04.03.2021 11:32:37
Markus
Hallo Nepumuk,
nein, es soll am Ende eine PDF Datei sein.
MfG
Markus

AW: Als PDF speichern
04.03.2021 11:56:33
Nepumuk
Hallo Markus,
ich bin jetzt mal davon ausgegangen dass sich der CommandButton in der Tabelle "Übersicht" befindet.
Das PDF wird im Ordner der Mappe gespeichert, den Dateinamen musst du noch anpassen.
Option Explicit

Private Sub CommandButton1_Click()
    Dim objCell As Range
    Dim astrWorksheets() As String
    Dim ialngIndex As Long
    Redim astrWorksheets(1)
    astrWorksheets(0) = "Übersicht"
    astrWorksheets(1) = "Zusammenfassung"
    ialngIndex = 1
    For Each objCell In Range(Cells(8, 7), Cells(Rows.Count, 7).End(xlUp))
        If Not IsEmpty(objCell.Value) Then
            ialngIndex = ialngIndex + 1
            Redim Preserve astrWorksheets(ialngIndex)
            astrWorksheets(ialngIndex) = CStr(objCell.Offset(0, -6).Value)
        End If
    Next
    If ialngIndex > 1 Then
        Call Worksheets(astrWorksheets).Select
        Call ActiveSheet.ExportAsFixedFormat(Type:=xlTypePDF, Filename:=ThisWorkbook.Path & "\Test.pdf")
        Call Me.Select
    End If
End Sub

Gruß
Nepumuk

Anzeige
AW: Als PDF speichern
04.03.2021 12:51:40
Markus
Hallo Nepumuk,
leider ist noch ein Fehler drin. Die Tabelle "Übersicht soll nicht mit ausgegeben werden, sondern nach meinem Bsp. müsste Tabellenblatt 1+3+Zusammenfassung ausgegeben werden.
MfG Markus

AW: Als PDF speichern
04.03.2021 12:55:04
Nepumuk
Hallo Markus,
dann so:
Option Explicit

Private Sub CommandButton1_Click()
    Dim objCell As Range
    Dim astrWorksheets() As String
    Dim ialngIndex As Long
    Redim astrWorksheets(0)
    astrWorksheets(0) = "Zusammenfassung"
    For Each objCell In Range(Cells(8, 7), Cells(Rows.Count, 7).End(xlUp))
        If Not IsEmpty(objCell.Value) Then
            ialngIndex = ialngIndex + 1
            Redim Preserve astrWorksheets(ialngIndex)
            astrWorksheets(ialngIndex) = CStr(objCell.Offset(0, -6).Value)
        End If
    Next
    If ialngIndex > 0 Then
        Call Worksheets(astrWorksheets).Select
        Call ActiveSheet.ExportAsFixedFormat(Type:=xlTypePDF, Filename:=ThisWorkbook.Path & "\Test.pdf")
        Call Me.Select
    End If
End Sub

Gruß
Nepumuk

Anzeige
AW: Als PDF speichern
04.03.2021 13:28:26
Markus
Hallo Nepumuk,
jetzt ist es so, dass nur Zusammenfassung und Tabellenblatt 3 ausgegeben werden. Es soll ja so sein, dass sobald im Tabellenblatt "Übersicht" in der Tabelle Tb_Übersicht[Wart./Insp.] etwas steht soll das dazu gehörige Tabellenblatt mit ausgegeben werden. Darum haben die Tabellenblätter auch die selbe Bezeichnung wie die Angebotsnummer (Spalte "A"). Ich werde meine Bsp Datei mal erweitern damit es etwas vertändlicher ist.
MfG Markus

AW: Als PDF speichern
04.03.2021 13:35:46
Markus
Hallo Nepumuk,
sorry ich muss meine letzte Nachricht zurück nehmen, in der Test Prog funktioniert es nur in der Originalen nicht. Muss erstmal nachscheuen was da jetzt anders sein soll.
MfG Markus

Anzeige
AW: Als PDF speichern
04.03.2021 14:40:34
Markus
Hallo Nepumuk
leider wird in meiner Original Datei immer die Tabelle 1 ausgelassen. Vielleicht hast du ja eine Idee. Ich habe sogar gerade die Datei nochmal neu aufgesetzt.
MfG Markus

AW: Als PDF speichern
04.03.2021 15:12:11
Markus
Hallo Nepumuk,
ich habe den Fehler gefunden. In meiner original Datei fing die Tabelle "Übersicht" nicht in Zeile 7 sondern in der Zeile 5 an. Einfach zwei Zeilen eingefügt und siehe da es funktioniert.
Ich danke dir für deine Hilfe.
MfG Markus

376 Forumthreads zu ähnlichen Themen

Anzeige
Anzeige
Anzeige
Anzeige

Links zu Excel-Dialogen

Beliebteste Forumthreads (12 Monate)

Anzeige

Beliebteste Forumthreads (12 Monate)

Anzeige
Anzeige
Anzeige