Live-Forum - Die aktuellen Beiträge
Datum
Titel
29.03.2024 13:14:12
28.03.2024 21:12:36
28.03.2024 18:31:49
Anzeige
Archiv - Navigation
1584to1588
Aktuelles Verzeichnis
Verzeichnis Index
Übersicht Verzeichnisse
Vorheriger Thread
Rückwärts Blättern
Nächster Thread
Vorwärts blättern
Anzeige
HERBERS
Excel-Forum (Archiv)
20+ Jahre Excel-Kompetenz: Von Anwendern, für Anwender
Inhaltsverzeichnis

Suche Formel - evtl. INDEX?

Suche Formel - evtl. INDEX?
23.10.2017 15:52:09
Jens
Liebes Forum,
ich bin auf der Suche nach einer Formel die mir hilft, die monatlich anfallenden Tätigkeiten untereinander aufzulisten.
Grundlage ist eine Tabelle in der sowohl Tätigkeiten aufgeführt sind,
wie auch die Häufigkeit. Wenn eine Aufgabe fällig wird, dann steht im Schnittpunkt zw. Tätigkeit und Monat eine "1".
Manche Aufgaben fallen monatlich an, ander alle 2 Monate usw.
Durch die Formel sollen alle Tätigkeiten für einen vorher definierten Monat - z. B. durch Pull-Down-Feld - dargestellt werden.
Ich könnte mir vorstellen, das eine INDEX-Formel evtl. weiterhilft,
bin mir aber nicht sicher, wie ich es anfangen soll.
Wer kann helfen?
Schon jetzt vielen herzlichen Dank.
Jens
Anlage: Muster
https://www.herber.de/bbs/user/117169.xlsx

16
Beiträge zum Forumthread
Beiträge zu diesem Forumthread

Betreff
Datum
Anwender
Anzeige
AW: Suche Formel - evtl. INDEX?
23.10.2017 15:54:48
SF
Hola,
in J1 kommt der zu suchende Monat.
=WENNFEHLER(INDEX($A$3:$A$8;AGGREGAT(15;6;ZEILE($A$3:$A$8)-2/(($B$2:$F$2=$J$1)*($B$3:$F$8=1)); _ ZEILE(A1)));"")
Gruß,
steve1da
AW: mit INDEX() und AGGREGAT() ...
23.10.2017 16:00:48
...
Hallo Jens,
... nachfolgende Formel nach unten kopieren:
 ABCDEFGHI
1TätigkeitMonate   
2SeptemberOktoberNovemberDezemberJanuar  September
3A11     A
4B 1     C
5C11     F
6D 1      
7E        
8F1       
9         

Formeln der Tabelle
ZelleFormel
I3=IFERROR(INDEX(A:A,AGGREGATE(15,6,ROW(A$3:A$19)/INDEX(B$3:G$19,,MATCH(I$2,B$2:G$2,)),ROW(A1))),"")

Datengültigkeit der Tabelle
ZelleZulassenDatenEingabe 1Eingabe 2
I2Liste =Monate 
Namen in Formeln
ZelleNameBezieht sich auf
I2Monate=Tabelle1!$B$2:$F$2
Namen verstehen


Excel Tabellen im Web darstellen >> Excel Jeanie HTML 4
Gruß Werner
.. , - ...
Anzeige
AW: mit INDEX() und AGGREGAT() ...
23.10.2017 16:10:29
Luschi
Hallo Werner,
meine deutsche Excel-Version streikt bei dem Vorschlag mit englischen Formeln.
Das habe ich bei Dir ja moch nie gesehen; sicher nur ein Schalterproblem im AddIn.
Gruß von Luschi
aus klein-Paris
AW: "übersetzt" ins deutsche ...
23.10.2017 16:16:26
...
Hallo Luschi,
... lautet die Formel dann so (ich hatte aus Versehen in der Jeanie noch den Schalter für eine englische Version zu stehen):
 I
3A

Formeln der Tabelle
ZelleFormel
I3=WENNFEHLER(INDEX(A:A;AGGREGAT(15;6;ZEILE(A$3:A$19)/INDEX(B$3:G$19;;VERGLEICH(I$2;B$2:G$2;)); ZEILE(A1))); "")


Excel Tabellen im Web darstellen >> Excel Jeanie HTML 4
Gruß Werner
.. , - ...
Anzeige
AW: "übersetzt" ins deutsche ...
23.10.2017 16:25:32
Jens
Hallo Werner,
herzlichen Dank für die Formel.
Funktioniert so wie ich mir das vorgestellt habe.
Danke.
Jens
AW: es geht allerdings auch einfacher ...
23.10.2017 16:20:42
...
Hallo,
... in I3 so:

=WENNFEHLER(INDEX(A:A;AGGREGAT(15;6;ZEILE($A$3:$A$19)/(B$2:G$2=I$2)/B$3:F$19;ZEILE(A1)));"")

und Formel nach unten kopieren.
Gruß Werner
.. , - ...
AW: es geht allerdings auch einfacher ...
23.10.2017 16:29:46
Jens
Danke.
Jens
verständlicher ohne Aggregat
23.10.2017 18:17:06
WF
Hi,
in I3 folgende Arrayformel:
{=WENNFEHLER(INDEX(A:A;KKLEINSTE(WENN((B$3:F$9>0)*(B$2:F$2=I$2);ZEILE(X$3:X$9));ZEILE(X1)));"")}
runterkopieren
Statt der 1 kannst Du auch alles andere - Texte und Zahlen (außer <=0) - einsetzen.
WF
Anzeige
AW: verständlicher ohne Aggregat
23.10.2017 18:52:29
Jens
Hallo WF,
herzlichen Dank für die Variante.
Es ist echt toll wie viele verschiedene Möglichkeiten es gibt.
LG
Jens
AW: viele sehen es mittlerweile anders owT
23.10.2017 19:48:28
...
Gruß Werner
.. , - ...
viele: sind das 3 oder schon 5 ?
23.10.2017 20:45:11
WF
.
Sicher mehr! Aber Du hast auf gewisse Weise ...
24.10.2017 01:58:16
Luc:-?
…schon recht, Walter,
denn diese eigentlich nur als besseres TEILERGEBNIS gedachte Fkt wirkt wie zusammengeflickt, so unbegründet uneinheitlich ist ihre Wirkungsweise und Argumentierung → gut gedacht, aber schlecht gemacht!
Aber Dir, Werner,
geht's ja wohl in 1.Linie um die {}-Vermeidung, von Dir (missverständlich) als Matrix­funk­tiona­lität bezeichnet. Das ist aber mE irre­levant, vor allem, wenn eine einfache manuelle Aktion durch eine kompliziertere und idR weniger leicht durchschaubare Fml ersetzt wird. Ob das nun für Anfänger hilfreicher ist, wage ich doch zu bezweifeln…
Deshalb habe ich euch mal ein paar problembezogene Fmln zusammengestellt, die die Irrelevanz eures Streits gut doku­men­tieren. Zuerst habe ich wechsel­seitig die relevanten Inhalte eurer Fmln mit der jeweils anderen Gesamt­form kombi­niert, was in beiden Fällen erwar­tungs­gemäß singulare Matrix­Fmln (auch so ein irrationales Unding, für das es nur eine einzige, oft irrelevante Begründung gibt) erfordert. Damit wird klar, dass AGGREGAT hier nur ver­wendet wird, um die fehler­pro­duzie­rende Divisions­Form für das Hpt­Argument von KKLEINSTE nutzen zu können:
neopa auf WF: {=WENNFEHLER(INDEX(A:A;KKLEINSTE(WENNFEHLER(ZEILE($A$3:$A$19)/(B$2:F$2=J$2)/B$3:F$19;"");ZEILE(A1)));"")}
WF auf neopa: {=WENNFEHLER(INDEX(A:A;AGGREGAT(15;6;WENN((B$3:F$9>0)*(B$2:F$2=K$2);ZEILE(X$3:X$9));ZEILE(X1)));"")}

Anschld habe ich einerseits die AGGREGAT-MatrixFml auf die UDF AggregateXk umgestellt und Walters Fml auf Auswertung mit der UDF TxEval. Und siehe da, keinerlei MatrixFmlForm mehr erforderlich:
m.AggregateXk: =WENNFEHLER(INDEX(A:A;AggregateXk(-15;6;WENN((B$3:F$9>0)*(B$2:F$2=K$2);ZEILE(X$3:X$9));ZEILE(X1)));"")
m.TxEval: =WENNFEHLER(INDEX(A:A;TxEval("small(if((B3:F9>0)*(B2:F2=K2),row(X3:X9)),"&ZEILE(X1)&")"));"")

Aber da UDFs ja mit dem garstigen VBA erstellt wdn, habe ich noch ein Übriges getan und eine gute, weil auf einer uralten Makro­Spra­che fußend (was ist daran kein Pgm‽), XLM-Fkt in benannter Fml eingesetzt, die auch lokale (hier dt) FmlTexte versteht:
benXLMFkt: =WENNFEHLER(INDEX(A:A;AuswIdx);"")
AuswIdx: =AUSWERTEN("kkleinste(wenn((B3:F9>0)*(B2:F2=K2);zeile(X3:X9));"&ZEILE(X1)&")")
Und siehe da, wiederum keine MatrixFmlForm benötigt! ;-]
Das Ergebnis ist bei allen zuvor (und jetzt von mir) geposteten Fmln für das hoch­geladene Bsp immer das­selbe → in Matrix­Kon­stan­ten­Form für 6 Zeilen/Zellen: {"A";"C";"F";"";"";""}
🙈 🙉 🙊 🐵 Gruß, Luc :-?
Die Intelligenz ist auf diesem Planeten eine Konstante, die Bevölkerung nimmt aber zu! Darum informieren mit …
Anzeige
AW: wir hatten das bereits ausdiskutiert ...
24.10.2017 10:11:50
...
Hallo Luc,
... deswegen gehe ich hier nicht mehr darauf ein.
Allerdings muss ich darauf hinweisen, dass Du meine Formel hier im thread sowohl falsch wiedergegeben, als auch falsch zugeordnet hast.
Und im Weiteren sowohl Deine Formeln mit Deinen UDFs, als auch die mit der alten Excel4-Makrofunktion erfordern in neueren Excelversionen das Abspeichern der entsprechenden Datei als XLSm oder XLSb-Datei, was nicht jeder darf.
Gruß Werner
.. , - ...
Ja, ja, das .xlsm-Problem, ...
25.10.2017 04:29:13
Luc:-?
…Werner,
bei XLM-Fktt tatsächlich unumgänglich, bei UDFs schon, wenn sie in einem aktiven AddIn stationiert sind. Nur VBA zur Projekt­Auto­ma­ti­sie­rung (Reaktion auf Ereignisse u.ä.) erfordert meist Speicherung als .xlsm/b, vor allem, wenn NutzerFormulare (UFs) im Spiel sind.
Mein Anliegen war nicht, Deine oder WFs Fml erneut abzubilden, sondern ihre Innenleben ggeinander auszutauschen! Das hatte ich auch, nebst SchlussFolgerungen daraus, geschrieben. Wahrscheinlich hast Du das nicht aufmerksam genug gelesen, weil Du das Thema für ausdiskutiert hältst, was es aber nicht wirklich ist. Mit diesem BT habe ich euch beiden sowohl in Teilen recht gege­ben als auch Kritik an euren wechselseitigen StandPktt geübt, denn die ganze Streiterei bzw wohl eher gröbere (WF) „Neckerei“ ist im Grunde genommen doch recht sinnlos, denn letztlich kann ja jeder die Fml anbieten, die ihm am besten gefällt. Welche dann letztlich verwendet wird, entscheidet ohnehin der Anwender. Walter scheint ja auch eher Dein nahezu messianischer (Pro­pa­gie­rungs-)Eifer zu stören, weshalb er (D)ein AGGREGAT-Angebot, falls möglich, zu kontern sucht (quasi ähnlich wie D.E. meine UDF-Angebote per Archiv-Verweis, nur harmloser…).
Also, nicht ärgern! Kannst Du wohl genausowenig ändern wie MS' AGGREGAT-Fkt…! ;-]
Übrigens zeigen meine Bspp mE auch, dass es eine fml-bezogene Matrix­Fml­Fktio­na­li­tät ohne MxFmlForm nicht gibt, Matrix­Fktio­na­li­tät aber durchaus. Auch die meisten Xl-Fktt haben letztere, einige auch erstere, genau wie meine UDFs, wenn ich sie so pgmmiert habe (was zumindest in letzterem Fall unbedingt erforderlich wäre)… ;-]
Morrn, Luc :-?
Anzeige
OT: AGGREGAT noch nicht überall angekommen
26.10.2017 13:27:35
lupo1
Softmaker bezeichnet sich mit seinem Office als maximal kompatibel. Während es tatsächlich mittlerweile (in der Beta 2018)
WENNFEHLER (xl2007) kennt, ist dies für
AGGREGAT (xl2010) und
TEXTVERKETTEN (xl2016) noch nicht der Fall.
Anders übrigens hier: https://help.libreoffice.org/Calc/AGGREGATE_function/de (dort auch noch kein TEXTVERKETTEN)
Umgekehrt bei Google Docs: Kein AGGREGATE, aber dafür TEXTJOIN.
Anzeige

Beliebteste Forumthreads (12 Monate)

Anzeige

Beliebteste Forumthreads (12 Monate)

Anzeige
Anzeige
Anzeige