ADO - Daten aus geschlossener Arbeitsmappe holen

Hallo zusammen,
Sepp hat mir Anfang September einen Code zusammengestellt, mit dem man via ADO Daten in eine "geschlossenen" Arbeitsmappe schreiben kann.
Der Code sieht folgendermaßen aus:

Sub updateData()
Dim ExcelTable As Object
Dim Path As String, Table As String, SourceRange As String
Dim SQL As String, Con As String
Dim Seriennummer As String
Path = "C:\Datenbank\Mappe1.xls"  ' Dateiname - Anpassen!
Table = "Tabelle2"                ' Tabellenname - Anpassen
SourceRange = "A1:A2"             ' Bereich - Anpassen!
Seriennummer = ThisWorkbook.Worksheets("Tabelle3").Range("A1").Value
SQL = "select * from [" & Table & "$" & SourceRange & "]"
If Right(Path, 3) = "xls" Then
Con = "Provider=Microsoft.Jet.OLEDB.4.0;" _
& "Extended Properties=Excel 8.0;" _
& "Data Source=" & Path & ";"
ElseIf Right(Path, 4) = "xlsx" Or Right(Path, 4) = "xlsm" Then
Con = "Provider=Microsoft.ACE.OLEDB.12.0;" _
& "Extended Properties=""Excel 12.0;HDR=YES"";" _
& "Data Source=" & Path & ";"
End If
Set ExcelTable = CreateObject("ADODB.Recordset")
ExcelTable.Open SQL, Con, 3, 3
With ExcelTable
.Movefirst
.Fields(0) = Seriennummer
.Update
.Close
End With
Set ExcelTable = Nothing
End Sub

Nun suche ich einen Code für den umgekehrten Weg.
Ich möchte via ADO Daten aus einer "geschlossenen" Arbeitsmappe holen.
Die Lösung sollte nicht über eine Formel funktionieren die auf die Mappe verlinkt.
Sondern wirklich über die oben beschriebene Methode.
Könnt ihr mir da helfen?
Viele Grüße
Timo

Hallo Timo,
keine Ahnung ob das ADO ist.

Option Explicit
Public Function GetDataClosedWB(SourcePath As String, _
SourceFile As String, sourceSheet As String, _
SourceRange As String, TargetRange As Range) As Boolean
'Holt einen Bereich aus einer _geschlossenen_ Arbeitsmappe
'Nur in VBA zu verwenden; nicht aus einer Tabellenzelle heraus
'? t.ramel@mvps.org
' wird durch die HoleDaten aufgerufen
Dim strQuelle       As String
Dim Zeilen          As Long
Dim Spalten         As Byte
On Error GoTo InvalidInput
strQuelle = "'" & SourcePath & "[" & SourceFile & "]" & sourceSheet & "'!" & Range( _
SourceRange).Cells(1, 1).Address(0, 0)
Zeilen = Range(SourceRange).Rows.Count
Spalten = Range(SourceRange).Columns.Count
With TargetRange.Cells(1, 1).Resize(Zeilen, Spalten)
.Formula = "=IF(" & strQuelle & "="""",""""," & strQuelle & ")"
.Value = .Value
End With
GetDataClosedWB = True
Exit Function
InvalidInput:
MsgBox "Die Quelldatei oder der Quellbereich ist ung?ltig!", vbExclamation, "Get data from  _
closed Workbook"
GetDataClosedWB = False
End Function
Public Sub HoleDaten()
' Die Funktion arbeitet mit der obrigen GetDataClosedWB zusammen
Dim Pfad            As String
Dim Dateiname       As String
Dim Blatt           As String
Dim Bereich         As String
Dim Ziel            As Range
Pfad = "L:\Eigene Dateien\Hajo\Internet\Test\2009\"
Dateiname = "Beispiel Forum 30.xlsm" ' aus welcher Datei soll er holen?
Blatt = "Tabelle1"  ' von welcher Tabelle soll er holen?
Bereich = "A1:B9"   ' aus welchem Bereich soll er holen?
Set Ziel = ActiveSheet.Range("A1")  ' in welchen Bereich soll er kopieren? Genauer gesagt:  _
Bei welcher Zelle soll er anfangen, Datein reinzukopieren? Bsp: ActiveCell geht auch
If GetDataClosedWB(Pfad, Dateiname, Blatt, Bereich, Ziel) Then
MsgBox "Daten importiert"
End If
End Sub

Beiträge von Werner, Luc, robert, J.O.Maximo und folgende lese ich nicht.

ADO - Daten aus geschlossener Arbeitsmappe holen

Forumthread: ADO - Daten aus geschlossener Arbeitsmappe holen

6
Beiträge zum Forumthread

Beiträge zu diesem Forumthread

Infobox / Tutorial