Datenprüfung-Makro

Hallo zusammen
Ich bin auf der Suche nach einem Marko, das mir meine Zwischenablage mit "=" konkateniert und anschliessend den Wert als Formel in eine Datenüberprüfung als Liste einfügt. Ich habe es zwar bereits selbst versucht, aber bin leider mit jedem Versuch gescheitert. Folgende Aufgabe möchte ich regelmässig durchführen:
Ich wähle einen Zellenbereich an und definiere einen Namen dafür. Gleichzeitig nehme ich den Namen in die Zwischenablage. Dann wähle ich die Zelle im Excel, in der ich eine Werteliste platzieren möchte. Den darauffolgende Teil möchte ich mit einem Makro lösen:
1. Ich wechsle in den Reiter "Daten" zu "Datentools" und wähle "Datenüberprüfung". Es öffnet sich die Maske "Datenüberprüfung".
2. Bei "Zulassen:" wähle ich "Liste" aus.
3. Bei "Daten:" gebe ich zuerst ein "=" (Gleichheitszeichen) und füge anschliessend den Zwischenspeicher (Ctrl-v) ein.
4. Das Ganze schliesse ich mit OK ab.
Danach habe ich in der Zeile eine Werteliste zum Auswählen. Die Punkte 1. bis 4. hätte ich gerne mit einem Makro gelöst. Ich kriege es nur nicht hin. Kann mir jemand helfen?

Beiträge zum Forumthread

Beiträge zu diesem Forumthread

Betreff

Datum

Anwender

Hallo Peter,
diese beiden Makros zusammen in ein allgemeines Modul

Public Function HoleTextVonZwischenablage() As String
'### von Peter Haserodt ###
Dim oData As New DataObject
On Error Resume Next ' Brutal um falsche Formate abzuwürgen, gibt dann einen Leerstring
oData.GetFromClipboard
HoleTextVonZwischenablage = oData.GetText
End Function
Public Sub RausMitZwischenAblage()
'### von Peter Haserodt ###
Dim oData As New DataObject
oData.SetText ""
oData.PutInClipboard
End Sub

Dieses Makro ins Code-Modul des Arbeitsblattes, auf dem du deine Gültigkeitslisten einfügen willst.
Dazu rechtsklick auf den Tabellenblattreiter - Code anzeigen - Code rechts ins Codefenster kopieren

Private Sub Worksheet_BeforeDoubleClick(ByVal Target As Range, Cancel As Boolean)
Dim Bereichsnamen As Variant
Bereichsnamen = HoleTextVonZwischenablage 'Zwischenablage in Variable
If Bereichsnamen = "" Then Exit Sub
Cancel = True
With Target.Validation
.Delete
.Add Type:=xlValidateList, AlertStyle:=xlValidAlertStop, Operator:= _
xlBetween, Formula1:="=" & Bereichsnamen
.IgnoreBlank = True
.InCellDropdown = True
.InputTitle = ""
.ErrorTitle = ""
.InputMessage = ""
.ErrorMessage = ""
.ShowInput = True
.ShowError = True
End With
RausMitZwischenAblage 'Zwischenablage leeren
End Sub

Ich habe jetzt mal das Doppelklick-Ereignis genommen.
Ablauf: du markierst deinen Zellbereich, definierst einen Namen, kopierst den Namen in die Zwischenablage, wechselst auf das Blatt auf dem die Gültigkeitsliste rein soll (dort muss natürlich der entsprechende Code hinterlegt sein). Durch Doppelklick in irgendeine Zelle wird dort die Datengültigkeit mit dem Bereichsnamen aus der Zwischenablage erstellt.
Sollte der Code bei der Benutzung mit einer Fehlermeldung aussteigen, dann liegt das vermutlich an einem fehlenden Verweis auf die Microsoft Forms 2.0 Objektlibrary.
Das ist aber kein Problem. Einfach eine Userform anlegen/einfügen, dann wird der entsprechende Verweis automatisch gesetzt.
Die Userform kannst du dann wieder löschen. Beim Speichern der Datei wird der gesetzte Verweis mit gespeichert.
Gruß Werner

Beliebteste Forumthreads (12 Monate)

3
Beiträge zum Forumthread

Beiträge zu diesem Forumthread

Links zu Excel-Dialogen

Beliebteste Forumthreads (12 Monate)

Beliebteste Forumthreads (12 Monate)

Datenprüfung-Makro

3 Beiträge zum Forumthread Beiträge zu diesem Forumthread

Links zu Excel-Dialogen

Beliebteste Forumthreads (12 Monate)

Beliebteste Forumthreads (12 Monate)

3
Beiträge zum Forumthread

Beiträge zu diesem Forumthread