Konsolidierung via VBA: Daten verknüpfen

Bild

Betrifft: Konsolidierung via VBA: Daten verknüpfen
von: Heiko
Geschrieben am: 28.10.2015 15:27:46

Hallo zusammen,
leider komme ich erst heute wieder dazu mein Anliegen weiter zu bearbeiten:
https://www.herber.de/forum/archiv/1448to1452/t1451521.htm#1451521
Ich kann den Beitrag leider nicht mehr bearbeiten bzw. fortführen, so daß ich ihn hier neu aufmache.

 Hallo zusammen,
ich nutze zur Zusammenfassen meherer Datenblätter folgendes Macro.
Sub Konsolidieren()
Dim Wks As Worksheet
Dim Bereich As Range
Dim strLC As String
Dim i As Integer
Set Wks = Worksheets.Add
Wks.Name = "Konsolidierung"
For i = 2 To Worksheets.Count
 With Worksheets(i).UsedRange
  strLC = .Cells(.Rows.Count, .Columns.Count).Address
  Set Bereich = .Range("A1:" & strLC)
  Bereich.Copy Destination:=Wks.Cells(Rows.Count, 1).End(xlUp).Offset(1, 0)
  End With
Next i
End Sub
Somit werden alle Daten ins Zielblatt kopiert.
Ich möchte aber, daß die Daten im Zielblatt (Konsolidierung) als Verküpfung eingefügt werden.
Link:=true funktioniert hierbei aber nicht
Wer kann mir helfen?
Danke für Eure Hilfe
Mit Verkrüpfung ist Formel "=Tabelle1!A1" gemeint.
Wer kann mir helfen?
Besten Dank!

Bild

Betrifft: AW: Konsolidierung via VBA: Daten verknüpfen
von: Rudi Maintaire
Geschrieben am: 28.10.2015 15:48:37
Hallo,
teste mal:

Sub Konsolidieren()
  Dim a(), z As Long, s As Long
  Dim Wks As Worksheet
  Dim i As Integer
  Dim strSheet As String
  
  Set Wks = Worksheets.Add(before:=Sheets(1))
  Wks.Name = "Konsolidierung"
  
  For i = 2 To Worksheets.Count
    strSheet = "'" & Worksheets(i).Name & "'!"
    With Worksheets(i).UsedRange
      ReDim a(1 To .Rows.Count, 1 To .Columns.Count)
      For z = 1 To .Rows.Count
        For s = 1 To .Columns.Count
          a(z, s) = "=" & strSheet & .Cells(z, s).Address
        Next
      Next
    End With
    Wks.Cells(Rows.Count, 1).End(xlUp).Offset(1).Resize(UBound(a), UBound(a, 2)).Formula = a
  Next i
End Sub

Gruß
Rudi

Bild

Betrifft: AW: Konsolidierung via VBA: Daten verknüpfen
von: Heiko
Geschrieben am: 28.10.2015 16:13:43
Hallo Rudi,
das funktioniert hervorragend - besten Dank dafür.
Gruß
Heiko

 Bild

Beiträge aus den Excel-Beispielen zum Thema "Daten in andere Datei exportieren, wenn Datei gesc"