Herbers Excel/VBA-Archiv

Informationen und Beispiele zum Thema CommandButton
Screenshot zu CommandButton	CommandButton-Seite mit Beispielarbeitsmappe aufrufen

VBA ausgewählte Tabelle als Pdf via Checkbox

• VBA ausgewählte Tabelle als Pdf via Checkbox von Sino vom 14.11.2014 07:11:36
• AW: VBA ausgewählte Tabelle als Pdf via Checkbox - von fcs am 14.11.2014 12:59:37
  • AW: VBA ausgewählte Tabelle als Pdf via Checkbox - von Sino am 14.11.2014 13:05:32

Betrifft: VBA ausgewählte Tabelle als Pdf via Checkbox von: Sino
Geschrieben am: 14.11.2014 07:11:36

Hallo Leute,

hoffe ihr könnt mir helfen. Ich würde gerne per Checkbox Tabellen einblenden und die auch per Buttom als PDF speichern. Die Seite mit den Checkboxen soll natürlich nicht gespeichert werden. Feste Tabellen wie Deckblatt und Bemerkung sollen immer gespeichert werden.

VG Sino

Datei: https://www.herber.de/bbs/user/93763.xlsm

Betrifft: AW: VBA ausgewählte Tabelle als Pdf via Checkbox von: fcs
Geschrieben am: 14.11.2014 12:59:37

Hallo Sino,

Makro für Schlatfläche:

Private Sub CommandButton1_Click()

'Eingeblendete Tabellen als PDF speichern. Deckblatt und Bemerkung immer speichern.
  Dim arrSheets(), intSheet, objSheet As Object, varName
  
  For Each objSheet In ActiveWorkbook.Sheets
    Select Case objSheet.Name
      Case "Daten"
        'diese Blätter nicht drucken/speichern
      Case Else
        If objSheet.Visible = xlSheetVisible Then
          intSheet = intSheet + 1
          ReDim Preserve arrSheets(1 To intSheet)
          arrSheets(intSheet) = objSheet.Name
        End If
    End Select
  Next
  
  If intSheet > 0 Then
    ActiveWorkbook.Sheets(arrSheets()).Select
  ' SaveAsPDF Makro
  '
    varName = Application.GetSaveAsFilename(FileFilter:="PDF (*.PDF),*.pdf", _
        Title:="Bitte Name für PDF-Datei eingeben/auswählen")
  '
    If varName <> False Then
      ActiveSheet.ExportAsFixedFormat Type:=xlTypePDF, Filename:=varName, _
          Quality:=xlQualityStandard, IncludeDocProperties:=True, _
          IgnorePrintAreas:=False, OpenAfterPublish:=True
    End If
    Sheets("Daten").Select
  End If

End Sub

Gruß
Franz

Betrifft: AW: VBA ausgewählte Tabelle als Pdf via Checkbox von: Sino
Geschrieben am: 14.11.2014 13:05:32

Suuupper, vielen vielen Dank

Beiträge aus den Excel-Beispielen zum Thema "VBA ausgewählte Tabelle als Pdf via Checkbox"