Diagramm in userform

Guten Tag meine Damen und Herren,
Ich hatte schonmal ein Thread zu diesem Thema geöffnet, aber es kamen keine Antworten. Also versuche ich es nochmal..
Ich habe auf Excel 'Tabelle 1' eine Datenreihe gegeben. Nun möchte ich aber auf eine Userform mit einem ChartSpace ein liniendiagramm zeichnen lassen. Die Messdaten sind in B18:B39 und D18:D39 aufgelistet. Ich möchte auch das die Skalierung der Achsen automatisch gewählt wird. Ein Chartspace habe ich bereits mit Hilfe des Werkzeugtools hinzugefügt, aber ich weiß nicht, wie ich die Werte mit dem Chartspace in Verbindung setze und diese zeichnen lasse. Und wie benenne ich die Achsen?
Es geht mir lediglich erstmal nur darum, dass der Graph richtig gezeichnet wird.
Viel Dank für eure Antworten schon mal!
Gruß, Max

Beiträge zum Forumthread

Beiträge zu diesem Forumthread

Betreff

Datum

Anwender

Hallo Max,
teste mal:

Private Sub UserForm_Activate()

    Dim oChart As OWC11.ChChart
    Dim oSeries1 As OWC11.ChSeries, oSeries2 As OWC11.ChSeries
    Dim oAxis1 As OWC11.ChAxis, oAxis2 As OWC11.ChAxis

    Set oChart = ChartSpace1.Charts.Add
    With oChart
        .HasLegend = True
        .Legend.Position = chLegendPositionBottom
        .HasTitle = True
        .Title.Caption = "Sales & Discounts"
    End With

    Set oSeries1 = oChart.SeriesCollection.Add
    With oSeries1
        .Caption = "Sales"
        .Type = chChartTypeScatterSmoothLine
        Call .SetData(chDimXValues, chDataLiteral, _
            Application.Transpose(Tabelle1.Range("B18:B39").Value))
        Call .SetData(chDimYValues, chDataLiteral, _
            Application.Transpose(Tabelle1.Range("D18:D39").Value))
    End With

    Set oSeries2 = oChart.SeriesCollection.Add
    With oSeries2
        .Caption = "Discount"
        .Type = chChartTypeScatterSmoothLine
        Call .SetData(chDimXValues, chDataLiteral, _
            Application.Transpose(Tabelle1.Range("B18:B39").Value))
        Call .SetData(chDimYValues, chDataLiteral, _
            Application.Transpose(Tabelle1.Range("G18:G39").Value))
    End With

    Set oAxis1 = oChart.Axes(chAxisPositionLeft)
    With oAxis1
        .Scaling.Minimum = 0
        .HasMajorGridlines = True
        .HasTitle = True
        .Title.Caption = "Wert"
    End With

    Set oAxis2 = oChart.Axes(chAxisPositionBottom)
    With oAxis2
        .Scaling.Minimum = 0
        .HasMajorGridlines = True
        .HasTitle = True
        .Title.Caption = "Kategorie"
    End With
End Sub

Gruß
Nepumuk

Beliebteste Forumthreads (12 Monate)

8
Beiträge zum Forumthread

Beiträge zu diesem Forumthread

Links zu Excel-Dialogen

Beliebteste Forumthreads (12 Monate)

Beliebteste Forumthreads (12 Monate)

Diagramm in userform

8 Beiträge zum Forumthread Beiträge zu diesem Forumthread

VBA Beispiele zu verwandten Themen

Links zu Excel-Dialogen

Beliebteste Forumthreads (12 Monate)

Beliebteste Forumthreads (12 Monate)

8
Beiträge zum Forumthread

Beiträge zu diesem Forumthread