Zellnamen in Array

Informationen und Beispiele zu den hier genannten Dialog-Elementen:
InputBox MsgBox
Bild

Betrifft: Zellnamen in Array
von: chito
Geschrieben am: 28.05.2015 11:13:42

Hallo zusammen,
ich hab mal wieder ein Problem und komme einfach nicht auf die Lösung.
In meiner Tabelle(Auswertung1)Auswertung2 und Auswertung3 stehen in Spalte A5-A250 Namen, die gleichen Namen haben meine Tabellenblätter nun möchte ich nur die Blätter ein und ausblenden, die in Auswertung3 stehen, sollte über VBA Makro gehen. Sollte so funktionieren, dass wenn ich Makro starte ich die Blätter von Auswertung1 oder 2 oder 3 sehen. Kann mir da geholfen werden.
Gruß
Chito

Bild

Betrifft: AW: Zellnamen in Array
von: fcs
Geschrieben am: 28.05.2015 13:06:52
Hallo Chito,
probiere als Ansatz das folgende Makro.
Gruß
Franz

Sub BlaetterEinAusblenden()
  Dim varAuswertung
  Dim wksAuswertung As Worksheet, wks As Worksheet
  Dim rngNamen As Range, varLine
  varAuswertung = Application.InputBox(Prompt:="Welche Auswertung soll angezeigt werden?" _
      & vbLf & "(1, 2 oder 3)", _
      Title:="Blätter einer Auswertung anzeigen", Default:=3, Type:=1)
  Select Case varAuswertung
    Case False
      Exit Sub
    Case 1, 2, 3
      Set wksAuswertung = ActiveWorkbook.Worksheets("Auswertung" & varAuswertung)
      Set rngNamen = wksAuswertung.Range("A5:A250")
      For Each wks In ActiveWorkbook.Worksheets
        Select Case wks.Name
            Case "Auswertung1", "Auswertung2", "Auswertung3"
              'diese Blätter nicht aus-/einblenden
            Case Else
              varLine = Application.Match(wks.Name, rngNamen, 0)
              If IsError(varLine) Then
                wks.Visible = xlSheetHidden
              Else
                wks.Visible = xlSheetVisible
              End If
        End Select
      Next
    Case Else
      MsgBox "Unzulässiger Zahlenwert für Auswertung!"
  End Select
End Sub


 Bild

Beiträge aus den Excel-Beispielen zum Thema "Formel vereinfachen"