Schleife für Controls über Zugriff auf Tabelle

Hallo zusammen,
ich brauche Hilfe dabei, eine Schleife zu bauen.
Ich habe dazu eine ganz gute Beispielmappe gemacht.
https://www.herber.de/bbs/user/79180.xls
Hier die Erläuterung zu dem was ich nicht hinbekomme.
In der Beispielmappe
--------------------------------------------------------------------------------------------------------------------
- Eine Userfom enthält eine Multipage und ein Button.
- Eine Seite der Multipage besitzt noch mal eine Multipage.
- 10 Checkboxen sind verteilt auf der Userform, jeweils 2 Checkboxen je Multipage-Seite.
- die Checkboxen sollen unterschiedliche Eigenschaften bekommen, je nach Inhalt der jeweiligen Zelle.
- Die Eigenschaften werden in einer Tabelle über eine Zahl gesteuert.
- Beim Klick auf den Button sollen den Checkboxen die Eigenschaften zugewiesen werden.
--------------------------------------------------------------------------------------------------------------------
Bei der hohen Zahl an Checkboxen (ca. 700) in meiner eigentlichen Datei ist das Schreiben des Codes in folgender Form viel zu viel für mich und sicher nicht die eleganteste Lösung:

Sub EigenschaftenDerCheckBoxen
Dim WS As Worksheet
Set WS = Worksheets("SheetXY")
If WS.Range("G3") = "0" Then
Userform.Checkbox1.Value = False
Userform.Checkbox1.Visible = False
Else
End If
End Sub

Wie kann man das in einer Schleife oder Ähnlichem realisieren?
Sowas wie einen Gruppennamen kann ich den CheckBoxen zuweisen wenn das nützlich sein sollte.
Und noch eine Frage: wie deklariert man Controls oder Userformen (ähnlich Dim WS as Worksheet)?
Dank und Gruß
Erdogan.
PS: Feedback ist selbstverständlich!

Hallo Erdogan,
hier ein Code-Vorschlag für die Zuweisung der Eigenschaften der Checkboxen.
Bei ggf. 700 Checkboxen in der Userform solltest du die Namen der Checkboxen ggf. etwas strukturieren, z.B. pro Page zählen - also P01_chkbox1, P01_chkbox2, P011_chkbox1, P012_chkbox2, P02_chkbox1, P02_chkbox2 usw.
Das ist zwar etwas mühseliger bei der Erstellung des Userforms (Umbenennen der Sterelemente), aber du verlierst sonst komplett den Überblick.
Ein Beispiel für die Deklaration von Controls findest du im Code. Man muss aber sehr genau darauf achten, das beim Zuweisen der Objekte die Typen passen. Oft ist es einfacher, eine Variable als Control zu deklarieren. Damit können allgemeine Control-Eigenschaften zugewiesen/abgefragt werden. Spezifische Eigenschaften, die nicht jedes Control hat, müssen dann über das zugehörige Objekt zugewiesen/abgefragt werden werden.
Beispiel:

Private Sub UserForm_Click()
Dim objControl As Control, objFormat As ControlFormat
For Each objControl In Me.Controls
With objControl
.Visible = True
With .Object
Select Case LCase(TypeName(objControl))
Case "checkbox"
.Enabled = True
.Value = False
.Locked = False
End Select
End With
End With
Next objControl
End Sub

Objektvariablen als MSForms.Userform zu deklarieren bringt meist nicht so viel.
Innerhalb eines Userform-Code-Moduls kann man die Sytemvariable Me verwenden, um auf das Userform zu verweisen.
In anderen Codemodulen ist es am einfachsten, direkt den Userformnamen zu verwenden.
Gruß
Franz

'Erstellt unter Excel 2007
Private Sub CommandButton1_Click()
'Hier sollte das Makro starten
Call EigenSchaftenEinlesen
End Sub
Private Sub EigenSchaftenEinlesen()
Dim wks As Worksheet, Zelle As Range
Dim objCheckbox As MSForms.CheckBox
On Error GoTo Fehler
Set wks = Worksheets("Tabelle1")
With wks
For Each Zelle In .Range(.Cells(3, 2), .Cells(.Rows.Count, 2).End(xlUp))
Set objCheckbox = Me.Controls(Zelle.Text)
With objCheckbox
Select Case Zelle.Offset(0, 1).Value
Case 0
.Visible = True
.Locked = True
.Value = True
Case 1
.Visible = True
.Locked = True
.Value = False
Case 2
.Visible = False
.Locked = False
.Value = False
End Select
End With
Resume01:
Next
End With
Fehler:
'Fehlerbehandlung
With Err
Select Case .Number
Case 0 'kein Fehler
Case -2147024809
MsgBox "Fehler-Nr.: " & .Number & vbLf & .Description & vbLf & vbLf _
& "Steuerelement mit Name """ & Zelle.Text & """ existiert nicht!", _
vbInformation + vbOKOnly, "Eigenschaften einlesen"
Case Else
MsgBox "Fehler-Nr.: " & .Number & vbLf & .Description
End Select
End With
End Sub

Schleife für Controls über Zugriff auf Tabelle

Forumthread: Schleife für Controls über Zugriff auf Tabelle

12
Beiträge zum Forumthread

Beiträge zu diesem Forumthread

Infobox / Tutorial