Index / Vergleich geschachtelt...

Bild

Betrifft: Index / Vergleich geschachtelt...
von: Joerschi
Geschrieben am: 10.07.2015 20:47:02

Hallo liebes Forum,
ich hatte die Tage schon mal eine (einfachere Variante) des Problems geschildert und eine gute Lösung bekommen.
Zu finden hier: https://www.herber.de/forum/archiv/1432to1436/t1435268.htm
Jetzt benötige ich eine kleine Erweiterung der Formel, komme aber absolut nicht weiter :-(
Folgendes Problem soll via Formal gelöst werden (aktualisierte Skizze + Musterdatei unten):
Vorgegeben sind zwei Tabellen.
Tabelle 1 von B1:F4 mit 4 Bedingungen (jeweils untereinander zugehörig) sowie eine Ergebnistabelle B5:F6.
Bedingung 1 gehört zu Ergebnis 1, Bedingung 2 zu Ergebnis 2 und Bedingung 3 zu Ergebnis 3.
In Tabelle 1 ist immer ein Mix aus Bedingung 0 (Plichtbedingung) und Bedingung 1 ODER Bedingung 2 ODER Bedingung 3 gegeben.
Hieraus sind in der Zuordnungstabelle manuell gemischte Vorgaben daraus eingetragen (in A11:B14).
In C12:C15 soll nun - anhand der Vorgaben in A11:B14 - per Formel ausgerechnet werden, welches Ergebnis aus der Ergebnistabelle dazu passt.
Hier gab es schon eine Lösung von Werner (obiger Link) - allerdings damals noch ohne Bedingung/Ergebnis 3.
Außerdem soll in D12:D15 der Name des letztlichen Ergebnisses (aus D12:D15) ausgegeben werden.
In der Skizze sind die Ergebnisse schon kursiv eingetragen:
Userbild
Musterdatei: https://www.herber.de/bbs/user/98764.xls
Hätte jemand eine Idee, wie man
a) die Formel des gelben Bereiches adaptieren kann
b) die Formel des orangenen Bereiches aufstellen kann?
Danke vorab und liebe Grüße
Joerschi

Bild

Betrifft: AW: Index / Vergleich geschachtelt...
von: Sepp
Geschrieben am: 10.07.2015 21:44:34
Hallo Joerschi,
Tabelle1

 ABCDEFG
1Beding. 0F1F2F3F4F5 
2Beding. 15%3%2%1%20% 
3Beding. 214%20%12%3%4% 
4Beding. 312%18%25%40%42% 
5Ergebnistabelle      
6Ergebnis 125%26%27%28%29% 
7Ergebnis 230%31%32%33%34% 
8Ergebnis 365%66%67%68%69% 
9       
10Zuordnen      
11Beding. 0:Beding. 1 oder 2:Ergebnis?Name   
12F15%25,00%Ergebnis 1   
13F114%30,00%Ergebnis 2   
14F41%28,00%Ergebnis 1   
15F542%69,00%Ergebnis 3   
16       
17       

Formeln der Tabelle
ZelleFormel
C12{=INDEX($B$6:$F$8;MAX(WENN(INDEX($B$2:$F$4;;VERGLEICH($A12;$B$1:$F$1;0))=$B12;ZEILE($A$1:$A$3))); VERGLEICH($A12;$B$1:$F$1;0))}
D12{=INDEX($A$6:$A$8;MAX(WENN(INDEX($B$2:$F$4;;VERGLEICH($A12;$B$1:$F$1;0))=$B12;ZEILE($A$1:$A$3))))}
Enthält Matrixformel:
Umrandende
{ } nicht miteingeben,
sondern Formel mit STRG+SHIFT+RETURN abschließen!
Matrix verstehen


Excel Tabellen im Web darstellen >> Excel Jeanie HTML 4
Gruß Sepp


Bild

Betrifft: AW: Index / Vergleich geschachtelt...
von: Joerschi
Geschrieben am: 10.07.2015 22:18:02
Vielen lieben Dank Sepp :-)
Funktioniert einwandfrei *thumbsup*
Beste Grüße aus HD
Joerschi

Bild

Betrifft: geschachtelt ohne! MATRIX{} und kürzer, denn ...
von: der neopa C
Geschrieben am: 11.07.2015 08:12:06
Hallo Joerschi,
... Deine neue Fragestellung ist lediglich eine kleine Abwandlung zu Deiner letzten auf den Du auch per Link verwiesen hast. Deinen Text in B11 hab ich korrigiert.
Hier nun ist also Lösung nur eine kleine Anpassung meiner Formel von da notwendig. Siehe unten V12.
Zur Ermittlung des Namens in D12 ist die gleiche Formelbasis verwendbar. Die Formel hierfür wird aber noch kürzer, weil es ja keine Spaltenermittlung braucht (In unten stehender Formel D12 könnte auch anstelle $6:$8 jetzt A$6:A$8 stehen und dafür ";1" vor der letzten Klammer entfallen).
Dann hätte ich an Dich noch die Frage, warum Deine eingestellten Beispieldateien immer XLS-Dateien sind, obwohl Du angibst, das Du Excel 2010 im Einsatz hast?

 ABCDEF
1Beding. 0F1F2F3F4F5
2Beding. 15%3%2%1%20%
3Beding. 214%20%12%3%4%
4Beding. 312%18%25%40%42%
5Ergebnistabelle     
6Ergebnis 125%26%27%28%29%
7Ergebnis 230%31%32%33%34%
8Ergebnis 365%66%67%68%69%
9      
10Zuordnen     
11Beding. 0:Beding. ErgebnisName  
12F15%25,00%Ergebnis 1  
13F114%30,00%Ergebnis 2  
14F41%28,00%Ergebnis 1  
15F542%69,00%Ergebnis 3  
16      

Formeln der Tabelle
ZelleFormel
C12=INDEX($6:$8;VERGLEICH(B12;INDEX($2:$2;VERGLEICH(A12;$1:$1;)):INDEX($4:$4;VERGLEICH(A12;$1:$1;)); ); VERGLEICH(A12;$1:$1;))
D12=INDEX($6:$8;VERGLEICH(B12;INDEX($2:$2;VERGLEICH(A12;$1:$1;)):INDEX($4:$4;VERGLEICH(A12;$1:$1;)); ); 1)


Excel Tabellen im Web darstellen >> Excel Jeanie HTML 4
Gruß Werner
.. , - ...

Bild

Betrifft: Danke
von: Joerschi
Geschrieben am: 11.07.2015 09:28:01
Hallo Werner,
vielen Dank auch für Deine Lösung!
Zum Dateiformat: sorry, da hab ich nicht drauf geachtet. Ich speichere eher aus "Reflex" immer im xls-Format (und gebe dann nur an, mit welcher Version ich jedoch arbeite).
Wird künftig darauf geachtet.
Liebe Grüße
Joerschi

 Bild

Beiträge aus den Excel-Beispielen zum Thema "Index / Vergleich geschachtelt..."