Plan erweiterung

Bild

Betrifft: Plan erweiterung
von: Petra
Geschrieben am: 01.10.2015 18:38:13

Hallo zusammen,
http://www.uploadagent.de/show-200222-1443708691.html
musste es leider unter XLS hochladen , da es anders zu Groß oder nicht ging
Ich möchte gerne meine Datei Urlaubsplanung erweitern , hoffe ihr könnt mir dabei helfen, das es sehhhhr kompliziert ist.
Die Tabellenblätter Montag , Dienstag usw... sind Neu.
TB Mitarbeiter ist mein Stammbereich.
Rest sind die Kalendermonate ( Urlaub und Krank usw.)
Nehmen wir das TB Montag KW 40 als Beispiel.
Montag ist unsere Tagesansicht, die wir herausdrucken und manuell reinschreiben, wer Krank , Urlaub ,NS usw. hat.
1. Jetzt möchte ich gerne, dass wenn ich in der A1 die KW ändere, das dann Automatisch C1, und F1 aktualisiert wird.
Danach soll er in die Tabellenblätter Januar , Februar usw... ( bis KW 40 ) und dann Daten reinschreiben, ob der Mitarbeiter ( MA) krank, Frei, usw... drin steht und die in den TB Montag eintragen.
So das ich automatisch den Tagesreport/ Wochenreport habe, wenn ich die KW ändere.
Somit hätte ich fünf Blatter ( Montag Dienstag .....) zum ausdrucken und hätte alles drauf.
2. TB Montag soll natürlich auch die Mitarbeiter unterteilen in früh und spät wie TB Mitarbeiter Spalte H. Natürlich auch die anderen dazugehörigen Daten ( TB Mitarbeiter)Spalte( i,j)
Sollte ein Mitarbeiter gehen oder kommen, lege ich alles in der TB Mitarbeiter an.
Das TB Montag habe ich mal Manuell eingefügt.
Wie mache ich das, ist nicht gerade einfach
Danke an Alle, und hoffe um Hilfe.
Lieben Dank
Petra
Gruß aus ALLGÄU :-)

Bild

Betrifft: AW: Plan erweiterung - Formellösung
von: fcs
Geschrieben am: 02.10.2015 07:27:39
Hallo Petra,
eine Formellösung läßt sich umsetzen, wenn man sich in der Tabelle "Mitarbeiter" und den Tagestabellen Informationen aufbereitet, um über mehrere Ecken auf die Infos in den Monatstabellen zugreifen zu können. Diese Hilfsspalten kann man dann wenn alles funktioniert ausblenden.
Wenn ich dir die komplette Datei via E-Mail oder Upload aus Cloud zukommen lassen soll, dann schicke mir eine Mail (E-Mail-Adresse siehe mein Profil).
Nachfolgend Tabellenauszüge mit den Formeln.
Die letzte Zeile kannst du dann nach unten kopieren.
Für die Blätter kannst du die Formeln von Dienstag kopieren und musst nur die Formel in F1 anpassen.
Im Blatt "Mitarbeiter" musst du den Autofilterbereiche erweitern bis einschließlich der Hilfsspalte.
Im Blatt "Montag" wird die KW nur Zahl eingegeben. Die Darstellung "KW 40" ereichst du dann über eine benutzerdefinierte Formatierung: "KW "0
Gruß
Franz
Mitarbeiter

 QS
1  
2  
3GesamtHS
42015Früh/Spät
530,0früh001
630,0spät001
730,0früh002

Formeln der Tabelle
ZelleFormel
Q4=A1
Q5=N5+O5+P5
S5=WENN(H5="";"";WENN(H5="spät";"spät"&TEXT(ZÄHLENWENN(H$4:H5;"spät"); "000"); WENN(H5="früh";"früh"&TEXT(ZÄHLENWENN(H$4:H5;"früh"); "000"); "xxx")))
Q6=N6+O6+P6
S6=WENN(H6="";"";WENN(H6="spät";"spät"&TEXT(ZÄHLENWENN(H$4:H6;"spät"); "000"); WENN(H6="früh";"früh"&TEXT(ZÄHLENWENN(H$4:H6;"früh"); "000"); "xxx")))
Q7=N7+O7+P7
S7=WENN(H7="";"";WENN(H7="spät";"spät"&TEXT(ZÄHLENWENN(H$4:H7;"spät"); "000"); WENN(H7="früh";"früh"&TEXT(ZÄHLENWENN(H$4:H7;"früh"); "000"); "xxx")))


Excel Tabellen im Web darstellen >> Excel Jeanie HTML 4.8
Montag

 ABCDEFGHIJKLM
1KW 40Montag28.09.2015September28
2DatenfrühSAInfo DatenspätSAInfoPersNr. FrühPersNr. Spät
3655Mitarbeiter1    126Mitarbeiter2  NS5550155569

Formeln der Tabelle
ZelleFormel
B1=TEXT(F1;"TTTT")
F1=DATUM(JAHR('Ferien und Feiertage'!$A$1); 1;7*A1-3-WOCHENTAG(DATUM(JAHR('Ferien und Feiertage'!$A$1); ;); 3))
L1=TEXT(F1;"MMMM")
M1=TAG(F1)
A3=WENNFEHLER(SVERWEIS(L3;Mitarbeiter!$B:$L;8;FALSCH); "")
B3=WENNFEHLER(SVERWEIS(L3;Mitarbeiter!$B:$L;2;FALSCH); "")
E3=WENN(L3=0;"";WENNFEHLER(TEXT(INDEX(INDIREKT("'" & $L$1 & "'!$F$10:$AJ$198"); VERGLEICH(L3;INDIREKT("'" & $L$1 & "'!$A$10:$A$198"); 0); $M$1); ""); ""))
G3=WENNFEHLER(SVERWEIS(M3;Mitarbeiter!$B:$L;8;FALSCH); "")
H3=WENNFEHLER(SVERWEIS(M3;Mitarbeiter!$B:$L;2;FALSCH); "")
K3=WENN(M3=0;"";WENNFEHLER(TEXT(INDEX(INDIREKT("'" & $L$1 & "'!$F$10:$AJ$198"); VERGLEICH(M3;INDIREKT("'" & $L$1 & "'!$A$10:$A$198"); 0); $M$1); ""); ""))
L3=WENNFEHLER(INDEX(Mitarbeiter!$B:$B;VERGLEICH($B$2&TEXT(ZEILE()-ZEILE($L$2); "000"); Mitarbeiter!$S:$S;0); 1); "0")
M3=WENNFEHLER(INDEX(Mitarbeiter!$B:$B;VERGLEICH($H$2&TEXT(ZEILE()-ZEILE($L$2); "000"); Mitarbeiter!$S:$S;0); 1); "0")


Excel Tabellen im Web darstellen >> Excel Jeanie HTML 4.8
Dienstag

 ABCDEFGHIJKLM
1KW 40Dienstag29.09.2015September29
2Daten1frühSAInfo DatenspätSAInfoPersNr. FrühPersNr. Spät
3655Mitarbeiter1    126Mitarbeiter2  NS5550155569

Formeln der Tabelle
ZelleFormel
A1=Montag!A1
B1=TEXT(F1;"TTTT")
F1=Montag!F1+1
L1=TEXT(F1;"MMMM")
M1=TAG(F1)
A3=WENNFEHLER(SVERWEIS(L3;Mitarbeiter!$B:$L;8;FALSCH); "")
B3=WENNFEHLER(SVERWEIS(L3;Mitarbeiter!$B:$L;2;FALSCH); "")
E3=WENN(L3=0;"";WENNFEHLER(TEXT(INDEX(INDIREKT("'" & $L$1 & "'!$F$10:$AJ$198"); VERGLEICH(L3;INDIREKT("'" & $L$1 & "'!$A$10:$A$198"); 0); $M$1); ""); ""))
G3=WENNFEHLER(SVERWEIS(M3;Mitarbeiter!$B:$L;8;FALSCH); "")
H3=WENNFEHLER(SVERWEIS(M3;Mitarbeiter!$B:$L;2;FALSCH); "")
K3=WENN(M3=0;"";WENNFEHLER(TEXT(INDEX(INDIREKT("'" & $L$1 & "'!$F$10:$AJ$198"); VERGLEICH(M3;INDIREKT("'" & $L$1 & "'!$A$10:$A$198"); 0); $M$1); ""); ""))
L3=Montag!L3
M3=Montag!M3


Excel Tabellen im Web darstellen >> Excel Jeanie HTML 4.8

 Bild

Beiträge aus den Excel-Beispielen zum Thema "mehrere Blätter auf einmal schützen"