xml: alle child nodes eines parent nodes auslesen

René · 2018-07-19T12:41:22+00:00

Hallo zusammen, wie kann man per VBA in einem xml file alle untergeordneten Knoten eines Unterknotens auslesen? Wenn man voraussetzt, dass man bereits weiß, dass man sich im Unterknoten 1B befindet, wie erhält man die Namen der Knoten Unterknoten 2B1 u. Unterknoten 2B2 sowie deren Text (2B1A, 2B1B) (s.u.) Bsp. Struktur des xml files: Hauptknoten: SektionA Unterknoten 1A: Kunde1 Unterknoten 2A1: LandA Unterknoten 2A2: LandB Unterknoten 1B: Kunde2 Unterknoten 2B1: LandC Text 2B1A: PreisX Text 2B1B: GrößeY Unterknoten 2B2: LandD usw. Gruß René

Hallo
Hab folgenden Code auf https://stackoverflow.com/questions/11305/how-to-parse-xml-using-vba gefunden und etwas modifiziert. Du musst in EXTRAS-VERWEISE-MICROSOFT XML V6.0 aktivieren.


Option Explicit
Public Sub LoadDocument()
Dim xDoc As MSXML2.DOMDocument60
Set xDoc = New MSXML2.DOMDocument60
xDoc.validateOnParse = False
If xDoc.Load("C:\Users\ich\Documents\test.xml") Then
' The document loaded successfully.
' Now do something intersting.
DisplayNode xDoc.ChildNodes, 0
Else
' The document failed to load.
' See the previous listing for error information.
End If
End Sub
Public Sub DisplayNode(ByRef Nodes As MSXML2.IXMLDOMNodeList, _
ByVal Indent As Integer)
Dim xNode As MSXML2.IXMLDOMNode
Indent = Indent + 2
For Each xNode In Nodes
If xNode.NodeType = NODE_TEXT Then
Debug.Print Space$(Indent) & xNode.ParentNode.nodeName & _
":" & xNode.NodeValue
End If
If xNode.HasChildNodes Then
DisplayNode xNode.ChildNodes, Indent
End If
Next xNode
End Sub

Hallo
Könnte in etwa so ausschauen


Option Explicit
Dim xDoc As MSXML2.DOMDocument60
Public Sub LoadDocument()
Set xDoc = New MSXML2.DOMDocument60
xDoc.validateOnParse = True
If xDoc.Load("C:\Users\ich\Downloads\child_nodes_of_parent_node.xml") Then
' The document loaded successfully.
Else
' The document failed to load.
End If
End Sub
Sub GetKD_ID(myCustomer As String)
Dim oSeqNodes As IXMLDOMNodeList
Dim oSeqNode As IXMLDOMNode
Dim oSeqChild As IXMLDOMNode
Set oSeqNodes = xDoc.SelectNodes("//BrandData/" & myCustomer)
If oSeqNodes.Length = 0 Then
'show some message
Else
For Each oSeqNode In oSeqNodes
For Each oSeqChild In oSeqNode.ChildNodes
Debug.Print oSeqChild.nodeName
Next
Next
End If
End Sub
Sub GetKD_ID_Info(myCustomer As String, myK_ID As String)
Dim oSeqNodes As IXMLDOMNodeList
Dim oSeqNode As IXMLDOMNode
Dim oSeqChild As IXMLDOMNode
Set oSeqNodes = xDoc.SelectNodes("//BrandData/" & myCustomer & "/" & myK_ID)
If oSeqNodes.Length = 0 Then
'show some message
Else
For Each oSeqNode In oSeqNodes
For Each oSeqChild In oSeqNode.ChildNodes
Debug.Print oSeqChild.nodeName, ":", oSeqChild.Text
Next
Next
End If
End Sub
Sub Finish()
Set xDoc = Nothing
End Sub
Sub RunXml()
LoadDocument
GetKD_ID "Customer_Deutschland"
GetKD_ID_Info "Customer_Deutschland", "Kd_ID_Test8"
Finish
End Sub

xml: alle child nodes eines parent nodes auslesen

Forumthread: xml: alle child nodes eines parent nodes auslesen

10
Beiträge zum Forumthread

Beiträge zu diesem Forumthread

Infobox / Tutorial