AW: Diagramm kopieren
11.01.2018 12:40:22
Michael
Hallo!
Etwa so (hier mit der Annahme es ist nur ein Diagramm auf dem Blatt bzw. es soll das erste Diagramm auf dem Blatt in die Email übernommen werden):
Sub a()
Dim Wb As Workbook: Set Wb = ThisWorkbook
Dim Ws As Worksheet: Set Ws = Wb.Worksheets("Tabelle1")
Dim Dia As ChartObject
Dim Ol As Object, OlMail As Object, OlInsp As Object
Dim WdDoc As Object, WdRng As Object
On Error Resume Next
Set Ol = GetObject(, "Outlook.Application")
If Err Then Set Ol = CreateObject("Outlook.Application")
Ol.Visible = True
Set Dia = Ws.ChartObjects(1)
Dia.CopyPicture
Set OlMail = Ol.CreateItem(0)
With OlMail
.To = "jemand@mail.com"
.CC = "andere@post.tv"
.Subject = "Hier das aktuelle Diagramm"
Set OlInsp = .getInspector
Set WdDoc = OlInsp.WordEditor
Set WdRng = WdDoc.Range
WdRng.collapse 1
WdRng.Paste
.Display ' Mail anzeigen
'.Send 'Mail direkt senden (alternativ)
End With
Set Wb = Nothing: Set Ws = Nothing: Set Dia = Nothing
Set Ol = Nothing: Set OlMail = Nothing: Set OlInsp = Nothing
Set WdDoc = Nothing: Set WdRng = Nothing
End Sub
LG
Michael