Live-Forum - Die aktuellen Beiträge
Anzeige
Archiv - Navigation
1316to1320
Aktuelles Verzeichnis
Verzeichnis Index
Übersicht Verzeichnisse
Vorheriger Thread
Rückwärts Blättern
Nächster Thread
Vorwärts blättern
Anzeige
HERBERS
Excel-Forum (Archiv)
20+ Jahre Excel-Kompetenz: Von Anwendern, für Anwender
Inhaltsverzeichnis

Abgleich von Zeilen

Abgleich von Zeilen
26.06.2013 14:43:02
Zeilen

Hallo
In 2 Tabelle stehen jeweils ca. 5000 Zellen die gegeneinander abgeglichen werden müssen.
Beispiel: A4 Abgleich mit D4 = OK , A6 Abgleich mit D6 = falsch ( weil in A6 nicht vorhanden).
Gibt es hier eine Formel die angewendet werden kann um einen Abgleich auf alle 5000 Zellen durchführen zu können. Ich habe einen Auszug hinzugefügt. Für eure Hilfe wäre ich dankbar.
https://www.herber.de/bbs/user/86060.xlsx

8
Beiträge zum Forumthread
Beiträge zu diesem Forumthread

Betreff
Datum
Anwender
Anzeige
=WENN(UND(A4=D4;B4=E4);"OK";"falsch") _oT
26.06.2013 14:48:45
NoNet
_oT = "ohne Text"

AW: =WENN(UND(A4=D4;B4=E4);"OK";"falsch") _oT
26.06.2013 16:04:40
Hans
Danke für die schnelle Antwort.Sorry ich habe das Problem wohl nicht korrekt beschrieben!Die Spalten B und E in der Summen stehen sollen abgeglichen werden. Das kann ich ja mit einer Wenn Abfrage leicht machen. Dazu muss aber erst die Nummer in Spalt A und D gleich sein. Aber wenn in Spalte
A nicht das gleiche steht wie in D (oder umgekehrt)dann müsste ich erst die ganzen zellen aus A oder D manuell runterziehen.
Beispiel A4=2010 - D4=2010 (alles OK) wenn aber A4=2010 und D4=2011 dann muss ich die Spalte D4 bis D5000 markieren und eine Zelle runterziehen und dann in D4 erst 2010 einsetzen. Somit habe ich dann auf der gleichen Ebene die gleiche Zahl und kann dann die Summen aus B und E abgleichen.
Gibt es eine Formel die eine Zelle automatisch einfügt wenn eine Zahl fehlt?
Nochmal Danke.

Anzeige
Formelvorschlag
26.06.2013 18:14:02
Erich
Hi Hans,
meinst du das so?
 ABCDEFGHIJ
3Obj Tab_1Anzahl  Obj Tab_2Anzahl Info1Info2 Info1 kurzInfo1-Hilf
410021 10021ok  ok1
5101410 10149ungleich  ungleich2
6   10171fehlt: 1017fehlt:  fehlt: 1017#NV
710211   fehlt: fehlt: 1021 fehlt: #NV
810227 10223ungleich  ungleich5
910230 10231ungleich  ungleich6

Formeln der Tabelle
ZelleFormel
F4=WENN(ISTNV(VERGLEICH(D4;A$4:A$9999;0)); "fehlt: "&D4; WENN(E4=INDEX(B$4:B$9999;VERGLEICH(D4;A$4:A$9999;0)); "ok";"ungleich"))
G4=WENN(ISTNV(VERGLEICH(A4;D$4:D$9999;0)); "fehlt: "&A4;"")
I4=WENN(ISTNV(J4); "fehlt: "&D4;WENN(E4=INDEX(B$4:B$9999;J4); "ok";"ungleich"))
J4=VERGLEICH(D4;A$4:A$9999;0)


Excel Tabellen im Web darstellen >> Excel Jeanie HTML 4
In Sp. F wird geprüft, ob ein Wert aus Sp. D auch in Sp. A vorkommt. Wenn nein, wird "fehlt: ..." ausgegeben.
Wenn ja, werden die Werte in den Spalten B und E der entsprechenden Zeilen verglichen.
In Sp. G wird geprüft, ob ein Wert aus Sp. A auch in Sp. D vorkommt. Wenn nein, wird "fehlt: ..." ausgegeben.
Die Spalten I und J zeigen eine kürzere und schnellere Variante der Spalte F, aber mit J als Hilfsspalte.
Rückmeldung wäre nett! - Grüße aus Kamp-Lintfort von Erich

Anzeige
AW: Formelvorschlag
26.06.2013 19:20:43
Hans
Hallo Erich. Vielen Dank - Leider wird keine "neue" Zelle bei einer fehlenden Nummer eingefügt.
Ansonsten Super.Ich denke das geht nur über einen VBA Befehl
Danke nochmal

noch ein Formelvorschlag
26.06.2013 20:08:03
Erich
Hi Hans,
vielleicht möchtest du das hier erreichen (Formeln von F5:G5 nach unten kopieren):
 FG
3Alle Obj.Status
41002ok
51014ungleich
61017fehlt in A
71021fehlt in D
81022ungleich
91023ungleich

Formeln der Tabelle
ZelleFormel
F4=MIN(A4:A9999;D4:D9999)
G4{=WENN(F4="";"";WENN(ISTNV(VERGLEICH(F4;A$4:A$9999;0)); "fehlt in A"; WENN(ISTNV(VERGLEICH(F4;D$4:D$9999;0)); "fehlt in D"; WENN(SVERWEIS(F4;A$4:B$9999;2;0)=SVERWEIS(F4;D$4:E$9999;2;0); "ok";"ungleich"))))}
F5{=WENN(MAX(F$4:F4)=MAX(A$4:A$9999;D$4:D$9999); ""; MIN(WENN(A$4:A$9999>F4;A$4:A$9999); WENN(D$4:D$9999>F4;D$4:D$9999)))}
G5{=WENN(F5="";"";WENN(ISTNV(VERGLEICH(F5;A$4:A$9999;0)); "fehlt in A"; WENN(ISTNV(VERGLEICH(F5;D$4:D$9999;0)); "fehlt in D"; WENN(SVERWEIS(F5;A$4:B$9999;2;0)=SVERWEIS(F5;D$4:E$9999;2;0); "ok";"ungleich"))))}


 FG
561196fehlt in A
571198ungleich
581201ungleich
591204fehlt in D
601205fehlt in D
611210fehlt in D
621212fehlt in D
63  

In Spalte F werden zunächst alle Einträge aus A und D versammmelt (ohne Doppelte).
Dann wird für jeden Eintrag in F geprüft, ob er in A und in D vorhanden ist.
Ist er in beiden Spalten vorhanden, werden B und E vergleichen.
Rückmeldung wäre nett! - Grüße aus Kamp-Lintfort von Erich

Anzeige
ein weiterer Formelvorschlag
29.06.2013 10:32:54
Erich
Hi Hans,
und wie wäre es damit (Formeln von G5:I5 nach unten kopieren)?
 ABCDEFGHI
3Obj_1Wert  Obj_2Wert  Exp.Obj_1Exp.Obj_2Vergl
410021 10021 10021002ok
5101410 10149 10141014ungleich
6   10221 1021fehlt in Bfehlt
710211    10221022ungleich
810227 11003 fehlt in A1100fehlt
9120513 11961 fehlt in A1196fehlt
1014007 120513 12051205ok
1114011 14010 1400fehlt in Bfehlt
121402  1402  14011401ungleich
1314057 14031 14021402ok
14      fehlt in A1403fehlt
15      1405fehlt in Bfehlt
16        leer
17        leer

Formeln der Tabelle
ZelleFormel
G4=WENN(MIN(A4:A999)>MIN(D4:D999); "fehlt in A";MIN(A4:A999))
H4=WENN(MIN(A4:A999)<MIN(D4:D999); "fehlt in B";MIN(D4:D999))
I4=WAHL(1+ANZAHL(G4:H4); "leer";"fehlt";WENN(SVERWEIS(G4;A$4:B$999;2;0)=SVERWEIS(H4;D$4:E$999;2;0); "ok";"ungleich"))
G5{=WENN(MAX(G$4:H4)=MAX(A$4:A$999;D$4:D$999); ""; WENN(MAX(G$4:G4)=MAX(A$4:A$999); "fehlt in A"; WENN((MIN(WENN(A$4:A$999>MAX(G$4:H4); A$4:A$999))>MIN(WENN(D$4:D$999>MAX(G$4:H4); D$4:D$999))) *(MIN(WENN(D$4:D$999>MAX(G$4:H4); D$4:D$999))>=MAX(G$4:H4)); "fehlt in A";MIN(WENN(A$4:A$999>MAX(G$4:H4); A$4:A$999)))))}
H5{=WENN(MAX(G$4:H4)=MAX(A$4:A$999;D$4:D$999); ""; WENN(MAX(H$4:H4)=MAX(D$4:D$999); "fehlt in B"; WENN((MIN(WENN(D$4:D$999>MAX(G$4:H4); D$4:D$999))>MIN(WENN(A$4:A$999>MAX(G$4:H4); A$4:A$999))) *(MIN(WENN(A$4:A$999>MAX(G$4:H4); A$4:A$999))>=MAX(G$4:H4)); "fehlt in B";MIN(WENN(D$4:D$999>MAX(G$4:H4); D$4:D$999)))))}
I5=WAHL(1+ANZAHL(G5:H5); "leer";"fehlt";WENN(SVERWEIS(G5;A$4:B$999;2;0)=SVERWEIS(H5;D$4:E$999;2;0); "ok";"ungleich"))

Rückmeldung wäre nett! - Grüße aus Kamp-Lintfort von Erich

Anzeige
AW: ein weiterer Formelvorschlag
29.06.2013 14:12:34
Hans
Das sieht gut aus. So hab ich mir das vorgestellt. Danke Hans

und noch mal einfacher
29.06.2013 19:00:56
Erich
Hi Hans,
danke für deine Rückmeldung!
Dafür noch eine Vereinfachung der Formel in Spalte H:
 ABCDEFGHI
3Obj_1Wert  Obj_2Wert  Exp.Obj_1Exp.Obj_2Vergl
410021 10021 10021002ok
5101410 10149 10141014ungleich

Formeln der Tabelle
ZelleFormel
G4=WENN(MIN(A4:A999)>MIN(D4:D999); "fehlt in A";MIN(A4:A999))
H4=WENN(MIN(A4:A999)<MIN(D4:D999); "fehlt in B";MIN(D4:D999))
I4=WAHL(1+ANZAHL(G4:H4); "leer";"fehlt";WENN(SVERWEIS(G4;A$4:B$999;2;0)=SVERWEIS(H4;D$4:E$999;2;0); "ok";"ungleich"))
G5{=WENN(MAX(G$4:H4)=MAX(A$4:A$999;D$4:D$999); ""; WENN(MAX(G$4:G4)=MAX(A$4:A$999); "fehlt in A"; WENN((MIN(WENN(A$4:A$999>MAX(G$4:H4); A$4:A$999))>MIN(WENN(D$4:D$999>MAX(G$4:H4); D$4:D$999))) *(MIN(WENN(D$4:D$999>MAX(G$4:H4); D$4:D$999))>=MAX(G$4:H4)); "fehlt in A";MIN(WENN(A$4:A$999>MAX(G$4:H4); A$4:A$999)))))}
H5{=WENN(MAX(G$4:H4)=MAX(A$4:A$999;D$4:D$999); ""; WENN(ISTZAHL(G5); WENN(ISTNV(VERGLEICH(G5;D$4:D$999;0)); "fehlt in B";G5); MIN(WENN(D$4:D$999>MAX(G$4:H4); D$4:D$999))))}
I5=WAHL(1+ANZAHL(G5:H5); "leer";"fehlt";WENN(SVERWEIS(G5;A$4:B$999;2;0)=SVERWEIS(H5;D$4:E$999;2;0); "ok";"ungleich"))

Rückmeldung wäre nett! - Grüße aus Kamp-Lintfort von Erich
Anzeige

Beliebteste Forumthreads (12 Monate)

Anzeige

Beliebteste Forumthreads (12 Monate)

Anzeige
Anzeige
Anzeige