Anzeige
Archiv - Navigation
1340to1344
Aktuelles Verzeichnis
Verzeichnis Index
Übersicht Verzeichnisse
Vorheriger Thread
Rückwärts Blättern
Nächster Thread
Vorwärts blättern
Anzeige
HERBERS
Excel-Forum (Archiv)
20+ Jahre Excel-Kompetenz: Von Anwendern, für Anwender
Inhaltsverzeichnis

Drucken von ausgebelndeten Zeilen

Drucken von ausgebelndeten Zeilen
05.12.2013 09:56:48
ausgebelndeten
Hallo,
ich würde gerne ausgebelndete Zeilen mit auf dem Ausdruck haben. Ich habe auch bereits einen VBA code zum automatischen einblenden der Zeile vor dem Druck gefunden.
Private Sub Workbook_BeforePrint(Cancel As Boolean)
ActiveSheet.Cells.EntireRow.Hidden = False
End Sub

Leider reicht mir das nicht ganz - da die ausgeblendeten Zeilen dann wieder dauerhaft eingeblendet sind.
Lange Rede kurzer Sinn: Kann mir jemand den Code zum Drucken (nicht einblenden) von ausgeblendten Zeilen sagen?
Vielen Dank im Voraus!!

18
Beiträge zum Forumthread
Beiträge zu diesem Forumthread

Betreff
Datum
Anwender
Anzeige
AW: Drucken von ausgebelndeten Zeilen
05.12.2013 11:40:51
ausgebelndeten
Hallo
Ich habe es so gelöst:
- Druck abbrechen
- Kopie des Blattes anlegen
- alle ausgeblendeten Zeilen hinter der letzten benutzten Spalte markieren "HH"
- Filter setzen auf HH
- alle zeilen ab Zeile 2 (wegen der Überschrift) löschen
- Filter weg
- Markierung weg
- Ausdrucken
- Kopie löschen
OK?

Private Sub Workbook_BeforePrint(Cancel As Boolean)
Cancel = True
On Error GoTo Fehler
Dim TB1, ZE&, RR&, CC%, i%, Drucken As Boolean
ZE = 2 'erste Zeile ggf Ändern wegen Überschrift
Set TB1 = ActiveSheet
TB1.Copy After:=Sheets(Sheets.Count)
With ActiveSheet ' das Neue
If .AutoFilterMode Then .AutoFilterMode = False ' Autofilter ausschalten
RR = .Cells.SpecialCells(xlCellTypeLastCell).Row 'Letzte Zeile des gesamten Blattes
CC = .Cells.SpecialCells(xlCellTypeLastCell).Column + 1 'Letzte Spalte des gesamten  _
Blattes+1
Application.ScreenUpdating = False
For i = ZE To RR
If .Rows(i).EntireRow.Hidden = True Then
Drucken = True
.Cells(i, CC) = "HH"
End If
Next
If Drucken = True Then
.Columns(CC).AutoFilter Field:=1, Criteria1:="HH"
.Rows(ZE & ":" & RR).Delete xlUp
.AutoFilterMode = False
.Columns(CC).Delete xlLeft
Application.EnableEvents = False
'*** neu ausdrucken ggf anpassen
ExecuteExcel4Macro "PRINT(1,,,1,,,,,,,,2,,,TRUE,,FALSE)"
Application.EnableEvents = True
Else
MsgBox "Keine Daten zum Drucken"
End If
Application.DisplayAlerts = False
.Delete
Application.DisplayAlerts = True
End With
TB1.Select
Err.Clear
Fehler:
If Err.Number  0 Then MsgBox "Fehler: " & Err.Number & vbLf & Err.Description: Err.Clear
Application.DisplayAlerts = True
End Sub

Gruß UweD

Anzeige
AW: Drucken von ausgebelndeten Zeilen
05.12.2013 12:03:46
ausgebelndeten
Hallo UweD,
vielen Dank für deine Antwort und soweit ich das einschätzen kann, dürfte das auch mein Problem lösen. Leider hackt es an meinen (prkatisch nicht vorhanden) VBA Kenntnissen und der Anpassung deines Codes auf meine Datei.
Ich habe jetzt einfach mal die original Datei angehängt (ist sowieso nur ein Template)vielleicht bist ja so nett mir bei der Anpassung zu helfen....
https://www.herber.de/bbs/user/88387.xlsm
Sorry aber ist das erste Mal das ich mit VBA etwas zu tun habe.
In jedem Fall vielen Dank

Anzeige
AW: Drucken von ausgebelndeten Zeilen
05.12.2013 12:13:14
ausgebelndeten
Hallo
Ist doch richtig eingefügt.
Aber außer den beiden ersten Zeilen ist nichts ausgeblendet...
Gruß UweD

AW: Drucken von ausgebelndeten Zeilen
05.12.2013 12:22:04
ausgebelndeten
Hallo nochmal
ersetze bitte
ExecuteExcel4Macro "PRINT(1,,,1,,,,,,,,2,,,TRUE,,FALSE)"
durch

.Printout
(inkl. Punkt davor)

AW: Drucken von ausgebelndeten Zeilen
05.12.2013 12:29:54
ausgebelndeten
Hallo,
entschuldigung ich glaube ich hatte mich Anfangs nicht genau ausgedrückt. Ich möchte nicht nur die ausgeblendeten Zeilen drucken sondern AUCH die ausgeblendeten Zeilen (also inkl. den eingeblendeten Zeilen) drucken.
Wenn ich es mit deinem Code probiere habe ich zwei Probleme. Zum einen werden nur die ausgeblendeten Zeilen gedruckt aber auch hier scheint noch irgendwo ein Anpassungsfehler zu sein. Ausgeblendet sind die Zeilen 1 und 2 - gedruckt wird aber nur die Zeile 2 und nochmals eine Zeile die ich nicht genau benennen kann.
Dein Vorschlag mit .Printout habe ich probiert - gab aber keine Änderung am Ausdruck.
Gruß Sebastian

Anzeige
AW: Uuups
05.12.2013 12:54:30
UweD
Hallo
ja, das habe ich dann genauso (falsch) verstanden
Versuch erst mal die Anderen Lösungen.. Komme momentan nicht dazu
LG UweD

AW: Drucken von ausgebelndeten Zeilen
05.12.2013 12:50:29
ausgebelndeten
Hallo Sebastian,
anbei deine Datei mit Makro (Aufruf mit Strg+z) zurück.
Ich musste eine Hilfsspalte (momentan ausgeblendet) einfügen, weil du diverse Zellen "verbunden" hast.
Das ist leider meistens der Tod jeden Makros.
Hinweis: In der Datei sind z.Zt. alle Zeilen eingeblendet! Du musst also zunächst Zeilen ausblenden, um das Makro zu testen.
https://www.herber.de/bbs/user/88388.xlsm
Gruß, Rolf

Anzeige
AW: Drucken von ausgebelndeten Zeilen
05.12.2013 11:53:11
ausgebelndeten
Hallo Sebastian,
vielleicht so?
Sub AusEinblenden()
Dim z As Long
Dim r As String
'ausgeblendete Zeilen ermitteln
For z = 1 To ActiveSheet.UsedRange.Rows.Count
If Range("A" & z).EntireRow.Hidden = True Then
If r = "" Then
r = r & Range("A" & z).EntireRow.Row & ":" & _
Range("A" & z).EntireRow.Row
Else
r = r & ", " & Range("A" & z).EntireRow.Row & ":" & _
Range("A" & z).EntireRow.Row
End If
End If
Next z
'alle Zeilen einblenden und Tabelle drucken
With ActiveSheet
.UsedRange.EntireRow.Hidden = False
.PrintOut Copies:=1
End With
'alle ursprünglich ausgeblendeten Zeilen wieder ausblenden
Range(r).EntireRow.Hidden = True
End Sub
Gruß, Rolf

Anzeige
AW: Drucken von ausgebelndeten Zeilen
05.12.2013 12:49:34
ausgebelndeten
Hallo Rolf,
auch dir vielen Dank für die Antwort.
Habe ich probiert, leider ohne Ergebnis. Kann ich den Code 1:1 übernehmen?
Gruß Sebastian

AW: Drucken von ausgebelndeten Zeilen
05.12.2013 12:33:38
ausgebelndeten
Hallo,
Private Sub Workbook_BeforePrint(Cancel As Boolean)
Cancel = True
ActiveSheet.Copy
With ActiveSheet
If .FilterMode Then .ShowAllData
.Rows.Hidden = False
.PrintOut
.Parent.Close False
End With
End Sub

Gruß
Rudi

AW: Drucken von ausgebelndeten Zeilen
05.12.2013 12:46:39
ausgebelndeten
Hallo Rudi,
vielen Dank für deine Antwort.
Das Makro zieht zwar (kurz nach dem Druckbefehl werden die Zeilen ein- und dann wieder ausgeblendet)allerdings und ich kann leider nicht sagen wieso, werden die ausgeblendeten Zeilen nicht gedruckt.
Zudem wird die Datei automaisch geschlossen und das würde ich gerne vermeiden. Vermute aber das düfte einfach zu ändern sein?
Grüße Sebastian

Anzeige
AW: Drucken von ausgebelndeten Zeilen
05.12.2013 13:08:20
ausgebelndeten
Hallo nochmal
Das Makro von Rudi um eine Wort erweitert...
dann klappt es bei mir

Private Sub Workbook_BeforePrint(Cancel As Boolean)
Cancel = True
ActiveSheet.Copy
With ActiveWorkbook.ActiveSheet
If .FilterMode Then .ShowAllData
.Rows.Hidden = False
.PrintOut
.Parent.Close False
End With
End Sub

AW: Drucken von ausgebelndeten Zeilen
05.12.2013 13:22:46
ausgebelndeten
Hallo,
HAMMMMMMMMMMER
Funktioniert perfekt!!!
Viele, vielen Dank
Auch an die anderen Kollegen...

AW: Drucken von ausgebelndeten Zeilen
05.12.2013 14:57:49
ausgebelndeten
Hallo nochmal,
da war ich leider etwas zu schnell mit der Freude :-(
Wie gesagt der Code funktioniert reibungslos und tut genau das was er tun soll.
Allerdings habe ich bereits kurz erwähnt, dass es sich bei der Datei um ein Template handelt. Aus diesem Grund würde ich gerne (bzw. muss ich eigentlich fast) den Blattschutz aktivieren um gesperrte Zellen zu schützen.
Sobald ich aber den Blattschutz aktiviere kommt es zu Problemen mit VBA.
Fehlermeldung:
Laufzeitfehler '1004'
Die Hidden-Eigenschaft des Range-Objektes kann nicht festgelegt werden.
Wenn ich auf debuggen klicke, ist die Zeile ".Rows.Hidden = False" gelb markiert.
Hat jemand dazu einen Lösungsvorschlag?
Vielen Dank im Voraus
Sebastian

Anzeige
AW: Drucken von ausgebelndeten Zeilen
05.12.2013 15:05:44
ausgebelndeten
Hallo,
dann musst du ihn eben aufheben.

Private Sub Workbook_BeforePrint(Cancel As Boolean)
Cancel = True
ActiveSheet.Copy
With ActiveWorkbook.ActiveSheet
.UnProtect "Passwort"
If .FilterMode Then .ShowAllData
.Rows.Hidden = False
.PrintOut
.Parent.Close False
End With
End Sub
Gruß
Rudi

AW: Drucken von ausgebelndeten Zeilen
05.12.2013 15:09:27
ausgebelndeten
Naja, wäre glaube ich alles einfacher wenn man sich ein bisschen auskennt...
Auf jeden Fall VIELEN DANK

AW: Drucken von ausgebelndeten Zeilen
05.12.2013 16:06:54
ausgebelndeten
Hallo Sebastian,
anbei nochmals die Datei mit geändertem Makro. Ich hoffe, du hast kein Password vergeben...
https://www.herber.de/bbs/user/88390.xlsm
Gruß, Rolf

Anzeige
AW: Drucken von ausgebelndeten Zeilen
05.12.2013 13:09:13
ausgebelndeten
Hallo,
stimmt. Muss man enkoppeln.
in DieseArbeitsmappe:
Private Sub Workbook_BeforePrint(Cancel As Boolean)
Cancel = True
PrintAll ActiveSheet
End Sub

In ein Modul:
Sub PrintAll(wks As Worksheet)
wks.Copy
With ActiveSheet
If .FilterMode Then .ShowAllData
.Rows.Hidden = False
.PrintOut
.Parent.Close False
End With
End Sub

Gruß
Rudi

Beliebteste Forumthreads (12 Monate)

Anzeige

Beliebteste Forumthreads (12 Monate)

Anzeige
Anzeige
Anzeige