Termine auszählen

Bild

Betrifft: Termine auszählen
von: Sandra
Geschrieben am: 12.05.2015 20:55:32

Hallo zusammen,
aus einer Liste, die die Anwesennheiten von Teilnehmern in einem Kurs darstellt, möchte ich nun die Termine pro Kurs auflisten:
https://www.herber.de/bbs/user/97608.xlsx
1.) Tabellenblatt Anwesenheit = die gegebene Liste (ist im Original viel umfangreicher)
2.) Tabellenblatt KursTermine = soll aus dem 1. Tabellenblatt entstehen
3.) Tabellenblatt AnzahlProKurs = soll aus dem 1. oder 2. Tabellenblatt entstehen
Ich habe nun lange getüffelt, aber komme auf keinem grünen Zweig.
Kann mir jemand bei der Erstellung von 2 und 3 helfen?
Vielen Dank im Voraus
Sandra

Bild

Betrifft: mit Matrixfunktion(alität)sformeln ...
von: der neopa C
Geschrieben am: 13.05.2015 08:47:11
Hallo Sandra,
... und meiner Interpretation Deiner Zielstellung. Dazu hab ich in der Tabelle Anwesenheit!C15 den Termin geändert, damit die Ergebnisse einfacher kontrollierbar sind.
Die Formel Kurstermine!A2 nach rechts und unten kopieren (Spalte C erübrigt sich dort, weil jetzt hier nur die Termine gelistet werden, an dem eine Teilnahme erfolgte) und
Formel AnzahlProKurs!A2 nach unten und B2 nach rechts und unten kopieren. In dieser Tabelle sind jetzt auch nur die Termine aus Tabelle Kursteilnahme ausgewertet:

 ABCDEF
1Anzahl Teilnahme-Termine pro Kurs / Monat
2KursnrJan 15Feb 15Mrz 15Apr 15Mai 15
312000 
432010 
5      

Formeln der Tabelle
ZelleFormel
A3=WENNFEHLER(INDEX(KursTermine!A:A;AGGREGAT(15;6;ZEILE(A$1:A$99)/ISTFEHLER(VERGLEICH(KursTermine!A$1:A$99;A$2:A2;))/(KursTermine!A$1:A$99<>""); 1)); "")
B3=WENN($A3="";"";SUMMENPRODUKT(((KursTermine!$A$2:INDEX(KursTermine!$A:$A;ANZAHL(KursTermine!$B:$B)+1))=$A3)*(MONAT((KursTermine!$B$2:INDEX(KursTermine!$B:$B;ANZAHL(KursTermine!$B:$B)+1)))=MONAT(B$2))))


 AB
1KursnrDatum
2102.01.2015
3109.01.2015
4301.01.2015
5308.01.2015
6315.03.2015
7  

Formeln der Tabelle
ZelleFormel
A2=WENNFEHLER(INDEX(Anwesenheit!E:E;AGGREGAT(15;6;ZEILE(A$1:A$99)/(Anwesenheit!$G$1:$G$99="x")/ISTFEHLER(VERGLEICH(Anwesenheit!$E$1:$E$99&"#"&Anwesenheit!$F$1:$F$99;$A$1:$A1&"#"&$B$1:$B1;)); 1)); "")


 ABCDEFG
1TN-NrVornameNachnameFirmaKursnrDatumAW
21ElenaMüllerABC102.01.2015x
32MariaMeierABC102.01.2015x
41ElenaMüllerABC109.01.2015e
52MariaMeierABC109.01.2015x
63PetraSchmidtABC202.01.2015e
73PetraSchmidtABC215.01.2015e
84MiaNeumüllerDEF301.01.2015x
94MiaNeumüllerDEF309.01.2015e
105HeidiSteinDEF308.01.2015x
115HeidiSteinDEF315.03.2015x
125HeidiSteinDEF322.01.2015e
135HeidiSteinDEF329.01.2015e
14       

Gruß Werner
.. , - ...

Bild

Betrifft: AW: mit Matrixfunktion(alität)sformeln ...
von: Sandra
Geschrieben am: 13.05.2015 09:48:44
Hallo Werner,
funktioniert super. Bin begeistert.
Vielen Dank
Sandra

Bild

Betrifft: AW: mit Matrixfunktion(alität)sformeln ...
von: Sandra
Geschrieben am: 13.05.2015 10:38:04
Hallo Werner,
eine Rückfrage habe ich doch. Es funktioniert einwandfrei bis Zeile 99. Alle Daten, die darüber hinausgehen, ignoriert Excel (soweit logisch). Wenn ich die Bereich aber anpasse auf 9999, bekomme ich keine weiteren Daten und in Spalte A bekomme ich nur Kursnr 6 ab Zeile 12 gezeigt:
~f =WENNFEHLER(INDEX(Anwesenheit!E:E;AGGREGAT(15;6;ZEILE(A$1:A$9999)/(Anwesenheit!$G$1:$G$9999="x")/ISTFEHLER(VERGLEICH(Anwesenheit!$E$1:$E$9999&"#"&Anwesenheit!$F$1:$F$9999;$A$1:$A1&"#"&$B$1:$B1;)); 1)); "")
In der echten Tabelle gibt es ca. 100 Kurse mit 4-5 Daten pro Monat, 12 Monate pro Jahr und ca. 10 Teilnehmern pro Kurs....
Vielen Dank für Deine Rückmeldung
Sandra

Bild

Betrifft: kann ich so nicht nachvollziehen ...
von: der neopa C
Geschrieben am: 13.05.2015 14:11:29
Hallo Sandra,
... bist Du denn sicher, dass Du in der Tabelle Anwesenheit in Spalte G ab Zeile 99 auch "x" zu stehen hast?
Wenn nicht müsstest Du einen Dateiauszug hier einstellen.
Gruß Werner
.. , - ...

Bild

Betrifft: AW: anbei die Datei
von: Sandra
Geschrieben am: 14.05.2015 16:57:23
Hallo Werner,
anbei die Datei. Es sind derzeit über 360 Zeilen. Es sind aber auch erst 2 MOnate des Jahres eingelesen, und noch nicht alle Kurse dabei.
https://www.herber.de/bbs/user/97652.xlsx
Vielen Dank für Deine Rückmeldung
Sandra

Bild

Betrifft: die Formel konsequent anpassen ...
von: der neopa C
Geschrieben am: 15.05.2015 07:42:27
Hallo Sandra,
... Du hast in der Formel B2 den Zeilenbereich noch nicht an die 9999 angepasst. Dort steht noch ... ZEILE(B$1:B$99)... und demzufolge wertet die Formel auch nur bis Zeile 99 aus. Außerdem hast Du die Formel in Spalte A auch erst in A3 zu stehen. Die musst Du noch nach A2 kopieren.
Wenn Du wirklich Massendatenauswerten willst, gibt es schnellere Lösungsmöglichkeiten als die bisherige. Ich bin allerdings jetzt ab sofort erst einmal mindestens eine Woche offline. Mach nach Pfingsten einen neuen Thread auf sprich mich dort im Betreff an und verlinke auf diesen Thread https://www.herber.de/forum/archiv/1424to1428/t1426020.htm. Vorläufig könntest Du anstelle der 9999 mit der max. vorhandenen auszuwertenden Datenanzahl in Deiner Datentabelle "Anwesenheit" arbeiten.
Gruß Werner
.. , - ...

 Bild

Beiträge aus den Excel-Beispielen zum Thema "Termine auszählen"