Suchfeld



Excel-Version: Excel 2002
nach unten

Betrifft: Suchfeld
von: Micha
Geschrieben am: 10.07.2002 - 06:47:37

Hi Profies,
ich möchte eigentlich nur nach einem Text (z.Bsp. "Meier") in meiner Arbeitsmappe suchen. Das ganze soll jedoch nicht über "Bearbeiten" -> "Suchen" laufen, sondern ein Feld in welches ich den Namen eingeben kann und einen Button der die Suche startet. Also vom Ergebnis her wahrscheinlich wirklich simpel, aber ich habe wirklich keine Idee. Wichtig ist dabei nur zu wissen ob der Name Meier vorkommt und eventuell auf das Tabellenblatt zuspringen in welchem der Name steht. Ich hoffe Ihr könnt mir helfen. Danke und Gruß
Micha

nach oben   nach unten

Re: Suchfeld
von: Hans W. Herber
Geschrieben am: 10.07.2002 - 07:28:32

Hallo Micha,

wie folgt:


Sub GoToFinden()
   Dim wks As Worksheet
   Dim rng As Range
   Dim iCounter As Integer
   Dim vSearch As Variant
   vSearch = Range("B1").Value
   For iCounter = 2 To Worksheets.Count
      With Worksheets(iCounter)
         Set rng = .Cells.Find( _
            what:=vSearch, _
            after:=.Range("A1"), _
            LookIn:=xlValues, _
            lookat:=xlWhole)
      End With
      If Not rng Is Nothing Then
         Application.Goto rng, True
      End If
   Next iCounter
End Sub

hans

nach oben   nach unten

Re: Suchfeld
von: Micha
Geschrieben am: 10.07.2002 - 09:11:15

Hallo Hans,
erstmal viel Dank !!!
Jedoch erfolgt immer ein Sprung zum letzten Tabellenblatt der Arbeitsmappe wenn ich das Makro starte.
Ich sitze jetzt vor einem Excel 97, könnte da das Problem liegen ? Oder muß ich noch irgendwas editieren ?
Gruß und nochmal Danke
Micha

nach oben   nach unten

Re: Suchfeld
von: Hans W. Herber
Geschrieben am: 10.07.2002 - 14:21:03

... setze hinter die Zeile:
Application.Goto rng, True

eine Zeile mit:
Exit Sub

hans

nach oben   nach unten

Re: Suchfeld
von: Micha
Geschrieben am: 11.07.2002 - 20:58:43

Nochmals vielen Dank, Hans.

Jetzt funktioniert es. Zu 97% ...
Ich habe z.Bsp. 7 Tabellenblätter, auf jedem dieser Blätter soll eine Schaltfläche, verküpft mit diesem Makro, sein.
Jetzt ist es so, daß wenn ich einen Button, verküpft mit diesem Makro,auf dem Tabellenblatt 4 habe nur das Tabellenblatt 3 durchsucht wird. Nehme ich einen Namen von z.Bsp. Tabellenblatt 2, so springt nach klicken des Buttons der Cursor im Tabellenblatt 4 auf die Zelle in der der Suchbegriff steht.
Hast Du nochmal Lust Dein Knowhow preiszugeben ?
Auf jedenfall erstmal vielen Dank für alles und Grüße
Micha


nach oben   nach unten

Re: Suchfeld
von: Hans W. Herber
Geschrieben am: 12.07.2002 - 06:38:07

... das hat ja mit der Ausgangslage nicht mehr allzuviel zu tun. Inzwischen weiss ich auch nicht mehr so genau, was Du möchtest. Mal davon ausgehend, dass beim ersten Suchbegriff gestoppt werden soll, das nachfolgende Makro:


Sub GoToFinden()
   Dim wks As Worksheet
   Dim rng As Range
   Dim iCounter As Integer
   Dim vSearch As Variant
   vSearch = Range("B1").Value
   For iCounter = 1 To Worksheets.Count
      If Worksheets(iCounter).Name <> ActiveSheet.Name then
         With Worksheets(iCounter)
            Set rng = .Cells.Find( _
               what:=vSearch, _
               after:=.Range("A1"), _
               LookIn:=xlValues, _
               lookat:=xlWhole)
         End With
         If Not rng Is Nothing Then
            Application.Goto rng, True
            Exit Sub
         End If
      End If
   Next iCounter
End Sub

Du musst versuchen, den Code zu verstehen, so kompliziert ist er nicht.

hans

nach oben   nach unten

Re: Suchfeld
von: Micha
Geschrieben am: 12.07.2002 - 19:08:34

Hallo Hans,
vielen Dank zum x-ten Mal. Diesmal war es der Volltreffer, Du hast mir unglaublich geholfen.

Entschuldige bitte wenn ich mich nicht ganz klar ausgedrückt habe ...
Schönes Wochenende
Micha


 nach oben

Beiträge aus den Excel-Beispielen zum Thema "Aufgabe Aktiendepot"