workpath einbauen in skript einbauen

Bild

Betrifft: workpath einbauen in skript einbauen
von: CHRIST
Geschrieben am: 20.05.2015 11:15:05

Hallo zusammen ich habe ein fertiges skript.
danke dafür (rudi)
nun möchte ich den der speicherort in gleichen Verzeignis liegt


Sub aaa()
    Dim strIn As String, strOut As String
    Const strOrg As String = "AUTO1"
    Const strRep As String = "Auto2"
    Const strDatei As String = "c:\bauer.txt"
    Open strDatei For Input As #1
    Do While Not EOF(1)
      Line Input #1, strIn
      strOut = strOut & vbCrLf & Replace(strIn, strOrg, strRep, , , vbBinaryCompare)
    Loop
    Close #1
    strOut = Mid(strOut, 2)
    Open strDatei For Output As #1
    Print #1, strOut
    Close #1
  End Sub

mein versuch funktioniert so leider nicht liegt natürlich an dem string aber wie kann ich es sonst machen?
Sub txtchange()
Grundpfad = ActiveWorkbook.Path
  Dim strIn As String, strOut As String
  Const strOrg As String = "AUTO1"
  Const strRep As String = "AUTO2"
       
  Const strDatei As String = Grundpfad & "\bauer.txt"
  
  
  Open strDatei For Input As #1
  
  Do While Not EOF(1)
    Line Input #1, strIn
    strOut = strOut & vbCrLf & Replace(strIn, strOrg, strRep, , , vbBinaryCompare)
      Loop
     
  Close #1
  strOut = Mid(strOut, 2)
  Open strDatei For Output As #1
  Print #1, strOut
  Close #1
   
End Sub

Bild

Betrifft: AW: workpath einbauen in skript einbauen
von: Uwe Küstner
Geschrieben am: 20.05.2015 11:22:45
Hallo,
strDatei ist dann keine Konstante mehr.

Sub txtchange()
  Dim strDatei As String
  Dim strIn As String, strOut As String
  Const strOrg As String = "AUTO1"
  Const strRep As String = "AUTO2"
       
  strDatei = ActiveWorkbook.Path & "\bauer.txt"
  
  
  Open strDatei For Input As #1
  
  Do While Not EOF(1)
    Line Input #1, strIn
    strOut = strOut & vbCrLf & Replace(strIn, strOrg, strRep, , , vbBinaryCompare)
      Loop
     
  Close #1
  strOut = Mid(strOut, 2)
  Open strDatei For Output As #1
  Print #1, strOut
  Close #1
   
End Sub
Gruß Uwe

Bild

Betrifft: AW: workpath einbauen in skript einbauen
von: UweD
Geschrieben am: 20.05.2015 11:28:17
Hallo
Grundpfad hat erst Inhalt, wenn die aktive Datei gespeichert ist

Sub txtchange()
    Dim strIn As String, strOut As String
    Const strOrg As String = "AUTO1"
    Const strRep As String = "AUTO2"
    Dim strDatei As String
    Dim Grundpfad As String
    Grundpfad = ActiveWorkbook.Path
    strDatei = Grundpfad & "\bauer.txt"
    '...
  
Gruß UweD

Bild

Betrifft: AW: workpath einbauen in skript einbauen
von: CHRIST
Geschrieben am: 20.05.2015 14:23:05
danke es funktioniert perfekt

 Bild

Beiträge aus den Excel-Beispielen zum Thema "workpath einbauen in skript einbauen"