Live-Forum - Die aktuellen Beiträge
Datum
Titel
16.10.2025 00:15:51
Passwort im Herbersforum ändern
15.10.2025 16:22:17
Datum ist nicht Datum :(
15.10.2025 15:02:20
Blockpfeile mit Makro gehen nicht mehr nach freigabe
15.10.2025 13:51:13
VBA - Fortschrittsbalken unabhängig von Zellen
Keine passende Antwort im Forumarchiv gefunden?
Stelle deine Frage im Live-Forum
Anzeige
Anzeige
HERBERS
Excel-Forum (Archiv)
20+ Jahre Excel-Kompetenz: Von Anwendern, für Anwender
Vorheriger Thread
Vorheriger Thread
Rückwärts Blättern
1620to1624
1620to1624
Aktuelles Verzeichnis
Verzeichnis Übersicht
Verzeichnis Übersicht
Übersicht Verzeichnisse
Nächster Thread
Nächster Thread
Vorwärts blättern
Inhaltsverzeichnis

6.561 Kombinationen auflisten

Forumthread: 6.561 Kombinationen auflisten

6.561 Kombinationen auflisten
03.05.2018 13:16:39
erichm
Hallo,
ich muss alle Kombinationsmöglichkeiten bei
4 aus 9
auflisten.
Die Berechnung hierfür habe ich dort gefunden:
https://www.zum.de/Faecher/Materialien/gebhardt/stochastik/Kombin.html
Ergebnis: 6.561
Ich habe (evtl. in diesem Forum) vor einiger Zeit einen Code gefunden mit dem das bei entsprechender Änderung gehen könnte; leider habe ich die konkrete Quelle nicht mehr:
Option Explicit
Sub Schaltfläche1_Klicken()
Application.ScreenUpdating = False
Dim z
Dim t As Single
Dim z1 As Integer
Dim z2 As Integer
Dim z3 As Integer
Dim z4 As Integer
Dim z5 As Integer
Dim z6 As Integer
z = 1
t = Timer
For z1 = 1 To 9
For z2 = 1 To 9
For z3 = 1 To 9
For z4 = 1 To 9
For z5 = 1 To 9
For z6 = 1 To 9
Cells(z, 1) = z1
If frei(z2, z, 2) Then
Cells(z, 2) = z2
Else
GoTo weiter2
End If
If frei(z3, z, 3) Then
Cells(z, 3) = z3
Else
GoTo weiter3
End If
If frei(z4, z, 4) Then
Cells(z, 4) = z4
Else
GoTo weiter4
End If
If frei(z5, z, 5) Then
Cells(z, 5) = z5
Else
GoTo weiter5
End If
If frei(z6, z, 6) Then
Cells(z, 6) = z6
z = z + 1
'If (z Mod 30) = 0 Then ActiveWindow.ScrollRow = z - 20
Else
GoTo weiter6
End If
DoEvents
weiter6:
Next z6
weiter5:
Next z5
weiter4:
Next z4
weiter3:
Next z3
weiter2:
Next z2
weiter1:
Next z1
Application.ScreenUpdating = True
MsgBox Str(Timer - t) + " sec."
End Sub 
Public Function frei(ByVal zahl As Integer, ByVal z As Long, ByVal pos As Integer) As Boolean
Dim s
frei = True
For s = 1 To pos - 1
If Cells(z, s) = zahl Then frei = False
Next s
End Function
Mir gelingt aber leider die Anpassung nicht.
Ob das evtl. mit einer Formel-Funktion geht weiß ich nicht (würde mir aber auch reichen).
Besten Dank für eine Hilfe.
mfg
Anzeige

10
Beiträge zum Forumthread
Beiträge zu diesem Forumthread

Betreff
Datum
Anwender
Anzeige
So
03.05.2018 13:39:14
lupo1
Option Explicit
Sub s()
Application.ScreenUpdating = False
Dim z
Dim t As Single
Dim z1 As Integer
Dim z2 As Integer
Dim z3 As Integer
Dim z4 As Integer
z = 1
t = Timer
For z1 = 1 To 9
For z2 = 1 To 9
For z3 = 1 To 9
For z4 = 1 To 9
Cells(z, 1) = z1
If frei(z2, z, 2) Then
Cells(z, 2) = z2
Else
GoTo weiter2
End If
If frei(z3, z, 3) Then
Cells(z, 3) = z3
Else
GoTo weiter3
End If
If frei(z4, z, 4) Then
Cells(z, 4) = z4
z = z + 1
'If (z Mod 30) = 0 Then ActiveWindow.ScrollRow = z - 20
Else
GoTo weiter4
End If
DoEvents
weiter4:
Next z4
weiter3:
Next z3
weiter2:
Next z2
weiter1:
Next z1
Application.ScreenUpdating = True
MsgBox Str(Timer - t) + " sec."
End Sub

Anzeige
6.561 Kombinationen auflisten
03.05.2018 19:02:26
erichm
Danke - das sind jetzt 3.024 Kombinationen.
Der Unterschied zu den 6.561 gesuchten Kombinationen besteht wohl bei der Berücksichtigung von Wiederholungen. Die genannte Seite
https://www.zum.de/Faecher/Materialien/gebhardt/stochastik/Kombin.html
bietet bei der Berechnung die Möglichkeit mit Wiederholungen und ohne Wiederholungen an. An einem kleinen Beispiel versuche ich den Unterschied zu verdeutlichen:
2 aus 4
mit Wiederholungen = 64
111, 112, 113, 114, 121, 122, 123, 124, 131, 132, 133, 134, 141, 142, 143, 144, 211, 212, 213, 214, 221, 222, 223, 224, 231, 232, 233, 234, 241, 242, 243, 244, 311, 312, 313, 314, 321, 322, 323, 324, 331, 332, 333, 334, 341, 342, 343, 344, 411, 412, 413, 414, 421, 422, 423, 424, 431, 432, 433, 434, 441, 442, 443, 444,
ohne Wiederholungen = 24
123, 124, 132, 134, 142, 143, 213, 214, 231, 234, 241, 243, 312, 314, 321, 324, 341, 342, 412, 413, 421, 423, 431, 432,
Übertragen auf die Anfrage zu 6.561 Kombinationen müsste die 1. Kombination
1111
sein; die 2. Kombination
1112
Kann man das mit EXCEL darstellen / auflisten?
Danke nochmals.
mfg
Anzeige
AW: 6.561 Kombinationen auflisten
03.05.2018 19:38:18
onur
Wenn du von 6561 Kombinationen sprichst, kannst du eigentlich nur DAS meinen:
https://www.herber.de/bbs/user/121426.xlsm 
Sub Schaltfläche1_Klicken()
Dim s1, s2, s3, s4, z
Cells.ClearContents
z = 1
For s1 = 1 To 9
For s2 = 1 To 9
For s3 = 1 To 9
For s4 = 1 To 9
Cells(z, 1) = s1
Cells(z, 2) = s2
Cells(z, 3) = s3
Cells(z, 4) = s4
z = z + 1
Next s4
Next s3
Next s2
Next s1
End Sub

Wenn du aber wirklich 4 aus 9 (wie bei Lotto) meinst, wäre das eine Permutation, und es wären nur 3024 Möglichkeiten.
Anzeige
AW: 6.561 Kombinationen auflisten
04.05.2018 10:33:35
erichm
DANKE - das habe ich gesucht!!
mfg
AW: 6.561 Kombinationen auflisten
03.05.2018 20:07:48
Daniel
Hi
hier mal ein Code mit dem du relativ frei deine Kombinationen erzeugen kannst.
funktioniert für 4 aus x, mit oder ohne Wiederholungen.
die Möglichkeiten gibst du über die Variable Pool1 vor, jedes Zeichen ist eine Möglichkeit.
Du kannst statt der Ziffern auch Buchstaben verwenden.
über die Variable ohneWdh stellst du ein, ob mit oder ohne Wiederholungen
lediglich die 4 ist über die Schleifen fix vorgegeben. Wollte man die auch noch Variabel machen, müsste man das ganze über eine Rekursion realisieren.
Sub Kombis()
Dim Pool1 As String
Dim Pool2 As String
Dim Pool3 As String
Dim Pool4 As String
Dim Erg As String
Dim Arr
Dim z1 As Long, z2 As Long, z3 As Long, z4 As Long
Dim ohneWdh As Boolean
ohneWdh = False
Pool1 = "123456789"
Pool2 = Pool1
Pool3 = Pool1
Pool4 = Pool1
For z1 = 1 To Len(Pool1)
If ohneWdh Then Pool2 = Replace(Pool1, Mid(Pool1, z1, 1), "")
For z2 = 1 To Len(Pool2)
If ohneWdh Then Pool3 = Replace(Pool2, Mid(Pool2, z2, 1), "")
For z3 = 1 To Len(Pool3)
If ohneWdh Then Pool4 = Replace(Pool3, Mid(Pool3, z3, 1), "")
For z4 = 1 To Len(Pool4)
Erg = Erg & Mid(Pool1, z1, 1) & Mid(Pool2, z2, 1) _
& Mid(Pool3, z3, 1) & Mid(Pool4, z4, 1) & "|"
Next
Next
Next
Next
Arr = Split(Erg, "|")
Arr = WorksheetFunction.Transpose(Arr)
Cells(1, 1).Resize(UBound(Arr) - LBound(Arr) + 1, 1) = Arr
End Sub

Anzeige
WOW - das ist genial!!
04.05.2018 10:40:42
erichm
Hallo Daniel,
DANKE - das bietet mir neue Perspektiven. Habe jetzt verschiedenes getestet und hat wunderbar geklappt.
Die Flexibilität von der "4" wäre jetzt noch hilfreicher. Aber eine Rekursion kenne ich bisher nicht. Diverse Erklärungen / Beispiele in dem Forum hier bzw. per Google haben mir nicht geholfen, das hier einzubauen.
Besten Dank falls dies hier noch möglich wäre.
mfg
Anzeige
jetzt ist auch die 4 Flexibel mit Rekursion
04.05.2018 11:36:14
Daniel
Hi
hier jetzt auch die Variante, bei der auch die Anzahl der Elemente flexibel ist.
Läuft über Rekursion.
die Parameter gibst du bei Call Schleife() an.
1. die Auswahlliste
2. die Anzahl der Elemente
3. ohne oder mit Wiederholungen (true = ohne Wiederholungen)
Option Explicit
Public Ergebnis As String
Sub start()
Dim arr
Ergebnis = ""
Call Schleife("123456789", 4, True)
arr = Split(Ergebnis, "|")
arr = WorksheetFunction.Transpose(arr)
Cells(1, 1).Resize(UBound(arr, 1) - LBound(arr, 1) + 1, 1).Value = arr
End Sub
Private Sub Schleife(ByVal Pool As String, Anzahl As Long, ohneWdh As Boolean, Optional pos As  _
Long = 1, Optional TeilErg As String = "")
Dim i As Long
Dim Poolx As String
For i = 1 To Len(Pool)
If pos = Anzahl Then
Ergebnis = Ergebnis & TeilErg & Mid(Pool, i, 1) & "|"
Else
Poolx = Pool
If ohneWdh Then Poolx = Replace(Poolx, Mid(Pool, i, 1), "")
Call Schleife(Poolx, Anzahl, ohneWdh, pos + 1, TeilErg & Mid(Pool, i, 1))
End If
Next
End Sub
Gruß Daniel
Anzeige
Schöne Lösung!
04.05.2018 19:58:04
lupo1
Wenn WF nicht so VBA-allergisch wäre, gehörte das aufgrund der Universalität des Codes auf seine Seite.
danke für die Blumen
05.05.2018 13:50:49
Daniel
SUPER!
06.05.2018 11:37:59
erichm
Hallo Daniel,
allerbesten Dank; jetzt bin ich quasi optimal flexibel :)
Bin immer wieder erstaunt, welche Möglichkeiten EXCEL bietet.
mfg
Anzeige
;
Anzeige
Anzeige

Infobox / Tutorial

Alle Lotto-Kombinationen in Excel auflisten

Schritt-für-Schritt-Anleitung

Um alle möglichen Kombinationen aus 4 Zahlen in Excel aufzulisten, kannst du folgenden VBA-Code verwenden. Dieser ermöglicht dir, alle Kombinationen aus einer festgelegten Anzahl von Zahlen zu generieren. Hier ist ein einfacher Ansatz:

  1. Öffne Excel und drücke ALT + F11, um den VBA-Editor zu öffnen.
  2. Klicke auf Einfügen > Modul, um ein neues Modul zu erstellen.
  3. Kopiere und füge den folgenden Code in das Modul ein:
Sub Kombis()
    Dim Pool1 As String
    Dim Pool2 As String
    Dim Pool3 As String
    Dim Pool4 As String
    Dim Erg As String
    Dim Arr
    Dim z1 As Long, z2 As Long, z3 As Long, z4 As Long
    Dim ohneWdh As Boolean
    ohneWdh = False
    Pool1 = "123456789" ' Hier kannst du die Zahlen anpassen
    Pool2 = Pool1
    Pool3 = Pool1
    Pool4 = Pool1

    For z1 = 1 To Len(Pool1)
        If ohneWdh Then Pool2 = Replace(Pool1, Mid(Pool1, z1, 1), "")
        For z2 = 1 To Len(Pool2)
            If ohneWdh Then Pool3 = Replace(Pool2, Mid(Pool2, z2, 1), "")
            For z3 = 1 To Len(Pool3)
                If ohneWdh Then Pool4 = Replace(Pool3, Mid(Pool3, z3, 1), "")
                For z4 = 1 To Len(Pool4)
                    Erg = Erg & Mid(Pool1, z1, 1) & Mid(Pool2, z2, 1) & Mid(Pool3, z3, 1) & Mid(Pool4, z4, 1) & "|"
                Next
            Next
        Next
    Next

    Arr = Split(Erg, "|")
    Arr = WorksheetFunction.Transpose(Arr)
    Cells(1, 1).Resize(UBound(Arr) - LBound(Arr) + 1, 1) = Arr
End Sub
  1. Schließe den VBA-Editor und gehe zurück zu Excel.
  2. Drücke ALT + F8, wähle Kombis aus und klicke auf Ausführen.

Jetzt solltest du alle Kombinationen aus 4 Zahlen in der ersten Spalte deiner Excel-Tabelle sehen.

Häufige Fehler und Lösungen

  • Fehler: Keine Kombinationen werden angezeigt.

    • Lösung: Stelle sicher, dass du den Code korrekt kopiert hast und dass in der Variablen Pool1 die Zahlen richtig angegeben sind.

  • Fehler: Excel stürzt ab oder reagiert nicht.

    • Lösung: Reduziere die Anzahl der Kombinationen, indem du weniger Zahlen im Pool1 verwendest oder die Anzahl der generierten Kombinationen anpasst.

Alternative Methoden

Falls du eine Formel-basierte Lösung bevorzugst, kannst du auch die Funktion KOMBINIEREN nutzen, um die Anzahl der möglichen Kombinationen zu berechnen. Leider bietet Excel jedoch keine direkte Möglichkeit, alle Kombinationen aufzulisten, ohne auf VBA zurückzugreifen.

Praktische Beispiele

Hier sind einige Beispiele, wie du die Methoden anwenden kannst:

  • Beispiel 1: Wenn du alle Lotto-Kombinationen aus 1 bis 49 auflisten möchtest, ändere einfach Pool1 = "123456789" in Pool1 = "12345678910111213141516171819202122232425262728293031323334353637383940414243444546474849".

  • Beispiel 2: Für die Kombinationen aus 4 Zahlen ohne Wiederholung kannst du den ohneWdh Parameter auf True setzen, um sicherzustellen, dass jede Zahl nur einmal verwendet wird.

Tipps für Profis

  • Nutze die Option Explicit Anweisung am Anfang deines Codes, um sicherzustellen, dass alle Variablen deklariert sind.
  • Experimentiere mit verschiedenen Pools und Anzahl der Elemente, um flexible und interessante Kombinationen zu erstellen.
  • Verwende die Funktion KOMBINIEREN in Excel, um schnell die Anzahl der möglichen Kombinationen zu berechnen, bevor du die vollständige Liste generierst.

FAQ: Häufige Fragen

1. Wie kann ich die Anzahl der Elemente ändern? Du kannst die Anzahl der Schleifen im VBA-Code anpassen, um mehr oder weniger Elemente zu kombinieren.

2. Gibt es eine Möglichkeit, alle Lotto-Kombinationen in Excel ohne VBA zu generieren? Leider nicht. Excel bietet keine integrierte Funktion, um alle Kombinationen aufzulisten. VBA ist die beste Option für diese Aufgabe.

3. Was sind die Unterschiede zwischen Permutationen und Kombinationen? Permutationen berücksichtigen die Reihenfolge der Elemente, während Kombinationen dies nicht tun. Bei Lotto-Kombinationen ist die Reihenfolge nicht relevant.

4. Wie kann ich die generierten Kombinationen speichern oder exportieren? Du kannst die Zellen einfach kopieren und in eine neue Datei einfügen oder die Datei im gewünschten Format speichern.

Beliebteste Forumthreads (12 Monate)

Jetzt das Excel-Portal bewerten: Deine Stimme zählt!
Anzeige
Anzeige
Entdecke mehr
Finde genau, was du suchst

Die erweiterte Suchfunktion hilft dir, gezielt die besten Antworten zu finden

Suche nach den besten Antworten
Unsere beliebtesten Threads

Entdecke unsere meistgeklickten Beiträge in der Google Suche

Top 100 Threads jetzt ansehen
Anzeige