Live-Forum - Die aktuellen Beiträge
Datum
Titel
28.03.2024 21:12:36
28.03.2024 18:31:49
Anzeige
Archiv - Navigation
1304to1308
Aktuelles Verzeichnis
Verzeichnis Index
Übersicht Verzeichnisse
Vorheriger Thread
Rückwärts Blättern
Nächster Thread
Vorwärts blättern
Anzeige
HERBERS
Excel-Forum (Archiv)
20+ Jahre Excel-Kompetenz: Von Anwendern, für Anwender
Inhaltsverzeichnis

Zusammengestückelte Formel

Zusammengestückelte Formel
03.04.2013 11:43:23
Kraichtaler
Hallo liebe Excelpertinnen und Excelperten,
ich glaube ich war mit einer ähnlichen Frage schon mal hier, habe aber bis jetzt noch nicht DIE Lösung für mein Problem und wollte es daher nochmal vereinfacht nachfragen. Vielleicht hat ja jemand eine Idee.
Ich habe eine Zelle in der steht folgende Formel : =VERGLEICH((0,4);A3:A4000;1).
Darin wird mir im Zellbereich A3 bis A4000 die Zeilennummer ermittelt in der ein Zellwert kleiner oder gleich dem Wert 0,4 ist. Soweit so gut. Leider funktioniert diese Formel manchmal aus unerfindlichen Gründen nicht und liefert mir einen falschen Wert. Sie liefert mir dann nämlich immer die Zeilennummer mit dem letzten Wert in der Spalte. Wenn also im Bereich A3 bis A4000 bis zur Zeile 2706 Werte drin stehen, dann liefert mir die Formel den Wert 2706, was definitiv falsch ist.
Wie gesagt....warum das manchmal nicht funktioniert ist mir unerklärlich, aber ich habe es fast akzeptiert......weil nämlich ich herausgefunden habe, wie ich die Formel dann richtig zu arbeiten bekomme.
Ersetze ich nämlich in obiger Formel den Wert 4000 durch, in diesem Fall "2706", ändere die Formel also so : =VERGLEICH((0,4);A3:A2706;1), dann liefert sie mir das richtige Ergebnis. Schon seltsam, aber es ist so.
Meine Frage ist daher, ob es eine Möglichkeit gibt, sich diese Formel aus Zellen zusammenzubasteln. Ich könnte nämlich in einer Hilfszelle einfach die Zeilennummer mit dem letzten Eintrag heraussuchen und diesen dann in die Formel einbasteln. Nur funktioniert das mit meinem Wissen irgendwie nicht. Angenommen meine Hilfszelle ist die Zelle A30, dann stelle ich mir das ungefähr so vor: =VERGLEICH((0,4);A3:Inhalt von Zelle A30;1). Ich müsste das Ergebnis in Zelle A30 natürlich noch so formatieren, dass da nicht 2706 sondern "A2706" drin steht, aber es funktioniert trotzdem nicht.....bzw. ich weiß nicht wie.
Wär super wenn ihr mir helfen könntet.
lg
Jürgen

26
Beiträge zum Forumthread
Beiträge zu diesem Forumthread

Betreff
Datum
Anwender
Anzeige
Holzweg AW: Zusammengestückelte Formel
03.04.2013 12:02:22
Klaus
Hallo Jürgen,
erstens glaube ich, du benutzt "Verleich" falsch. Die Formel funktioniert definitiv nicht "manchmal, mysteriöserweise" nicht - sondern immer so wie der Anwender sie nutzt!
Suchts du nach "genau" 0,4 oder nach "nahe bei" 0,4?
wenn es genau 0,4 ist, dann so:
=VERGLEICH((0,4);A3:A4000;0)
Ersetze ich nämlich in obiger Formel den Wert 4000 durch, in diesem Fall "2706", ändere die Formel also so : =VERGLEICH((0,4);A3:A2706;1), dann liefert sie mir das richtige Ergebnis. Schon seltsam, aber es ist so.
Deine Liste ist nicht sortiert. Dass ist aber mit einem Bereich_Verweis=1 zwingend notwendig (steht auch so in der Hilfe!). Wenn du die Liste nicht sortieren kannst oder willst, ist Bereich_Verweis=1 im Verleich nicht zulässig und das finden des Näherungswertes (so) nicht möglich.
Glaub mir, das hat nichts, aber auch gar nichts mit Zeile 2706 zu tuen. Da bist du auf dem Holzweg.
Grüße,
Klaus M.vdT.

Anzeige
Holzweg AW: Zusammengestückelte Formel
03.04.2013 12:22:02
Kraichtaler
Hallo Klaus,
Du hast Recht....die Liste ist nicht sortiert....d.h. es kann sein dass die Werte ganz minimal nach oben und nach unten schwanken. Es handelt sich dabei um ein elektrisches Messsignal eines Verstärkers, das so im Bereich von 0 bis ca 2mV hochgeht und danach wieder auf 0 abfällt. Ich suche jetzt den Wert, bzw. die Zeile, in der der Wert 0,4 das erste Mal überschritten wird.
Leider kann ich die Liste auch nicht sortieren, weil das ja die Messung verfälschen würde. Komischerweise ist es aber tatsächlich so, dass die Formel korrekt arbeitet, wenn ich den Bereich auf die tatsächlich vorhandene Datenmenge reduziere. Warum auch immer....es ist fakt und hunderte mal schon durchgeführt.....es funktioniert.....aber eben nicht immer.
Man muss nämlich dazusagen, dass die Zeilenzahl von Messung zu Messung variiert....und immer so um die 2000-3000 Werte vorhanden sind. Um im "grünen" Bereich zu sein, hab ich den Bereich bis 4000 aufgedehnt.
Siehst Du eine andere Möglichkeit die Zeile zu finden, in der der Wert einer Spalte das erste Mal einen bestimmten Wert überschreitet ?
VG
Jürgen

Anzeige
Holzweg AW: Zusammengestückelte Formel
03.04.2013 12:32:22
Klaus
Komischerweise ist es aber tatsächlich so, dass die Formel korrekt arbeitet, wenn ich den Bereich auf die tatsächlich vorhandene Datenmenge reduziere
NEIN!
Ich bestreite nicht, dass deine Formel zufällig ein korrektes Ergebniss liefert. Aber ich bestreite, dass sie korrekt arbeitet!
Siehst Du eine andere Möglichkeit die Zeile zu finden, in der der Wert einer Spalte das erste Mal einen bestimmten Wert überschreitet ?
Klar, mit einer Hilfsspaltenlösung. Allerdings, wenn du nicht sortieren darfst / willst dann werden dir auch Hilfsspalten nicht schmecken.
Vielleicht kann jemand eine Zeilenlange Matrixformel schreiben, die das macht (ich kanns nicht!)
Ich kann dir aber anbieten, dafür eben ein VBA-Script zu erstellen.
Ich kann dir auch anbieten, dir ein Script oder eine INDIREKT-Konstruktion für dein "vergleich-unsortiert-bis-ende-Bereich" zu basteln, aber davon halte ich nix weil es (wie gesagt) wenn überhaupt dann nur zufällig funktioniert.
So oder so wirds mal Zeit für eine Musterdatei, oder?
Grüße,
Klaus M.vdT.

Anzeige
Holzweg AW: Zusammengestückelte Formel
03.04.2013 13:04:02
Kraichtaler
Hallo Klaus,
ich habe von einem Kollegen hier eine Lösung angeboten bekommen, die auf den ersten Blick zu funktionieren scheint. Ich will die jetzt die nächsten Tage mal ausgiebig testen. Sollte sie irgendwann doch wieder falsche Werte liefern melde ich mich nochmal. Dann lade ich auf jeden Fall auch mal ne Musterdatei hoch. Danke aber in jedem Fall für Dein Angebot und dass Du Dich mit dem Thema so intensiv beschäftigt hast.
vG.
Jürgen

Holzweg AW: Zusammengestückelte Formel
03.04.2013 13:09:03
Klaus
Hi,
danke für die Rückmeldung, ignorier meinen Beitrag unten da haben wir uns überschnitten.
Ich gebe dir zu bedenken, dass Rudi "nur" folgendes getan hat:
- Deine Formel nehmen
- die Standard-Lösung für "Matrix-Bis-Letzte-Zeile" nehmen
- beides zusammenfügen
Damit hat er deine Aufgabe bereits gut gelöst und ihm ist da nichts anzukreiden!
Allerdings bleibt es bei dem Fakt: du benutzt einen Bereich_Verweis=1 auf eine unsortierte Liste und das KANN nicht dauerhauft zu richtigen Ergebnissen führen! Ich übertreib mal: wenn du =ZUFALLSZAHL() in die Zelle eingibst, gibt es auch eine (wenn auch sehr geringe) Warscheinlichkeit, dass du das korrekte und gesuchte Ergebniss erhälst. Dein Vergleich-Unsortiert ist im Prinzip nichts anderes, nur die Chancen sind leicht höher.
Du lädst deine Musterdatei hoch, und ich beweise dir dass deine (Rudis) Formel fehlerhaft ist. Top die Wette gilt?
Grüße,
Klaus M.vdT.

Anzeige
Holzweg AW: Zusammengestückelte Formel
03.04.2013 13:19:20
Kraichtaler
Hallo Klaus,
da Du gegenüber mir der wesentlich gewieftere Excelspezialist bist, scheine ich die Wette bereits verloren zu haben :-))
Ich glaub ich komm dann doch mal gleich auf Dein Angebot zurück.....
Die gesuchte Formel steht im Beispiel in Zelle F1
VG
Jürgen
Hm....wie funktioniert das mit dem File-Upload ? Habe die Datei hochgeladen und gesagt bekommen ich solle diesen Link einfügen :

Die Datei https://www.herber.de/bbs/user/84688.xlsx wurde aus Datenschutzgründen gelöscht

. Keine Ahnung ob die Datei so für Dich erreichbar ist....

Anzeige
Holzweg AW: Zusammengestückelte Formel
03.04.2013 13:39:31
Rudi
Hallo,
ganz einfach:
DEF
1 Zeilen-Nr. ab der Kraft > 0,4kN :379

ZelleFormel
F1{=MIN(WENN(A3:A5000>0,4;ZEILE(3:5000);""))}
Achtung, Matrixformel!
Die geschweiften Klammern{} nicht eingeben,
sondern die Zelle mit
Shift + Strg + Enter
verlassen statt Enter alleine.

Gruß
Rudi

Anzeige
Holzweg AW: Zusammengestückelte Formel
03.04.2013 13:47:28
Kraichtaler
Hallo Rudi,
das sieht mir ja jetzt fast zu einfach aus um wahr zu sein.... :-)) Aber das Ergebnis stimmt.... Und das funktioniert jetzt immer ?
Ich versteh ja leider nicht so wirklich wie die Formel arbeitet, aber könnte man auf ähnliche Art und Weise auch den Wert finden wo der Wert das erste Mal wieder unterschritten wird....als auf dem abfallenden Zweig ? Die Werte steigen ja an bis zu einem Maximum bis sie wieder auf annähernd Null zurückgehen. Ich suche letztlich noch weitere Zwischenwerte, wie Du in meinem Muster ja vielleicht gesehen hast. Das über die Zeilennummern auszurechnen funktioniert zwar, aber nur auf dem aufsteigenden Zweig. Wenn ich den ähnlichen Kraft-Wert auf dem Weg zurück haben will, dann funktioniert meine Formel nicht mehr. Im Beispiel das ich hochgeladen hab, ist da nämlich ein Fehler drin. Die Zelle die Excel hier heranzieht stammt nämlich aus dem aufsteigenden Ast. Um die Hysterese zu berechnen brauche ich aber den Wert des absteigenden Astes.
vg
Jürgen

Anzeige
Holzweg AW: Zusammengestückelte Formel
03.04.2013 14:01:40
Klaus
Hi,
Rudi: tolle Lösung! Ich lade meine 2-Hilfsspalten-Lösung dann mal nicht hoch sondern schäme mich einfach ein bisschen.
Jürgen: vielleicht wird da ganz anders ein Schuh draus. Vergiss mal alles was bisher im Thread steht und deine bisherigen Formeln. Was suchst du in der Musterdatei, und weshalb? Ich schrieb ja schon oben, die Bezeichung "ab Zeile xxx über 0,4" ist faktisch auch nicht richtig ...
was sind aufsteigende / absteigende Äste in deinem Beispiel?
Rudis Formel funktioniert so:
wenn der Wert in A2 kleiner als 0,4 ist, dann "2" (die Zeilennummer), sonst "nix"
wenn der Wert in A3 kleiner als 0,4 ist, dann "3" (die Zeilennummer), sonst "nix"
[...]
wenn der Wert in A379 kleiner als 0,4 ist, dann "379" (die Zeilennummer), sonst "nix"
wenn der Wert in A380 kleiner als 0,4 ist, dann "380" (die Zeilennummer), sonst "nix"
[...]
Ergebiss (vorläufig:
nix, nix, [...], 379, 380, 381 [...]
das MIN von (nix, nix, 379, 380, 381) ist 379, und das ist die gesuchte Zeilennummer.
Grüße,
Klaus M.vdT.

Anzeige
Holzweg AW: Zusammengestückelte Formel
03.04.2013 14:14:19
Kraichtaler
Hallo Klaus,
wenn Du Dir meine Messreihe anschaust, dann siehst Du dass die Werte von fast 0 ansteigen bis etwas 12,56...... . Dies ist der aufsteigende Ast.
Danach fallen die Werte wieder ab bis wieder fast auf 0. Dies ist der absteigende Ast.
Was genau suche ich ?
a) Ich suche die Zeilennummer, in der der Wert in Spalte A im aufsteigenden Ast erstmalig größer als 0,4 ist. (Das hat den Grund, dass alle kleineren Werte nicht verwendet werden dürfen)
b) Außerdem such ich auch die Zeilennummer, in der der Wert noch größer 0,4 aber noch nicht kleiner als 0,4 ist. Hier jedoch auf dem absteigenden Ast.
c) Bonus wäre, aber das ergibt sich dann vielleicht wenn es für b) eine Lösung gibt, wenn ich für definierte Kraftwerte die Zeilennummer auf dem absteigenden Ast bekommen könnte. So hab ich z.B. die Kraftwerte 0,418593 und 1,840775 vom aufsteidenden Ast ermittelt. Um jetzt eine Hysterese ermitteln zu können, benötige ich die ungefähr gleichen Positionen vom absteigenden Ast.
Ich hoffe ich konnte mein Problem jetzt deutlicher machen.
viele Grüße
Jürgen

Anzeige
Klarstellung:
03.04.2013 14:16:31
Klaus
Hi Jürgen,
Rudi schüttelt das bestimmt aus dem Ärmel :-) Ich brauche dazu noch eine Klarstellung:
Wenn die Liste nicht sortiert ist, wie kann es dann einen definierten "aufsteigenden" und "absteigenden" Ast geben? Wie verhinderst du, dass ein ausreisserwert das ganze zunichte macht?
Grüße,
Klaus M.vdT.

AW: Klarstellung:
03.04.2013 14:39:35
Kraichtaler
Hallo Klaus,
die Liste ist nicht sortiert und kann auch nicht sortiert werden. Die ganze Spalte beinhaltet Messwerte mit einem Digitalvoltmeter. Wie bei jedem elektrischen Signal gibt es da ein gewisses Rauschen, weshalb es theoretisch (und praktisch) vorkommen kann, dass im aufsteigenden Ast z.B. Messwerte wie 4,123456 und danach 4,123356 und dann 4,123956 sind. Die Schwankungen sind im hinteren Nachkommastellenbereich und für mich erstmal nicht besonders relevant. Ob dann also der gefundene Wert letztlich ein zu früher oder ein zu später Wert ist, ist nicht so wichtig. Hauptsache er liegt so um 0,4.
viele Grüße
Jürgen

schüttel, schüttel
03.04.2013 15:08:34
Rudi
Hallo,
ist doch logisch.
Man sucht einfach hinter dem erstmalig über 0,4 liegenden Wert nach dem erstmalig unter 0,4 liegenden Wert.
{=MIN(WENN(INDEX(A:A;F1):A5000<0,4;ZEILE(INDEX(A:A;F1):A5000);""))}
Gruß
Rudi

Holzweg AW: Zusammengestückelte Formel
03.04.2013 14:50:35
Klaus
Hi,
Der Suchwert (0,4) steht zum Beispiel in Zelle P2
a) Rudis Formel:
{=MIN(IF(A3:A5000>P2;ROW(A3:A5000);""))}
{=min(wenn(A3:A5000>P2;zeile(A3:A500);""))}
b) folgende Formel:
{=MAX(IF(IF(ISNUMBER(A3:A5000);A3:A5000;0)>P2;ROW(A3:A5000);""))}
{=max(wenn(wenn(istzahl(A3:A5000);A3:A5000;0)>P2;Zeile(A3:A5000;""))}

jeweils alst Matrixformel, keine Garantie für die deutsche Übersetzung!
c) geht nicht. Der absteigende Ast beginnt bei Zeile 998, nach Zeile 998 gibt es keine Kraft gleich 0,418593 oder 1,840775 mehr .. wie denn auch, auf dem absteigend Ast ist ja nach definition alles KLEINER als 0,4!
Ich würd ja denken, Zeile 773 markiert den Beginn des absteigenden Astes (ab da wird es überwiegend kleiner). Aber deine Aufgabenstellung impliziert eindeutig, dass erst mit Zeile 998 der absteigende Ast beginnt - und ab da kannst du dann keine Werte größer 0,4 mehr finden!
Grüße,
Klaus M.vdT.

Holzweg AW: Zusammengestückelte Formel
03.04.2013 13:51:04
Klaus
Hi Jürgen,
alles richtig mit dem Dateiupload.
die Formel funktioniert bei dir so gut, weil deine Werte größtenteils und vor allem im relevanten Bereich sortiert sind! Die unsortiertheit schlägt sich nur in den ersten paar hundert und in den letzen paar hundert Zellen wieder.
Die Formulierung "Ab dieser Zeile" ist etwas irreführend. Ab Zeile 378 treten die Werte Gr als 0,4 auf, aber zB in Zeile 999 ist der Wert bereits wieder unter Null.
Rückschluss: NACH dem ersten 0,4er Wert dürfen Werte unter 0,4 auftreten. Es soll trotzdem der erste Wert gefunden werden.
Jetzt kommts: Trag mal in Zelle A370 manuell den Wert 0,4 ein. Jetzt müsste deine Formel eigentlich die 370 finden, oder? Passiert aber nicht.
Ich lad dir die Datei mal wieder hoch, als xlsm. F1 ist mit absicht leer, ein druck auf den Knopf findet die richtige Zeilennummer auch in einer unsortierten Liste!
https://www.herber.de/bbs/user/84690.xlsm
Ich mach gleich noch eine alternative per Formel und ohne Makro, die hat dann aber Hilfsspalten!
Grüße,
Klaus M.vdT.

Holzweg AW: Zusammengestückelte Formel
03.04.2013 14:44:47
Kraichtaler
Hallo Klaus,
ja, das ganze als Formel mit Hilfsspalten wär super.....dann versteh ich´s vielleicht sogar ;-))
und ich kann mir den Rest den ich noch brauche selbst "zusammenbauen"
Viele Grüße
Jürgen

AW: Hilfsspaltenlösung
03.04.2013 15:22:00
Kraichtaler
Hallo Klaus,
tut.....auch wenn ich da erst mal ne gewisse Zeit brauche um es zu verstehen. Ich sag trotzdem, achwas, ich sag gerade deswegen vielen, vielen Dank.
Wie gesagt, ich versuch mir das die nächsten Tage, vielleicht auch erst mal am Wochenende einzuverleiben und vielleicht kann ich mir dann daraus den Rest "basteln".....gemeint sind die anderen Kraftstufen die ich sowohl auf dem aufsteigenden und dem absteigenden Ast noch suche. Vermutlich brauch ich für jede Kraftstufe so eine Hilfsspalte, wenn ich das richtig sehe.
Ist das Ganze eigentlich so flexibel, dass es egal ist, wieviele Werte in Spalte A stehen ?
viele Grüße
Jürgen

Danke für die Rückmeldung!
03.04.2013 15:37:58
Klaus
Ist das Ganze eigentlich so flexibel, dass es egal ist, wieviele Werte in Spalte A stehen ?
ja!
Vermutlich brauch ich für jede Kraftstufe so eine Hilfsspalte, wenn ich das richtig sehe.
Oder du fragst Rudi ganz nett, ob er dafür noch ein paar Matrixformeln von seinem Wissensbaum schüttelt :-) Ich versteh aber gut, wenn du lieber die unelegante, aber nachvollziehbarere Lösung mit Hilfsspalten nimmst. Andererseits könnte man dies als Ansatz nehmen, tiefer in die geheimnisvolle Matrix-Materie einzusteigen ... ich find als ersten Input die Tutorials von Peter Haserodt sehr hilfreich: http://www.online-excel.de/excel/singsel.php?f=26
Ich denke, man kommt auch mit wenigen Hilfsspalten aus wenn man sich entsprechend Gedanken über die Struktur macht. Meine Lösung ist ja auch eher hingepfuscht. Bastel halt ein bisschen rum und meld dich dann hier oder in einem neuen Thread wieder, wir helfen immer gerne!
Grüße,
Klaus M.vdT.

ohne HS
03.04.2013 15:44:32
Rudi
Hallo,
so?
DEFGHIJK
1 Zeilen-Nr. ab der Kraft > 0,4kN :379Zeile bis zu der Kraft >=0,4 kN:998 aufsteigendabsteigend
2 Max.-Wert der Kraft Fx :12,56022765kN Zeile für Kraftstufe 1 :379769
3 Zeilennummer bei max. Kraft :769  Zeile für Kraftstufe 2 :422794
4 Wert der Achse FOX bei max.Kraft :2,1182121 Zeile für Kraftstufe 3 :466820
5     Zeile für Kraftstufe 4 :509845
6 Steigung :0,169566  Zeile für Kraftstufe 5 :552871
7 Achsabschnitt :-0,015763  Zeile für Kraftstufe 6 :596896
8 FS :2,117884  Zeile für Kraftstufe 7 :639922
9 NL FS0,909 %  Zeile für Kraftstufe 8 :682947
10 Hys FS0,028 %  Zeile für Kraftstufe 9 :726973
11     Zeile für Kraftstufe 10 :769998

ZelleFormel
F1{=MIN(WENN(A3:A5000>0,4;ZEILE(3:5000);""))}
H1{=MIN(WENN(INDEX(A:A;F1):A5000<0,4;ZEILE(INDEX(A:A;F1):A5000)-1;""))}
F2=WENN(ABS(MAX(A3:A5000))>ABS(MIN(A3:A5000));MAX(A3:A5000);MIN(A3:A5000))
F3=VERGLEICH((F2);A1:A5000;0)
F4=INDEX(B:B;VERGLEICH(MAX(A:A);A:A;0))
G4=WENN(F4<0;-1;1)
J2=RUNDEN($F$1+($F$3-$F$1)/9*(ZEILE()-2);)
K2=RUNDEN($F$3+($H$1-$F$3)/9*(ZEILE()-2);)
J3=RUNDEN($F$1+($F$3-$F$1)/9*(ZEILE()-2);)
K3=RUNDEN($F$3+($H$1-$F$3)/9*(ZEILE()-2);)
J4=RUNDEN($F$1+($F$3-$F$1)/9*(ZEILE()-2);)
K4=RUNDEN($F$3+($H$1-$F$3)/9*(ZEILE()-2);)
J5=RUNDEN($F$1+($F$3-$F$1)/9*(ZEILE()-2);)
K5=RUNDEN($F$3+($H$1-$F$3)/9*(ZEILE()-2);)
J6=RUNDEN($F$1+($F$3-$F$1)/9*(ZEILE()-2);)
K6=RUNDEN($F$3+($H$1-$F$3)/9*(ZEILE()-2);)
J7=RUNDEN($F$1+($F$3-$F$1)/9*(ZEILE()-2);)
K7=RUNDEN($F$3+($H$1-$F$3)/9*(ZEILE()-2);)
J8=RUNDEN($F$1+($F$3-$F$1)/9*(ZEILE()-2);)
K8=RUNDEN($F$3+($H$1-$F$3)/9*(ZEILE()-2);)
J9=RUNDEN($F$1+($F$3-$F$1)/9*(ZEILE()-2);)
K9=RUNDEN($F$3+($H$1-$F$3)/9*(ZEILE()-2);)
J10=RUNDEN($F$1+($F$3-$F$1)/9*(ZEILE()-2);)
K10=RUNDEN($F$3+($H$1-$F$3)/9*(ZEILE()-2);)
J11=RUNDEN($F$1+($F$3-$F$1)/9*(ZEILE()-2);)
K11=RUNDEN($F$3+($H$1-$F$3)/9*(ZEILE()-2);)
Achtung, Matrixformel!
Die geschweiften Klammern{} nicht eingeben,
sondern die Zelle mit
Shift + Strg + Enter
verlassen statt Enter alleine.

Gruß
Rudi

AW: Zusammengestückelte Formel
03.04.2013 12:07:13
Oberschlumpf
Hi Jürgen,
wieso schreibst du in der Formel den Wert 0,4 noc mal in eine extra Klammer?
Vielleicht ist das ja schon der Grund fürs manchmalige "Fehlverhalten" der Formel.
Hilfts?
Ciao
Thorsten

AW: Zusammengestückelte Formel
03.04.2013 12:46:30
Rudi
Hallo,
wenn A lückenlos mit Zahlen gefüllt ist, brauchst du keine Hilfszelle.
=VERGLEICH(0,4;A3:Index(A:A;Anzahl(A:A)+2);1)
Gruß
Rudi

AW: Zusammengestückelte Formel
03.04.2013 13:00:49
Kraichtaler
Hallo Rudi,
ist ja verrückt......Deine Formel scheint zu funktionieren.....Klasse....vielen, vielen Dank. Ich werde ab sofort mal diese Formel in meiner Datei einbauen und beobachten ob sie auch wirklich immer funktioniert.....aber schon jetzt vielen herzlichen Dank
gruß
Jürgen

AW: Zusammengestückelte Formel
03.04.2013 13:04:23
Klaus
Hallo Rudi und Jürgen,
ich bleibe der Meinung, dass dies ein Holzweg ist.
Jürgen, wenn du auf meinen Beitrag antwortest (und eine Datei lädst) teste ich das gerne ausführlich.
Grüße,
Klaus M.vdT.

so wie du die Formel anwendest, ...
03.04.2013 13:09:46
Rudi
Hallo,
... gibt sie immer die Pos. des letzten Werts, der kleiner oder gleich Kriterium ist, zurück.
Das kann zufällig richtig sein.
ABC
30,391WAHR8
40,392WAHR 
50,395WAHR 
62FALSCH 
70,396WAHR 
80,4WAHR 
90,398WAHR 
100,1WAHR 
112FALSCH 
125FALSCH 

ZelleFormel
B3=A3<=0,4
C3=VERGLEICH(0,4;A3:A121)

Richtig ist 6!
Gruß
Rudi

Danke Rudi! ...
03.04.2013 13:12:55
Klaus
...
Grüße,
Klaus M.vdT.

Beliebteste Forumthreads (12 Monate)

Anzeige

Beliebteste Forumthreads (12 Monate)

Anzeige
Anzeige
Anzeige