Live-Forum - Die aktuellen Beiträge
Anzeige
Anzeige
HERBERS
Excel-Forum (Archiv)
20+ Jahre Excel-Kompetenz: Von Anwendern, für Anwender
Sheets auswählen dann als PDF speichern
10.02.2019 09:54:06
Holly
Hallo und guten Morgen,
ich habe folgendes Problem.
Ich möchte in einer Userform einzelne bzw. mehrere Auswählen und dies dann als PDF speichern. Ein Blatt(Sheet)welches immer das gleiche ist möchte ich die möglichkeit haben es auswälen zu können ( Info Fahrer ). Die anderen Blätter möchte ich auswählen.
Meine Idee war in einer Userform über CheckBox die bzw. das Blatt auszuwählen.
Eine beispiel Tabbelle habe ich hochgelden.
https://www.herber.de/bbs/user/127541.xlsm
Die Checkboxen sollen die gleiche Beschriftung haben wie die Tabellenblätter.
Bei der Auswahl reichen mir die drei zu letzt erstelleten Blätten. Die Blätter haben die Namen der KW ( KW 1 oder KW 2, KW 3, ...).
Ich hoffe ich konnte mein Problem verständlich machen.
schon mal vielen Dank
Holly

6
Beiträge zum Forumthread
Beiträge zu diesem Forumthread

Betreff
Datum
Anwender
Anzeige
AW: Sheets auswählen dann als PDF speichern
10.02.2019 15:07:23
Holly
Hallo Nepumuk,
erstmal schon mal vielen Dank für deine Mühe,
im Grunde läuft es, die Auswahl wächst aber auch mit der Anzahl der Blätter.
Die letzten drei Blätter würden reichen (die mit der höchsten KW) sonst wird es nach einiger Zeit wieder unübersichtlich, am Ende des Jahres sind es ja 52 Blätter. Wenn er die ausgeblendeten Blätter über springt würde es auch scho gehen.
Schönen Sonntag noch
Holly
AW: Sheets auswählen dann als PDF speichern
10.02.2019 15:13:14
Nepumuk
Hallo Holly,
soll die Tabelle "Info Fahrer" trotzdem sie ausgeblendet ist angezeigt werden?
Gruß
Nepumuk
Anzeige
AW: Sheets auswählen dann als PDF speichern
10.02.2019 16:02:20
Holly
Muss nicht sein, es reicht das sie angezeigt wir wenn sie eingeblendet ist. und wenn sie ausgeblendet ist brauche ich sie auch nicht auswählen.
AW: Sheets auswählen dann als PDF speichern
10.02.2019 16:15:00
Nepumuk
Hallo Holly,
teste mal:
Option Explicit

Private Sub CommandButton1_Click()
    Dim aobjWorksheets() As Worksheet, objActiveSheet As Worksheet
    Dim lngIndex As Long, ialngWorksheetIndex As Long
    Dim blnSelectWorksheet As Boolean
    With ListBox1
        For lngIndex = 0 To .ListCount - 1
            If .Selected(lngIndex) Then
                Redim Preserve aobjWorksheets(ialngWorksheetIndex)
                Set aobjWorksheets(ialngWorksheetIndex) = ThisWorkbook.Worksheets(.List(lngIndex))
                ialngWorksheetIndex = ialngWorksheetIndex + 1
                blnSelectWorksheet = True
            End If
        Next
    End With
    If Not blnSelectWorksheet Then
        Call MsgBox("Bitte wählen Sie eine Tabelle zum drucken aus.", vbExclamation, "Hinweis")
    Else
        Application.ScreenUpdating = False
        Set objActiveSheet = ActiveSheet
        For ialngWorksheetIndex = 0 To UBound(aobjWorksheets)
            Call aobjWorksheets(ialngWorksheetIndex).Select(Replace:=ialngWorksheetIndex = 0)
        Next
        Call ActiveSheet.ExportAsFixedFormat(Type:=xlTypePDF, _
            Filename:=ThisWorkbook.Path & "\Ausdruck.pdf", _
            Quality:=xlQualityStandard, IncludeDocProperties:=False, _
            IgnorePrintAreas:=False, OpenAfterPublish:=True)
        Erase aobjWorksheets
        objActiveSheet.Select
        Set objActiveSheet = Nothing
        Application.ScreenUpdating = True
    End If
End Sub

Private Sub CommandButton2_Click()
    Call Unload(Object:=Me)
End Sub

Private Sub UserForm_Activate()
    Dim objWorksheet As Worksheet
    With ThisWorkbook
        For Each objWorksheet In ThisWorkbook.Worksheets
            Select Case objWorksheet.Name
                Case "Stammdaten", "Vorlage"
                    'do nothing
                Case Else
                    If objWorksheet.Visible = xlSheetVisible Then _
                        Call ListBox1.AddItem(objWorksheet.Name)
            End Select
        Next
    End With
End Sub

Gruß
Nepumuk
Anzeige
AW: Sheets auswählen dann als PDF speichern
10.02.2019 16:19:53
Holly
Super,
so ist es sehr gut.
vielen vielen Dank
wünsche dir noch einen schönen rest Sontag
Holly

390 Forumthreads zu ähnlichen Themen

Anzeige
Anzeige
Anzeige
Anzeige

Links zu Excel-Dialogen

Beliebteste Forumthreads (12 Monate)

Anzeige

Beliebteste Forumthreads (12 Monate)

Anzeige
Anzeige
Anzeige